Télécharger la plaquette Cast3M


fr en

Télécharger gaculVF.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : gaculVF.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH = FAUX ;
  5. ******************** CAS TEST : gacul.dgibi ************************
  6. *
  7. *
  8. * Test de fonctionnement de DARCYSAT en 2D avec effet de gravite
  9. * ==============================================================
  10. * Infiltration d'eau dans une colonne verticale de sable uniformément
  11. * désaturé.
  12. *
  13. * -  condition initiale : désaturation uniforme correspondant à une
  14. *    succion de 1,15 m ;
  15. * -  a l'instant initial, une extrémité de la colonne est noyée.
  16. *    La frontière est supposée rester a pression nulle ;
  17. *
  18. * ===================================================================
  19. *    Les options de modélisation declarées dans la table transmise à
  20. *    la procédure DARCYSAT sont les suivantes :
  21. *
  22. *
  23. * -  les effets gravitationnels sont pris en compte (indice GRAVITE de
  24. *    valeur VRAI);
  25. *
  26. * -  Une liste de temps de sauvegarde est fournie en valeur de l'indice
  27. *    TEMPS_SAUVES ;
  28. *
  29. * -  Le pas de temps est d'abord automatique (indice TEMPS_CALCULES absent)
  30. *    L'utilisateur fournit
  31. *    > le pas de temps initial (indice 'DT_INITIAL'),
  32. *    > le nombre d'itérations recherché par pas de temps (indice 'NITER')
  33. *    > le nombre de pas de temps (indice 'NPAS')
  34. *
  35. * -  Une sous-relaxation de 0,8 est prise en compte (indice SOUSRELAX)
  36. *
  37. * -  L'homogenéisation spatiale des propriétes physiques s'effectue
  38. *    par moyenne arithmétique des valeurs obtenues aux faces (indice
  39. *    HOMOGENEISATION de valeur DECENTRE)
  40. *
  41. *!!!!!!!!!!!!!!!!!!!!!!!!
  42. * -  La précision de convergence demandée est de 0,5 mm (indice RESIDU_MAX)
  43. * cas test tiré du rapport DMT 97/25 :
  44. * "Implémentation dans CASTEM 2000 d'un modèle de transfert hydrique
  45. *  en milieu poreux non saturé"
  46. *
  47. *
  48. ********************* CAS TEST : gacul.dgibi ************************
  49.  
  50. 'OPTION' 'ECHO' 1 ;
  51. 'SAUTER' 'PAGE';
  52. *
  53. 'TITRE' 'infiltration verticale dans le sable : gacul.dgibi';
  54. 'OPTION' 'DIME' 2 'ELEM' 'QUA4' ;
  55. 'OPTION' 'ISOV' 'LIGN' 'TRACER' 'PSC' ;
  56.  
  57. *--------------------------------------------------------------------
  58. * Création maillage
  59. *
  60. *- Discrétisation :
  61. ENX = 1      ;
  62. ENY = 200    ;
  63. 'DENS' (1./eny) ;
  64.  
  65. *- Création des points et des droites
  66. *
  67. A0 = -.5   1.0D0;  B0 = .5  1.0D0;
  68. A1 = -.5   0.5D0;  B1 = .5  0.5D0;
  69. A2 = -.5   0.25D0;  B2 = .5  0.25D0 ;
  70. A3 = -.5   0.0D0;  B3 = .5  0.0D0 ;
  71.  
  72. *- Création des droites
  73. *
  74. AB0 = 'DROIT' ENX A0 B0 ;
  75. AB1 = 'DROIT' ENX A1 B1 ;
  76. AB2 = 'DROIT' ENX A2 B2 ;
  77. AB3 = 'DROIT' ENX A3 B3 ;
  78.  
  79. *- Creation des surfaces
  80. *
  81. MASSIF0 = AB3 'REGLER' AB2 'REGLER' AB1 'REGLER' AB0 ;
  82. ENY  = 'NBEL' MASSIF0 ;
  83. ENTR = 'COULEUR' ('INVERSE' AB0) 'ROUGE' ;
  84. SORT = 'COULEUR' (AB3) 'ROUGE' ;
  85.  
  86. 'SI' GRAPH  ;
  87.   'TRACER' (MASSIF0 'ET' ENTR 'ET' SORT) ;
  88. 'FINSI' ;
  89.  
  90. *- Creation des maillages contenant tous les points
  91. *
  92. QFTOT  = 'CHANGER' MASSIF0 'QUAF' ;
  93. QFSORT = 'CHANGER' SORT    'QUAF' ;
  94. QFENTR = 'CHANGER' ENTR    'QUAF' ;
  95.  
  96.  
  97. 'ELIMINATION' 0.00001 (QFTOT 'ET' QFSORT 'ET' QFENTR) ;
  98.  
  99. *- Modèles
  100. *
  101. MODHYB  = 'MODELE' QFTOT  'DARCY' 'ISOTROPE'        ;
  102. MODENTR = 'MODELE' QFENTR 'DARCY' 'ISOTROPE'        ;
  103. MODSORT = 'MODELE' QFSORT 'DARCY' 'ISOTROPE'        ;
  104. CEENTR  = 'DOMA'  MODENTR 'CENTRE' ;
  105. CESORT  = 'DOMA'  MODSORT 'CENTRE' ;
  106. HYCEN   = 'DOMA'  MODHYB  'CENTRE' ;
  107. HYFAC   = 'DOMA'  MODHYB  'FACE';
  108.  
  109. *- ordonnées
  110. *
  111. NDIME = 'VALEUR' 'DIME' ;
  112. ZCC   = 'COOR' HYCEN NDIME ;
  113. ZFF   = 'COOR' HYFAC NDIME ;
  114.  
  115. *- Création ligne de suivi pour le post-traitement et le test
  116. * ligne des points centres (cas 1D)
  117. *
  118. 'REPETER' BCL (ENY - 1) ;
  119.     IP = &BCL ;
  120.     JP = IP + 1 ;
  121.     PI = 'POINT' HYCEN IP ;
  122.     PJ = 'POINT' HYCEN JP ;
  123.    'SI' (IP 'EGA' 1);
  124.       LCENC = ('MANU' 'SEG2' PI PJ) ;
  125.    'SINON' ;
  126.       LCENC = LCENC 'ET' ('MANU' 'SEG2' PI PJ) ;
  127.    'FINSI' ;
  128.  FIN BCL ;
  129.  
  130. *--------------------------------------------------------------------
  131. *- pression initiale (metre d'eau) dans le sable
  132. HN    = -1.15 ;
  133.  
  134. *--------------------------------------------------------------------
  135. *- Conditions aux limites
  136.  
  137. *- frontière en limite du domaine de calcul (milieu désaturé)
  138. ESORT = 'NOMC' (('REDU' ZFF CESORT) + HN) 'TH' 'NATURE' 'DISCRET';
  139.  
  140.  
  141. *- frontière mouillée
  142. EENTR = 'NOMC' ('REDU' ZFF CEENTR) 'TH' 'NATURE' 'DISCRET';
  143.  
  144. *- chargement des CLs
  145. LICALC = 'PROG' 0.D0  1.e20 ;
  146. LIST1  = 'PROG' 2 * 1.D0 ;
  147. VALI0  = 'CHAR' 'THIM' (ESORT et EENTR)  ('EVOL' 'MANU' LICALC LIST1) ;
  148.  
  149. *--------------------------------------------------------------------
  150. *- initialisation des inconnues
  151. *  (doit être compatible avec les conditions aux limites)
  152. *
  153.  
  154. *- trace de charge d'eau
  155. z      = 'REDU' (ZFF + HN) ('DIFF' CEENTR HYFAC) ;
  156.  
  157.  
  158. *- charge d'eau
  159. H0     = 'NOMC' (ZCC + HN) 'H' 'NATURE' 'DISCRET';
  160.  
  161. *- flux
  162. QFACE0 = 'MANU' 'CHPO' HYFAC 1 'FLUX' 0.D0 'NATURE' 'DISCRET' ;
  163.  
  164.  
  165. *                                         ---------------------------
  166. *                                         = Table DARCY_TRANSITOIRE =
  167. *                                         ---------------------------
  168. *- initialisation table
  169. SATUR                     = 'TABLE' ;
  170. SATUR. 'TEMPS'            = 'TABLE' ;
  171. SATUR. 'CHARGE'           = 'TABLE' ;
  172. SATUR. 'FLUX'             = 'TABLE' ;
  173.  
  174.  
  175. SATUR . 'ITMAX' = 20;
  176.  
  177. *- données géommétriques
  178. SATUR. 'SOUSTYPE'         = 'DARCY_TRANSATUR' ;
  179. SATUR. 'MODELE'           = MODHYB              ;
  180.  
  181. *- instant initial
  182. SATUR. 'TEMPS' . 0        = 0.                  ;
  183. SATUR. 'CHARGE' . 0       = H0                  ;
  184. SATUR. 'FLUX' . 0         = QFACE0              ;
  185.  
  186. *- conditions aux limites et chargements
  187. SATUR . 'TRACE_IMPOSE' = VALI0 ;
  188.  
  189.  
  190. SATUR . 'LUMP'   = FAUX;
  191. SATUR . 'TYPDISCRETISATION'   = 'VF' ;
  192.  
  193. * GBM MODIFIE
  194.  
  195. TABRES = table METHINV;
  196. TABRES . 'TYPINV' = 2;
  197. TABRES . 'PRECOND' = 5;
  198.  
  199. SATUR . 'METHINV' = TABRES;
  200. SATUR . 'METHINV' . RESID = 1.D-20;
  201.  
  202.  
  203. *- données physiques
  204. * loi de perméabilité
  205. LoiP                      = 'TABLE' 'PUISSANCE';
  206. LoiP.'ALPHA'              = 7.3 ;
  207. LoiP.'PERMSAT'            = 5.85E-2 / 3600. ;
  208. SATUR.'LOI_PERMEABILITE'  = 'TABLE' LoiP ;
  209.  
  210. * loi de succion
  211. LoiS                      = 'TABLE' 'VAN_GENUCHTEN';
  212. LoiS. 'PORO'              = 0.3 ;
  213. LoiS. 'TERESIDU'          = 0.055 ;
  214. LoiS. 'NEXP'              = 2.0304  ;
  215. LoiS. 'MEXP'              = 0.5075 ;
  216. LoiS. 'BHETA'             = 0.029227 * 100. ;
  217. SATUR.'LOI_SATURATION'    = 'TABLE' LoiS ;
  218.  
  219. * gravité (rho_w g,  en mètres d'eau, vaut 1)
  220. SATUR. 'FORCE_GRAVITE'    = 1.;
  221.  
  222. *- données numériques
  223. SATUR. 'SOUS_RELAXATION'  = 1.0D0;
  224. SATUR. 'TEMPS_FINAL'      = 3000. ;
  225. SATUR. 'HOMOGENEISATION'  = 'CHAINE' 'DECENTRE' ;
  226. SATUR. 'NPAS'             = 1000 ;
  227. SATUR. 'RESIDU_MAX'       = 1.D-2 ;
  228. SATUR. 'NITER'            = 12 ;
  229. SATUR. 'DT_INITIAL'       = 5. ;
  230. SATUR. 'TEMPS_SAUVES'     = ('PROG' 1 'PAS' 1 6.)*500. ;
  231. *SATUR. 'MESSAGES'         = 0 ;
  232.  
  233.  
  234. 'SI' GRAPH ;
  235. *--------------------------------------------------------------------
  236. *--- Visualisation de la loi de capacité capillaire.
  237. * droite support des variables
  238.   dx  = 'DROIT' (0. -1.15 ) 1000  (0. 0.) ;
  239.   zc  = 'COOR' dx 2 ;
  240.   ev2 = 'EVOL' 'BLEU' 'CHPO' zc 'SCAL' dx ;
  241.   px  = 'EXTR' ev2 'ORDO' ;
  242. * calcul de la teneur en eau pour la pression zc
  243.   TAB = 'TABLE'  ;
  244.   s0 t0 cap = HT_PRO (SATUR.'LOI_SATURATION') ZC  ;
  245.   ev0 = 'EVOL' 'TURQ' 'CHPO' s0 'SCAL' dx ;
  246.   evt = 'EVOL' 'VERT' 'MANU' px (100. * ('EXTR' ev0 'ORDO')) ;
  247.   'DESSIN' evt 'TITX' 'Pc(m)' 'TITY' 'S(%)'
  248.                'TITRE' 'Loi capillaire S(Pc)' ;
  249. * calcul de la teneur en eau pour la pression zc - dp
  250.   dp  = 1.e-4 ;
  251.   s1 t1 cap = HT_PRO (SATUR.'LOI_SATURATION')
  252.                ('KOPS' zc '-'  dp) ;
  253. * représentation de la capacité
  254.   c1  = (t0 - t1) / dp;
  255.   ev1 = 'EVOL' 'ROUGE' 'CHPO' c1 'SCAL' dx ;
  256.   evc = 'EVOL' 'JAUNE' 'MANU' px ('EXTR' ev1 'ORDO') ;
  257.   'DESSIN' evc 'TITX' 'Pc(m)' 'TITY' 'Capa(1/m)'
  258.                'TITRE' 'Capacite capillaire' ;
  259. 'FINSI' ;
  260.  
  261. *                                           ===========================
  262. *                                           |         CALCUL          |
  263. *                                           ===========================
  264. DARCYSAT SATUR ;
  265.  
  266. * Post-traitement
  267. * ===============
  268. *-- Test de non régression
  269. * Le test est effectué en vérifiant la solution à 1 heure de temps physique
  270.  
  271. *- solution a 1 heure de temps physique
  272. lp = 'PROG' 35*-1.1500 -1.1501 -1.1496 -1.1516 -0.95203 -0.40387
  273.             -0.22041 -0.15351 -0.11533 -8.84629E-02 -6.74391E-02
  274.             -4.98338E-02 -3.43395E-02 -2.01365E-02 -6.63732E-03 ;
  275.  
  276. *- construction de la pression aux centres
  277. SATUR.'PRESSION' = 'TABLE'  ;
  278. 'REPETER' bb (dime SATUR.TEMPS) ;
  279.    id = &bb - 1 ;
  280.    HN = SATUR.'CHARGE'.id ;
  281.    SATUR.'PRESSION'.id = (nomc HN SCAL 'NATURE' 'DISCRET') - ZCC ;
  282. 'FIN' bb ;
  283.  
  284. *ev   = 'EVOL' 'CHPO' SATUR.'PRESSION'. 4 'SCAL' LCENC ;
  285. *lp2  = 'EXTR' ev 'ORDO' ;
  286. *err1 = 'MAXIMUM' ('ABS' (lp - lp2)) ;
  287. *mess 'régression : ' err1 ;
  288.  
  289. *-- Tracé (tous les temps)
  290.   LT        = 'LECT' 0  PAS 1 ((dime SATUR.TEMPS) - 1)  ;
  291.   liopt     = 'MOTS' 'MIMA' 'AXES';
  292.   TDES      = TRACHIS SATUR 'CHARGE' LCENC LT 'PREF' ' ' 'UNIT' 's' ;
  293. 'SI' GRAPH ;
  294.   DESTRA TDES liopt 'TITX' 'z (m)' 'TITY' 'Pw (m)' ;
  295. 'FINSI' ;
  296.  
  297. toto = 'PRIM' TDES . 6 . VALEUR;
  298. inta = 'EXTRAIRE' toto 'ORDO';
  299. inta = 'EXTRAIRE'  ('DIME' inta) inta;
  300.  
  301. err = 'ABS' (inta '+' 0.235 '/' 0.235);
  302. 'LISTE' err;
  303.  
  304. 'SI' (err > 2.D-2) ;
  305.    'ERREUR'  5;
  306. 'FINSI'  ;
  307.  
  308.  
  309. 'FIN';
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales