Accueil | Cast3M

* fichier : g_decouplage_3.dgibi
****************************************************
****************************************************
*                                                  *
*      VERIFICATION DE LA PROCEDURE G_THETA        *
*    POUR LE CALCUL DES FIC POUR UNE FISSURE       *
*            DROITE DANS UNE PLAQUE                *
*                        -                         *
*      COMPARAISAON DU CALCUL DE KI ET KII ENTRE   *
*      ELEMENTS STANDARDS ET XFEM VIA DECOUPLAGE   *
*                                                  *
****************************************************
 
* I - CALCUL 2D ELEMENTS STANDARDS
* --------------------------------
 
* OPTIONS ET BOOLEEN POUR LES TRACERS
OPTI 'DIME' 2 'MODE' 'PLANDEFO' 'ELEM' 'QUA4' 'DENS' 1. ;
BTRAC = FAUX ;
 
* MAILLAGE DE LA TRANCHE
L1 = 0. ;
L2 = 10. ;
LP = 5. ;
 
NELDEF = 6 ;
DENS1 = 1./NELDEF ;
PP = LP 0. ;
P1 = PP MOIN ((NELDEF*DENS1) 0.) ;
P2 = PP PLUS ((NELDEF*DENS1) 0.) ;
D1 = DROI NELDEF (DROI NELDEF P1 PP) P2 ;
S1 = D1 TRAN NELDEF (0. (NELDEF*DENS1)) ;
 
EL1 = (CONT S1) ELEM 'COMPRIS' P2 P1 ;
RAP1 = LP/(NELDEF*DENS1) ;
EL2 = EL1 HOMO RAP1 PP ;
DENS2 = RAP1*DENS1 ;
S2 = EL1 REGL EL2 'DINI' DENS1 'DFIN' DENS2 ;
SURF1 = S1 ET S2 ;
 
* SYMETRIE
SURF2 = SURF1 SYME 'DROI' (0. 0.) (1. 0.) ;
OMEGA1 = SURF1 ET SURF2 ;
 
* DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
C1 = CONT SURF1 ;
POIN1 = (COOR 2 C1) POIN 'MINI' ;
ELEM1 = C1 ELEM 'APPUYE' POIN1 ;
POIN1 = (COOR 1 POIN1) POIN 'EGINFE' LP ;
LVSUP = C1 ELEM 'APPUYE' POIN1 ;
LIGSUP = ELEM1 DIFF LVSUP ;
C2 = CONT SURF2 ;
POIN2 = (COOR 2 C2) POIN 'MAXI' ;
ELEM2 = C2 ELEM 'APPUYE' POIN2 ;
POIN2 = (COOR 1 POIN2) POIN 'EGINFE' LP ;
LVINF = C2 ELEM 'APPUYE' POIN2 ;
LIGINF = ELEM2 DIFF LVINF ;
ELIM LIGSUP LIGINF 1.E-10 ;
SI BTRAC ;
    TRAC (OMEGA1 ET (LVSUP COUL 'ROUG')) ;
FINSI ;
 
* DEFINITION DU FRONT DE FISSURE
FRONFISS = ((COOR 1 LVSUP) POIN 'MAXI') POIN 1 ;
 
* MODELE ET MATERIAU
MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
MAT1 = MATE MOD1 'YOUN' 2.E5 'NU' 0.3 ;
RIG1 = RIGI MOD1 MAT1 ;
 
* CL
PSUP = (COOR 2 OMEGA1) POIN 'MAXI' ;
BLOQ1 = BLOQ 'UX' PSUP ;
BLOQ2 = BLOQ 'UY' PSUP ;
PINF = (COOR 2 OMEGA1) POIN 'MINI' ;
BLOQ3 = BLOQ 'UX' PINF ;
BLOQ4 = BLOQ 'UY' PINF ;
BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ET BLOQ4 ;
DEP1 = DEPI BLOQ1 1. ;
DEP2 = DEPI BLOQ2 1. ;
DEP3 = DEPI BLOQ3 (0.-1.) ;
DEP4 = DEPI BLOQ4 (0.-1.) ;
DEP0 = DEP1 ET DEP2 ET DEP3 ET DEP4 ;
 
* RESO
U1 = RESO (RIG1 ET BLOQ0) DEP0 ;
 
* G_THETA
SUPTAB = TABL ;
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP0 ;
SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'COUCHE' = 4 ;
SUPTAB.'FRONT_FISSURE' = FRONFISS ;
SUPTAB.'SOLUTION_RESO' = U1 ;
 
G_THETA SUPTAB ;
KI_STD = SUPTAB.'RESULTATS' ;
 
 
* II - CALCUL 2D XFEM
* -------------------
 
N1 = (2 * NELDEF) + 1 ;
P3 = (LP - (NELDEF*DENS1)) (0. - (NELDEF*DENS1)) ;
P4 = (LP + (NELDEF*DENS1)) (0. - (NELDEF*DENS1)) ;
D2 = DROI N1 P3 P4 ;
S3 = D2 TRAN N1 (0. (2.*NELDEF*DENS1)) ;
 
EL1 = CONT S3 ;
EL2 = EL1 HOMO RAP1 PP ;
S4 = EL1 REGL EL2 'DINI' DENS1 'DFIN' DENS2 ;
 
OMEGA2 = S3 ET S4 ;
 
FRONFISS = LP 0. ;
FISS1 = (DROI 10 (0. 0.) FRONFISS) COUL 'ROUG' ;
PSI0 PHI0 = PSIP OMEGA2 FISS1 'DEUX' FRONFISS ;
SI BTRAC ;
    TRAC PSI0 OMEGA2 (OMEGA2 ET FISS1) ;
    TRAC PHI0 OMEGA2 (OMEGA2 ET FISS1) ;
FINSI ;
 
* MODELE ET MATERIAU
MOD2 = MODE OMEGA2 'MECANIQUE' 'ELASTIQUE' 'XQ4R' ;
ENRI1 = TRIE MOD2 PSI0 PHI0 ;
MAT2 = MATE MOD2 'YOUN' 2.E5 'NU' 0.3 ;
RIG2 = RIGI MOD2 MAT2 ;
 
* CL
PSUP = (COOR 2 OMEGA2) POIN 'MAXI' ;
BLOQ1 = BLOQ 'UX' PSUP ;
BLOQ2 = BLOQ 'UY' PSUP ;
PINF = (COOR 2 OMEGA2) POIN 'MINI' ;
BLOQ3 = BLOQ 'UX' PINF ;
BLOQ4 = BLOQ 'UY' PINF ;
BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ET BLOQ4 ;
DEP1 = DEPI BLOQ1 1. ;
DEP2 = DEPI BLOQ2 1. ;
DEP3 = DEPI BLOQ3 (0.-1.) ;
DEP4 = DEPI BLOQ4 (0.-1.) ;
DEP0 = DEP1 ET DEP2 ET DEP3 ET DEP4 ;
 
* RESO
U2 = RESO (RIG2 ET BLOQ0) DEP0 ;
 
XTAB = TABL ;
XTAB.'MODELE' = MOD2 ;
XTAB.'CARACTERISTIQUES' = MAT2 ;
XTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
XTAB.'CHARGEMENTS_MECANIQUES' = DEP0 ;
XTAB.'OBJECTIF' = MOT 'DECOUPLAGE';
XTAB.'PSI' = PSI0 ;
XTAB.'PHI' = PHI0 ;
XTAB.'COUCHE' = 4 ;
XTAB.'FRONT_FISSURE' = FRONFISS ; 
XTAB.'SOLUTION_RESO' = U2 ;
 
G_THETA XTAB ;
KI_X = XTAB.'RESULTATS' ;
 
 
* III - COMPARAISON
* -----------------
 
ACCEPT = 1.E-2 ;
REPE IMOD 2 ;
    MMOD = EXTR 'II' 1 &IMOD ;
    CRIT1 = MAXI (KI_X.MMOD - KI_STD.MMOD) 'ABS' ;
    CMAX1 = MAXI KI_STD.MMOD 'ABS' ;
    MESS 'ERREUR RELATIVE = ' (CRIT1 / CMAX1 * 100.) '%' ;
    SI (CRIT1 > (CMAX1 * ACCEPT)) ;
        MESS 'LA SOLUTION XFEM EST TROP ELOIGNEE DE LA SOLUTION' ;
        MESS 'STANDARD POUR LE CALCUL DU FIC EN MODE' ' ' MMOD ;
        ERRE 5 ;
    FINSI ;
FIN IMOD ;
 
FIN ;