Télécharger la plaquette Cast3M


fr en

Télécharger g_defaut_circonferentiel_4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_defaut_circonferentiel_4.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *      VERIFICATION DE LA PROCEDURE G_THETA        *
  6. *    POUR UN DEFAUT CIRCONFERENTIEL DEBOUCHANT     *
  7. *          DANS UN TUYAU (FRONT DEBOUCHANT,        *
  8. *                1 LEVRE MODELISEE)                *
  9. *                        -                         *
  10. *  COMPARAISON ENTRE LE CALCUL 3D ET UN CALCUL     *
  11. *                2D AXISYMETRIQUE                  *
  12. *                                                  *
  13. ****************************************************
  14.  
  15. OPTI 'DIME' 3 'ELEM' 'CU20' 'DENS' 1. ;
  16. BTRAC = FAUX ;
  17.  
  18. * FRONT OUVERT, UNE LEVRE MODELISEE
  19.  
  20. * MAILLAGE DE LA TRANCHE
  21. L1 = 10. ;
  22. L2 = 20. ;
  23. H1 = 5. ;
  24. SURF1 = (DROI (L1 0. 0.) (L2 0. 0.)) TRAN (0. H1 0.) ;
  25. ANG1 = 36. ;
  26. VOLU1 = SURF1 VOLU 1 'ROTA' ANG1 (0. 1. 0.) (0. 0. 0.) ;
  27. ELIM VOLU1 1.E-10 ;
  28. OMEGA1 = VOLU1 ;
  29.  
  30. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  31. * PARTIE SUP
  32. ENVE1 = ENVE VOLU1 ;
  33. POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
  34. ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
  35. R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
  36. POIN1 = R1 POIN 'EGINFE' ((L1 + L2)/2) ;
  37. LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
  38. LIGSUP = ELEM1 DIFF LVSUP ;
  39. SI BTRAC ;
  40.         TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
  41. FINSI ;
  42. * DEFINITION DU FRONT DE FISSURE
  43. FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
  44.  
  45. * MODELE ET MATERIAU
  46. MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
  47. MAT1 = MATE MOD1 'YOUN' 2.E5 'NU' 0.3 ;
  48. RIG1 = RIGI MOD1 MAT1 ;
  49.  
  50. * CL
  51. PSUP = (COOR 2 OMEGA1) POIN 'MAXI' ;
  52. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') PSUP ;
  53. BLOQ2 = BLOQ 'UY' PSUP ;
  54. BLOQ3 = BLOQ 'UY' LIGSUP ;
  55. SYM1 = OMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;
  56. BLOQ4 = SYMT 'DEPL' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) SYM1 ;
  57. SYM2 = OMEGA1 POIN 'PLAN' (0. 0. 0.) (0. 1. 0.) ((COS ANG1) 0. (SIN ANG1)) ;
  58. BLOQ5 = SYMT 'DEPL' (0. 0. 0.) (0. 1. 0.) ((COS ANG1) 0. (SIN ANG1)) SYM2 ;
  59. BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ET BLOQ4 ET BLOQ5 ;
  60. DEP1 = DEPI BLOQ2 1. ;
  61.  
  62. * RESO
  63. U1 = RESO (RIG1 ET BLOQ0) DEP1 ;
  64.  
  65. * G_THETA
  66. SUPTAB = TABL ;
  67. SUPTAB.'MODELE' = MOD1 ;
  68. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  69. SUPTAB.'BLOCAGES_MECANIQUES' = CL ;
  70. SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP1 ;
  71. SUPTAB.'OBJECTIF' = 'J' ;
  72. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  73. SUPTAB.'COUCHE' = 4 ;
  74. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  75. SUPTAB.'SOLUTION_RESO' = U1 ;
  76.  
  77. G_THETA SUPTAB ;
  78. G3D = PROG ;
  79. IND1 = INDE SUPTAB.'RESULTATS' ;
  80. NFRON = DIME IND1 ;
  81. REPE IFRON NFRON ;
  82.         PFRON = IND1.&IFRON ;
  83.         G3D = G3D ET (PROG SUPTAB.'RESULTATS'.PFRON) ;
  84. FIN IFRON ;
  85.  
  86.  
  87. * II - CALCUL 2D AXISYMETRIQUE
  88. * ----------------------------
  89.  
  90. OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA8' ;
  91.  
  92. OMEGA2 = SURF1 ;
  93.  
  94. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  95. C1 = CONT SURF1 ;
  96. POIN1 = (COOR 2 C1) POIN 'MINI' ;
  97. ELEM1 = C1 ELEM 'APPUYE' POIN1 ;
  98. POIN1 = (COOR 1 POIN1) POIN 'EGINFE' ((L1 + L2)/2) ;
  99. LVSUP = C1 ELEM 'APPUYE' POIN1 ;
  100. LIGSUP = ELEM1 DIFF LVSUP ;
  101. SI BTRAC ;
  102.         TRAC (OMEGA2 ET (LVSUP COUL 'ROUG')) ;
  103. FINSI ;
  104.  
  105. * DEFINITION DU FRONT DE FISSURE
  106. FRONFISS = ((COOR 1 LVSUP) POIN 'MAXI') POIN 1 ;
  107.  
  108. * MODELE ET MATERIAU
  109. MOD2 = MODE OMEGA2 'MECANIQUE' 'ELASTIQUE' ;
  110. MAT2 = MATE MOD2 'YOUN' 2.E5 'NU' 0.3 ;
  111. RIG2 = RIGI MOD2 MAT2 ;
  112.  
  113. * CL
  114. PSUP = (COOR 2 OMEGA2) POIN 'MAXI' ;
  115. BLOQ1 = BLOQ 'UR' PSUP ;
  116. BLOQ2 = BLOQ 'UZ' PSUP ;
  117. BLOQ3 = BLOQ 'UZ' LIGSUP ;
  118. BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ;
  119. DEP1 = DEPI BLOQ2 1. ;
  120.  
  121. * RESO
  122. U2 = RESO (RIG2 ET BLOQ0) DEP1 ;
  123.  
  124. * G_THETA
  125. SUPTAB = TABL ;
  126. SUPTAB.'MODELE' = MOD2 ;
  127. SUPTAB.'CARACTERISTIQUES' = MAT2 ;
  128. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  129. SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP1 ;
  130. SUPTAB.'OBJECTIF' = 'J' ;
  131. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  132. SUPTAB.'COUCHE' = 4 ;
  133. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  134. SUPTAB.'SOLUTION_RESO' = U2 ;
  135.  
  136. G_THETA SUPTAB ;
  137. G2D = PROG NFRON * SUPTAB.'RESULTATS' ;
  138.  
  139.  
  140. * III - COMPARAISON
  141. * -----------------
  142.  
  143. CRIT1 = MAXI (G3D - G2D) 'ABS' ;
  144. CMAX = MAXI G2D 'ABS' ;
  145. SI (CRIT1 > (CMAX*5.E-3)) ;
  146.         MESS 'LA SOLUTION 3D EST TROP ELOIGNEE DE LA SOLUTION 2D AXIS' ;
  147.         ERRE ;
  148. FINSI ;
  149.  
  150. FIN ;
  151.  
  152.  
  153.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales