Exemples de jeux de données Cast3M

* fichier : g_decouplage_6.dgibi
****************************************************
****************************************************
*                                                  *
*      VERIFICATION DE LA PROCEDURE G_THETA        *
*    POUR LE CALCUL DES FIC POUR UNE FISSURE       *
*              DROITE DANS UN CARRE                *
*                        -                         *
*     VERIFICATION DU CALCUL DE KI ET KII VIA      *
*     DECOUPLAGE EN 2D AVEC ELEMENTS STANDARDS     *
*     ET LA SOLUTION ANALYTIQUE DE WESTERGAARD     *
*                                                  *
****************************************************
 
* I - INIT DES DONNÉES CAS_TEST
* -----------------------------
 
OPTI 'DIME' 2 'ELEM' 'QUA4' ;
BTRA = FAUX ;
 
* DONNEES GEOMETRIQUES
A0 = 1. ;
L1 = A0 / 4. ;
DENS1 = L1 / 5. ;
DENS2 = A0 / L1 * DENS1 ;
DENS DENS1 ;
 
* PROPRIÉTÉS MATÉRIAU
MYOU = 2E11 ;
POI = 0.001 ;
KAPPA = 3-(4*POI) ;
MU = MYOU/(2*(1+POI)) ;
 
 
* II - MAILLAGE
* -------------
 
* CREATION DES SURFACES
P0 = 0. 0. ;
D1 = DROI (P0 MOIN (L1 0.)) (P0 PLUS (L1 0.)) ;
S1 = D1 TRAN (0. L1) ;
CONT1 = CONT S1 ;
CONT1 = DIFF CONT1 D1 ;
CONT2 = CONT1 HOMO (A0 / L1) P0 ;
S2 = CONT1 REGL 'DFIN' DENS2 CONT2 ;
S1 = S1 ET S2 ;
S2 = S1 SYME 'DROI' P0 (1. 0.) ;
S0 = (S1 COUL 'BLEU') ET (S2 COUL 'ROUG') ;
* TRAC S0 ;FIN ;
 
* FUSION
PRE1 = 1.E-10 ;
PLIGS = S1 POIN 'DROI' P0 (1. 0.) ;
PLIGS = (COOR 1 PLIGS) POIN 'EGSUPE' (0. - PRE1) ;
PLIGI = S2 POIN 'DROI' P0 (1. 0.)  ;
PLIGI = (COOR 1 PLIGI) POIN 'EGSUPE' (0. - PRE1) ;
ELIM PLIGS PLIGI PRE1 ;
 
* LEVRES ET FRONT
CON0 = CONT S0 ;
PLEVS = S1 POIN 'DROI' P0 (1. 0.) ;
PLEVS = (COOR 1 PLEVS) POIN 'EGINFE' PRE1 ;
LVSUP = CON0 ELEM 'APPUYE' PLEVS ;
PLEVI = S2 POIN 'DROI' P0 (1. 0.) ;
PLEVI = (COOR 1 PLEVI) POIN 'EGINFE' PRE1 ;
LVINF = CON0 ELEM 'APPUYE' PLEVI ;
FRON1 = INTE (CHAN 'POI1' LVSUP) (CHAN 'POI1' LVINF) ;
FRON1 = FRON1 POIN 1 ;
 
 
* III - MODELE ET MATERIAU
* ------------------------
 
MOD1 = MODE S0 'MECANIQUE' 'ELASTIQUE' ;
MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
 
 
* IV - CONDITIONS AUX LIMITES POUR LES 2 MODES
* --------------------------------------------
 
T_CHAR = TABL ;
T_DEPL = TABL ;
 
* IV.1 - EFFORTS DONNES
* *********************
 
* PREPARATIFS
CEXT = DIFF CON0 (LVSUP ET LVINF) ;
SEXT = S0 ELEM 'APPUYE' 'LARGEMENT' CON0 ;
MOD2 = REDU MOD1 SEXT ;
X Y = COOR SEXT ;
X Y = (CHAN 'CHAM' X MOD2 'STRESSES') (CHAN 'CHAM' Y MOD2 'STRESSES') ;
TETA = CHAN (ATG Y (X + 1.E-30)) 'TYPE' 'SCALAIRE' ;
RAY1 = (((X)**2) + ((Y)**2))**0.5 ;
RAY1 = CHAN RAY1 'TYPE' 'SCALAIRE' ;
PREF = 1. / ((2*PI*RAY1)**0.5) ;
COS05 = COS (TETA/2) ;
SIN05 = SIN (TETA/2) ;
COS15 = COS (3*TETA/2) ;
SIN15 = SIN (3*TETA/2) ;
SIG0 = ZERO MOD2 'CONTRAIN' ;
 
* MODE I :
SXX = PREF*(COS05*(1.-(SIN05*SIN15))) ;
SXY = PREF*(COS05*SIN05*COS15) ;
SYY = PREF*(COS05*(1.+(SIN05*SIN15))) ;
SZZ = POI * (SXX + SYY) ;
SIG1 = SIG0 + (NOMC 'SMXX' SXX) + (NOMC 'SMXY' SXY) + (NOMC 'SMYY' SYY)
                + (NOMC 'SMZZ' SZZ) ;
T_CHAR.'I' = REDU (BSIG MOD2 SIG1) CEXT ;
 
* MODE II :
SXX = PREF*(0. - (SIN05*(2.+(COS05*COS15)))) ;
SXY = PREF*(COS05*(1.-(SIN05*SIN15))) ;
SYY = PREF*(SIN05*COS05*COS15) ;
SZZ = POI * (SXX + SYY) ;
SIG1 = SIG0 + (NOMC 'SMXX' SXX) + (NOMC 'SMXY' SXY) + (NOMC 'SMYY' SYY)
                + (NOMC 'SMZZ' SZZ) ;
T_CHAR.'II' = REDU (BSIG MOD2 SIG1) CEXT ;
 
 
* IV.2 - DEPLACEMENT ANALYTIQUE
* *****************************
 
* PREPARATIFS
X Y = COOR S0 ;
LSUP = (COOR 1 PLEVS) POIN 'EGINFE' (0. - PRE1) ;
LINF = (COOR 1 PLEVI) POIN 'EGINFE' (0. - PRE1) ;
Y = Y + ((COOR 2 LSUP) + 1.E-30) + ((COOR 2 LINF) - 1.E-30) ;
TETA = ATG Y (X + 1.E-30) ;
RAY1 = (((X)**2) + ((Y)**2))**0.5 ;
PREF = (RAY1/(2*PI))**0.5 ;
COS05 = COS (TETA/2) ;
SIN05 = SIN (TETA/2) ;
XI0 = CHAN 'CHPO' MOD1 (ZERO MOD1 'DEPLACEM') ;
 
* MODE I :
XIX = PREF/(2.*MU)*(COS05*(KAPPA - 1. + (2.*(SIN05**2)))) ;
XIY = PREF/(2.*MU)*(SIN05*(KAPPA + 1. - (2.*(COS05**2)))) ;
T_DEPL.'I' = XI0 + (NOMC 'UX' XIX) + (NOMC 'UY' XIY) ;
 
* MODE II :
XIX = PREF/(2.*MU)*(SIN05*(KAPPA + 1. + (2.*(COS05**2)))) ;
XIY = PREF/(2.*MU)*(0. - (COS05*(KAPPA - 1. - (2.*(SIN05**2))))) ;
T_DEPL.'II' = XI0 + (NOMC 'UX' XIX) + (NOMC 'UY' XIY) ;
 
 
* V - APPEL A G_THETA
* -------------------
 
* CREATION DE LA TABLE
SUPTAB = TABL ;
SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
SUPTAB.'FRONT_FISSURE' = FRON1 ; 
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'COUCHE' = 4 ;
 
* APPELS A G_THETA
GTAB = TABL ;
REPE IMOD 2 ;
    MMOD = EXTR 'II' 1 &IMOD ;
    TAB1 = COPI SUPTAB ;
    TAB1.'SOLUTION_RESO' = T_DEPL.MMOD ;
    TAB1.'CHARGEMENTS_MECANIQUES' = T_CHAR.MMOD ;
    G_THETA TAB1 ;
    GTAB.MMOD = TAB1 ;
FIN IMOD ;
 
* CALCUL DES ERREURS
SAUT 'LIGNE' ;
REPE IMOD 2 ;
* ON ITERE SUR CHAQUE CHAMP DE DEPLACEMENT UTILISE
    MMOD = EXTR 'II' 1 &IMOD ;
    MESS 'SOLUTION EN MODE' ' ' MMOD ' :' ;
    SAUT 'LIGNE' ;
    TAB1 = GTAB.MMOD ;
    REPE JMOD 2 ;
* ET ON ITERE SUR LES 2 MODES
        MMOD = EXTR 'II' 1 &JMOD ;
        KNUM = EXTR TAB1.'CHPO_RESULTATS' 'VALE' (CHAI 'K' &JMOD) FRON1 ;
        KNUM = EXTR KNUM 1 ;
        SI (EGA &IMOD &JMOD) ;
* SI LE MODE CORRESPOND A CELUI DU CHAMP ANALYTIQUE ON DOIT TROUVER K=1
            KANA = 1. ;
        SINON ;
* SINON ON DOIT TROUVER K=0
            KANA = 0 ;
        FINSI ;
* ON CALCULE L'ERREUR
        ERR1 = ABS (KANA - KNUM) ;
        MESS 'ERREUR SUR LE CALCUL DE K' MMOD ' :'*30 ERR1 ;
        CRI1 = 1.E-3 ;
        SI (ERR1 >EG CRI1) ;
            MESS 'ERREUR : L''ERREUR SUR K' MMOD ' DEPASSE LE CRITERE' ;
            MESS '         POUR LE CHAMP ANALYTIQUE EN MODE' ' ' &IMOD ;
            ERRE 5 ;
        FINSI ;
    FIN JMOD ;
    SAUT 'LIGNE' ;
FIN IMOD ;
 
FIN ;