Télécharger la plaquette Cast3M


fr en

Télécharger g_defaut_circonferentiel_2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_defaut_circonferentiel_2.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *      VERIFICATION DE LA PROCEDURE G_THETA        *
  6. *    POUR UN DEFAUT CIRCONFERENTIEL DEBOUCHANT     *
  7. *  DANS UN TUYAU (FRONT FERME, 1 LEVRE MODELISEE   *
  8. *                        -                         *
  9. *  COMPARAISON ENTRE LE CALCUL 3D ET UN CALCUL     *
  10. *                2D AXISYMETRIQUE                  *
  11. *                                                  *
  12. ****************************************************
  13.  
  14. * I - CALCUL 3D COMPLET
  15. * ---------------------
  16.  
  17. OPTI 'DIME' 3 'ELEM' 'CU20' 'DENS' 1. ;
  18. BTRAC = FAUX ;
  19.  
  20. * MAILLAGE DE LA TRANCHE
  21. L1 = 10. ;
  22. L2 = 20. ;
  23. H1 = 5. ;
  24. SURF1 = (DROI (L1 0. 0.) (L2 0. 0.)) TRAN (0. H1 0.) ;
  25. ANG1 = 360. ;
  26. VOLU1 = SURF1 VOLU 10 'ROTA' ANG1 (0. 1. 0.) (0. 0. 0.) ;
  27. ELIM VOLU1 1.E-10 ;
  28. OMEGA1 = VOLU1 ;
  29.  
  30. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  31. * PARTIE SUP
  32. ENVE1 = ENVE VOLU1 ;
  33. POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
  34. ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
  35. R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
  36. POIN1 = R1 POIN 'EGINFE' ((L1 + L2)/2) ;
  37. LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
  38. LIGSUP = ELEM1 DIFF LVSUP ;
  39. SI BTRAC ;
  40.         TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
  41. FINSI ;
  42. * DEFINITION DU FRONT DE FISSURE
  43. FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
  44.  
  45. * MODELE ET MATERIAU
  46. MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
  47. MAT1 = MATE MOD1 'YOUN' 2.E5 'NU' 0.3 ;
  48. RIG1 = RIGI MOD1 MAT1 ;
  49.  
  50. * CL
  51. PSUP = (COOR 2 OMEGA1) POIN 'MAXI' ;
  52. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') PSUP ;
  53. BLOQ2 = BLOQ 'UY' PSUP ;
  54. BLOQ3 = BLOQ 'UY' LIGSUP ;
  55. BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ;
  56. DEP1 = DEPI BLOQ2 1. ;
  57.  
  58. * RESO
  59. U1 = RESO (RIG1 ET BLOQ0) DEP1 ;
  60.  
  61. * G_THETA
  62. SUPTAB = TABL ;
  63. SUPTAB.'MODELE' = MOD1 ;
  64. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  65. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  66. SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP1 ;
  67. SUPTAB.'OBJECTIF' = 'J' ;
  68. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  69. SUPTAB.'COUCHE' = 4 ;
  70. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  71. SUPTAB.'SOLUTION_RESO' = U1 ;
  72.  
  73. G_THETA SUPTAB ;
  74. G3D = PROG ;
  75. IND1 = INDE SUPTAB.'RESULTATS' ;
  76. NFRON = DIME IND1 ;
  77. REPE IFRON NFRON ;
  78.         PFRON = IND1.&IFRON ;
  79.         G3D = G3D ET (PROG SUPTAB.'RESULTATS'.PFRON) ;
  80. FIN IFRON ;
  81.  
  82.  
  83. * II - CALCUL 2D AXISYMETRIQUE
  84. * ----------------------------
  85.  
  86. OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA8' ;
  87.  
  88. OMEGA2 = SURF1 ;
  89.  
  90. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  91. C1 = CONT SURF1 ;
  92. POIN1 = (COOR 2 C1) POIN 'MINI' ;
  93. ELEM1 = C1 ELEM 'APPUYE' POIN1 ;
  94. POIN1 = (COOR 1 POIN1) POIN 'EGINFE' ((L1 + L2)/2) ;
  95. LVSUP = C1 ELEM 'APPUYE' POIN1 ;
  96. LIGSUP = ELEM1 DIFF LVSUP ;
  97. SI BTRAC ;
  98.         TRAC (OMEGA2 ET (LVSUP COUL 'ROUG')) ;
  99. FINSI ;
  100.  
  101. * DEFINITION DU FRONT DE FISSURE
  102. FRONFISS = ((COOR 1 LVSUP) POIN 'MAXI') POIN 1 ;
  103.  
  104. * MODELE ET MATERIAU
  105. MOD2 = MODE OMEGA2 'MECANIQUE' 'ELASTIQUE' ;
  106. MAT2 = MATE MOD2 'YOUN' 2.E5 'NU' 0.3 ;
  107. RIG2 = RIGI MOD2 MAT2 ;
  108.  
  109. * CL
  110. PSUP = (COOR 2 OMEGA2) POIN 'MAXI' ;
  111. BLOQ1 = BLOQ 'UR' PSUP ;
  112. BLOQ2 = BLOQ 'UZ' PSUP ;
  113. BLOQ3 = BLOQ 'UZ' LIGSUP ;
  114. BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ;
  115. DEP1 = DEPI BLOQ2 1. ;
  116.  
  117. * RESO
  118. U2 = RESO (RIG2 ET BLOQ0) DEP1 ;
  119.  
  120. * G_THETA
  121. SUPTAB = TABL ;
  122. SUPTAB.'MODELE' = MOD2 ;
  123. SUPTAB.'CARACTERISTIQUES' = MAT2 ;
  124. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  125. SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP1 ;
  126. SUPTAB.'OBJECTIF' = 'J' ;
  127. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  128. SUPTAB.'COUCHE' = 4 ;
  129. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  130. SUPTAB.'SOLUTION_RESO' = U2 ;
  131.  
  132. G_THETA SUPTAB ;
  133. G2D = PROG NFRON * SUPTAB.'RESULTATS' ;
  134.  
  135.  
  136. * III - COMPARAISON
  137. * -----------------
  138.  
  139. CRIT1 = MAXI (G3D - G2D) 'ABS' ;
  140. CMAX = MAXI G2D 'ABS' ;
  141. SI (CRIT1 > (CMAX*5.E-3)) ;
  142.         MESS 'LA SOLUTION 3D EST TROP ELOIGNEE DE LA SOLUTION 2D AXIS' ;
  143.         ERRE ;
  144. FINSI ;
  145.  
  146. FIN ;
  147.  
  148.  
  149.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales