Exemples de jeux de données Cast3M

Télécharger g_fissure_circulaire_1.dgibi
* fichier : g_fissure_circulaire_1.dgibi
****************************************************
****************************************************
*                                                  *
*      VERIFICATION DE LA PROCEDURE G_THETA        *
*      POUR LE CALCUL DE G POUR UNE FISSURE        *
*       CIRCULAIRE DANS UNE GEOMETRIE PLANE        *
*                        -                         *
*       COMPARAISON ENTRE LE RESULTAT EN 2D        *
*   DEFORMATIONS PLANES AVEC ET SANS L'OPTION      *
*   'POINT_CENTRE' ET UNE SOLUTION ANALYTIQUE      *
*                                                  *
*  SOLUTION ANALYTIQUE TIREE DE :                  *
*  "THE STRESS ANALYSIS OF CRACKS HANDBOOK"        * 
*  TADA, PARIS AND IRWIN (2000)                    *
*                                                  *
****************************************************
 
* I - OPTIONS ET DONNEES
* ----------------------
 
* OPTIONS
OPTI 'DIME' 2 'ELEM' 'QUA8' ;
* SI BTRAC = VRAI ON TRACE LE MAILLAGE
BTRAC = FAUX ;
 
* DONNEES
* L1   = COTE DU CARRE
* LF   = LONGUEUR DE LA FISSURE
* ANG1 = SECTEUR ANGULAIRE DE LA FISSURE
L1 = 50. ;
LF = 1. ;
ANG1 = 45. ;
 
* PROPRIÉTÉS MATÉRIAU
MYOU = 2.E5 ;
POI = 0.3 ;
 
 
* II - MAILLAGE
* -------------
 
* PARAMETRES DU MAILLAGE
DENS1 = 0.1 ;
DENS DENS1 ;
PREC1 = DENS1 * 1.E-10 ;
 
* MAILLAGE RAYONNANT AUTOUR DE LA POINTE DE FISSURE
RRAY = LF / 6. ;
PF = 0. 0. ;
P1 = 0. (0. - RRAY) ;
D1 = DROI 5 PF P1 ;
S1 = D1 ROTA 8 180. PF ;
X Y = COOR S1 ;
R = ((X**2) + (Y**2))**0.5 ;
PELIM = R POIN 'MINI' ;
ELIM PELIM PREC1 ;
S1 = REGE S1 ;
 
* PASSAGE EN RECTANGLE
CON1 = CONT S1 ;
FL1 = MAXI R;
PCER = R POIN 'SUPERIEUR' (FL1 * 0.9999);
CER1 = CON1 ELEM 'APPUYE' PCER ;
NEL = (NBEL CER1) / 4 ;
XP = RRAY * 1.5 ;
XN = 0. - XP ;
REC1 = DROI NEL (0. XN) (XP XN) ;
REC1 = DROI (2 * NEL) REC1 (XP XP) ;
REC1 = DROI NEL REC1 (0. XP) ;
S2 = CER1 REGL 2 REC1 ;
STOT = S1 ET S2 ;
 
* RESTE DU MAILLAGE AUTOUR DE LA FISSURE
Y = COOR 2 STOT ;
YMIN = ABS (MINI Y) ;
ELINF = REC1 ELEM 'APPUYE' (Y POIN 'MINI') ;
S3 = ELINF TRAN (0. (YMIN - LF)) ;
STOT = STOT ET S3 ;
 
* DEFINITION DE LA FISSURE
CON2 = CONT STOT ;
PGAU = CON2 POIN 'DROI' (0. 0.) (0. 1.) ;
PFIS = (COOR 2 PGAU) POIN 'EGINFE' 0. ;
PLIG = (COOR 2 PGAU) POIN 'EGSUPE' 0. ;
LVSUP = CON2 ELEM 'APPUYE' PFIS ;
LVSUP = LVSUP COUL 'BLEU' ;
LIG = CON2 ELEM 'APPUYE' PLIG ;
 
* SYMETRIE
S4 = STOT SYME 'DROI' (0. 0.) (0. 1.) ;
LVINF = LVSUP SYME 'DROI' (0. 0.) (0. 1.) ;
LVINF = LVINF COUL 'ROUG' ;
ELIM S4 (LIG ET LVINF) PREC1 ;
STOT = STOT ET S4 ;
 
* FRONT
MFRO1 = INTE (CHAN 'POI1' LVSUP) (CHAN 'POI1' LVINF) ;
MFRO1 = MFRO1 COUL 'VERT' ;
FRO1 = MFRO1 POIN 1 ;
 
* DEPLACEMENT AU BON ENDROIT
DEPL STOT 'PLUS' (0. LF) ;
 
* DEFINITIONS D'ENTITES UTILES
CON3 = CONT STOT ;
X Y = COOR CON3 ;
PGAU = X POIN 'MINI' ;
DGAU = CON3 ELEM 'APPUYE' PGAU ;
PDRO = X POIN 'MAXI' ;
DDRO = CON3 ELEM 'APPUYE' PDRO ;
PHAU = Y POIN 'MAXI' ;
DHAU = CON3 ELEM 'APPUYE' PHAU ;
 
* TRANSFORMATION EN ARC DE CERCLE
RFIS = LF / (45./180. * PI) ;
X1 Y1 = COOR STOT ;
THET1 = Y1 / RFIS * 180. / PI ;
R1 = RFIS + X1 ;
X2 = R1 * (COS THET1) ;
Y2 = R1 * (SIN THET1) ;
UDEP = (NOMC 'UX' (X2 - X1)) + (NOMC 'UY' (Y2 - Y1)) ;
DEPL STOT 'PLUS' UDEP ;
 
* ON COMPLETE
CON2 = CONT STOT ;
X Y = COOR STOT ;
XMAX = MAXI X ;
YMAX = MAXI Y ;
D2 = ORDO (DGAU ET DHAU) ;
D3 = DROI (NBEL D2) (0. 0.) (0. YMAX) ;
S5 = D2 REGL 6 D3 ;
D4 = INVE (ORDO DDRO) ;
D5 = DROI (NBEL D4) ((2.*RFIS) 0.) ((2.*RFIS) YMAX) ;
S6 = D4 REGL 6 D5 ;
STOT = STOT ET S5 ET S6 ;
SZOOM = STOT ;
 
* FIN DU MAILLAGE
PHAU = STOT POIN 'DROI' (0. YMAX) (1. YMAX) ;
D6 = (CONT STOT) ELEM 'APPUYE' PHAU ;
LIG1 = ORDO (D3 ET D6 ET D5) ;
LIG2 = LIG1 HOMO (L1 / (MESU D6)) (RFIS 0.) ;
S7 = LIG1 REGL LIG2 ;
STOT = STOT ET S7 ;
STRAC = STOT ET LVSUP ET LVINF ET MFRO1 ;
SI BTRAC ;
    TRAC STRAC 'BOIT' SZOOM ;
FINSI ;
 
 
* III - MODELE, MATERIAU, CLS ET RESOLUTION
* -----------------------------------------
 
* MODELE ET MATERIAU
MOD1 = MODE STOT 'MECANIQUE' 'ELASTIQUE' ;
MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
RIG1 = RIGI MAT1 MOD1 ;
 
* CONDITIONS AUX LIMITES ET CHARGEMENT
CONTOT = CONT STOT ;
PBAS = (COOR 2 CONTOT) POIN 'MINI' ;
DBAS = CONTOT ELEM 'APPUYE' PBAS ;
DAUTRES = DIFF CONTOT (DBAS ET LVSUP ET LVINF) ;
BLO1 = BLOQ 'UY' DBAS ;
BLO2 = BLOQ 'UX' PF ;
BLO0 = BLO1 ET BLO2 ;
F0 = PRES 'MASS' MOD1 -1. DAUTRES ;
 
* RESOLUTION
U0 = RESO (RIG1 ET BLO0) F0 ;
 
SI BTRAC ;
    DEF0 = DEFO STRAC U0 0. ;
    DEF1 = DEFO STRAC U0 'ROUG' ;
    TRAC (DEF0 ET DEF1) 'BOIT' SZOOM ;
FINSI ;
 
 
* IV - POST-TRAITEMENT
* --------------------
 
* APPEL A G_THETA
SUPTAB = TABL ;
SUPTAB.'OBJECTIF' = MOT 'J' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'FRONT_FISSURE' = FRO1 ; 
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'SOLUTION_RESO' = U0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = F0 ;
SUPTAB.'COUCHE' = 5 ;
SUPSANS = COPI SUPTAB ;
SUPTAB.'POINT_CENTRE' = (0. 0.) ;
SUPAVEC = COPI SUPTAB ;
G_THETA SUPAVEC ;
GAVEC = SUPAVEC.'RESULTATS' ;
G_THETA SUPSANS ;
GSANS = SUPSANS.'RESULTATS' ;
 
* SOLUTION ANALYTIQUE
GANA = (1.-(POI**2)) / MYOU * (PI * RFIS * (SIN ANG1)) / ((1. + ((SIN (ANG1 / 2.))**2.))**2.) ;
 
* COMPARAISON
ERRAVEC = (ABS (GAVEC - GANA)) / GANA ;
MESS 'ERREUR SUR LE CALCUL DE G AVEC L''OPTION POINT_CENTRE :' ERRAVEC ;
ERRSANS = (ABS (GSANS - GANA)) / GANA ;
MESS 'ERREUR SUR LE CALCUL DE G SANS L''OPTION POINT_CENTRE :' ERRSANS ;
CRI1 = 2.E-3 ;
SI (ERRAVEC > CRI1) ;
    MESS 'ERREUR : L''ERREUR SUR G DEPASSE LE CRITERE' ;
    ERRE 5 ;
FINSI ;
SI (ERRAVEC > ERRSANS) ;
    MESS 'ERREUR : L''ERREUR SUR G AVEC L''OPTION POINT_CENTRE EST' ;
    MESS '         SUPERIEURE A L''ERREUR SANS CETTE OPTION' ;
    ERRE 5 ;
FINSI ;
 
FIN ;