Télécharger la plaquette Cast3M


fr en

Télécharger equ_chaleur2D_VFcyl.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  equ_chaleur2D_VFcyl.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ***********************************************************************
  5. * NOM         : equ_chaleur2D_VFcyl.dgibi
  6. * ___
  7. *
  8. * DESCRIPTION : Solution stationnaire de l'équation de la chaleur  (3D)
  9. *               dans un doamine cylindrique
  10. * ___________  
  11. *
  12. *               GEOMETRIE : 1 < r < 2
  13. *               ----------
  14. *
  15. *
  16. *               EQUATIONS :
  17. *               ----------
  18. *
  19. *               - Equations :
  20. *
  21. *                  mu Laplacien(T) = 0 avec mu = 1 ici
  22. *                  
  23. *               - Conditions aux limites :
  24. *
  25. *                  T = 0 @ r = 1 
  26. *                  DT/dr = 1 @ r = 2
  27. *
  28. *               - Solution exacte :
  29. *
  30. *                  T(r)= 2 ln (r) 
  31. *
  32. *
  33. * DISCRETISATION : une méthode de Volume Finis d'ordre 2 en espace. 
  34. * ______________   
  35. *                 
  36. *
  37. * Opérateurs utilisés : PENT ('DIAMAN2')
  38. *                       LAPN (option VF implicite)
  39. *
  40. * RESOLUTION :     - Solveur BiCGStab
  41. * __________       - Préconditionneur ILU(0)
  42. *
  43. * TESTS EFFECTUES : Vérification de l'ordre 2 en espace de la méthode
  44. * _______________   (utilisation d'une norme pseudo-L2) et de la 
  45. *                   précision absolue sur le maillage le plus fin.
  46. *                   
  47. *
  48. * LANGAGE     : GIBIANE-CASTEM 2000
  49. * AUTEUR      : A. Beccantini
  50. *               Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
  51. *               mél : gounand@semt2.smts.cea.fr
  52. ************************************************************************
  53. * VERSION    : v1, 15/04/02, version initiale
  54. * HISTORIQUE : v1, 25/02/03, création
  55. * HISTORIQUE :
  56. ************************************************************************
  57. * Prière de PRENDRE LE TEMPS de compléter les commentaires
  58. * en cas de modification de ce sous-programme afin de faciliter
  59. * la maintenance !
  60. ************************************************************************
  61.  interact= FAUX ;
  62.  complet = FAUX ;
  63.  graph   = FAUX ;
  64.  logxmgr = FAUX ;
  65.  
  66.  TYPEL = 'QUA4' ;
  67.  'OPTION' 'DIME' 2 'ELEM' TYPEL 'MODE' 'PLAN' ;
  68.  'OPTION' 'ISOV' 'SULI' ;
  69.  'OPTION' 'ECHO' 1 ;
  70.  nbisov = 15 ;
  71.  'SI' ('NON' interact) ;
  72.    'OPTION' 'TRAC' 'PS' ;
  73.    'OPTION' 'ISOV' 'LIGNE' ;
  74.    'OPTION' 'ECHO' 0 ;
  75.  'FINSI' ;  
  76. *
  77. ** Erreur Linfini entre deux Champoints.
  78. *
  79.  DEBPROC CALCERR vitp1*'CHPOINT' vit*'CHPOINT' ;
  80.     err = MAXI (vitp1 - vit) 'ABS' ;
  81.  FINPROC err ;
  82. *
  83. ** Erreur Pseudo L2 entre deux Champoints.
  84. *
  85. *
  86. * L2 = \sqrt{\frac{1}{vol} .
  87. *            \sum_{i} err_i^2 vol_i}
  88. *
  89.  DEBPROC CALCERR2 vitp1*'CHPOINT' vit*'CHPOINT' vol*'CHPOINT' ;
  90.    er2 = vitp1 '-' vit ;
  91.    compv  = 'EXTRAIRE' er2 'COMP' ;
  92.    er2 = 'PSCAL' er2 er2 compv compv ;
  93.    suppv  = 'EXTRAIRE' vol 'MAIL' ;
  94.    chpun = 'MANUEL' 'CHPO' suppv 1 'SCAL' 1 ;
  95.    voltot = 'XTY' chpun ('MOTS' 'SCAL') vol ('MOTS' 'SCAL') ;
  96.    error = 'XTY' er2 ('MOTS' 'SCAL') vol ('MOTS' 'SCAL') ;
  97.    error = error '/' voltot ;
  98.    error = error '**' 0.5 ;
  99.  FINPROC error ;
  100. *
  101. * Procédure paramétrée (raffinement)
  102. * renvoyant l'erreur en norme L2 sur la température.
  103. * On calcule une solution de l'équation de Laplace
  104. * (équations de la chaleur) ;
  105. *
  106.  'DEBPROC' CALCUL nraff*'ENTIER' ;
  107. *nraff=2 ;
  108. *
  109. * titre global pour les dessins
  110. *
  111.  titglob = 'CHAINE' ' ; nraff=' nraff ;
  112. *
  113. * Paramètres physiques
  114. *
  115. * 
  116.  cv=  1.0 ;
  117.  mu = 0.0 ;
  118.  kappa = 1.0 ;
  119.  rho = 1.0 ;
  120. *
  121. *  Géométrie
  122. *
  123.  p00 = 0.   0.  ;
  124.  p01 = 0.   0.  ;
  125.  pA = 1.   0.  ;
  126.  pB = 2.   0.  ;
  127. *
  128. * Paramètres de la discrétisation de base
  129. *
  130.  nAB = (nraff '+' 1) ;
  131. *
  132. * Géométrie discrétisée
  133. *
  134.  angle   = (180 '/' PI) * (1. '/' nab) ;
  135.  xPA1    = ('COORDONNEE' 1 PA) '*' ('COS' ANGLE) ;
  136.  yPA1    = ('COORDONNEE' 1 PA) '*' ('SIN' ANGLE) ;
  137.  PA1     = xpa1 ypa1;
  138.  
  139.  xPB1    = ('COORDONNEE' 1 PB) '*' ('COS' ANGLE) ;
  140.  yPB1    = ('COORDONNEE' 1 PB) '*' ('SIN' ANGLE) ;
  141.  PB1     = xpb1 ypb1 ;
  142.  
  143.  facint  = PA1 'DROIT' 1 PA ;
  144.  facext  = PB1 'DROIT' 1 PB ;
  145.  
  146.  mt = facint 'REGL' nab facext ;
  147.  cnt = 'CONT' mt ;
  148.  faccon = 'DIFF' cnt (facint 'ET' facext) ;
  149. *
  150. * Eventuellement, on trace le résultat
  151. *
  152.  'SI' graph ;
  153.     'TRACER' faccon ;
  154.      titgeo = 'CHAINE' 'mt ' 'NBPO=' ('NBNO' mt)
  155.                       ' NBELEM=' ('NBEL' mt) titglob ;
  156.     'TRACER' mt 'TITRE' titgeo ;
  157.  'FINSI' ;
  158. *
  159. *
  160. * Creation des modèles
  161. *
  162. * MODELS 
  163.  MDNS  = 'EULER' ;
  164.  $mt      = 'MODE' mt 'EULER'  ;
  165.  $cnt     = 'MODE' cnt 'EULER'  ;
  166.  $facint  = 'MODE' facint 'EULER'  ;
  167.  $facext  = 'MODE' facext 'EULER'  ;
  168.  $faccon  = 'MODE' faccon 'EULER'  ;
  169. *
  170.  Tmt      = 'DOMA' $mt 'VF'  ;
  171.  Tcnt     = 'DOMA' $cnt 'VF'  ;
  172.  Tfacint  = 'DOMA' $facint 'VF'  ;
  173.  Tfacext  = 'DOMA' $facext 'VF'  ;
  174.  Tfaccon  = 'DOMA' $faccon 'VF'  ;
  175. * QUAF
  176.  Mmt     = Tmt   . 'QUAF' ;
  177.  Mcnt    = Tcnt  . 'QUAF' ;
  178.  Mfacint = Tfacint  . 'QUAF' ;
  179.  Mfacext   = Tfacext  . 'QUAF' ;
  180.  Mfaccon   = Tfaccon  . 'QUAF' ;
  181.  'ELIM' (Mmt 'ET' Mcnt 'ET' Mfacint 'ET' Mfacext 'ET' Mfaccon)  1.E-8 ;
  182. * CHAMPOINT vide et MATRIK vide
  183.  chvid matvid = 'KOPS' 'MATRIK' ; 
  184. *
  185. * Solution exacte bilinéaire (sur le centre du contour)
  186. *
  187.  xx yy = 'COORDONNEE' ('DOMA' $cnt 'CENTRE') ;
  188. *
  189.  rr2 = (xx '*' xx) '+' (yy '*' yy) ;
  190.  rr  = rr2 '**' 0.5 ;
  191.  solex = 2 '*' ('LOG' rr) ;
  192. *
  193. * Solution exacte aux centres
  194. *
  195.  xx yy = 'COORDONNEE' ('DOMA' $mt 'CENTRE') ;
  196.  rr2 = (xx '*' xx) '+' (yy '*' yy) ;
  197.  rr  = rr2 '**' 0.5 ;
  198.  solexc = 2 '*' ('LOG' rr) ;
  199. *
  200.  'SI' FAUX ;
  201. *
  202. *   Gradient exact (aux faces)
  203. *
  204. *   Ca ne marche pas (probleme 2)
  205. *   En effet j'ai 1.0002 à la place de 1
  206. *   Probleme de quadr. du cercle.
  207. *
  208.     xx yy = 'COORDONNEE' ('DOMA' $mt 'FACE') ;
  209.     rr2 = (xx '*' xx) '+' (yy '*' yy) ;
  210.     gradtx = 'NOMC' 'UX' (2 '*' (xx '/' rr2)) 'NATU'
  211.           'DISCRET' ;
  212.     gradty = 'NOMC' 'UY' (2 '*' (yy '/' rr2)) 'NATU'
  213.           'DISCRET' ;
  214.     gradt = gradtx 'ET' gradty ;
  215.  
  216. * Test 
  217.     nn = 'DOMA' $mt 'XXNORMAF' ;
  218.     aa = 'REDU' nn ('DOMA' $faccon 'CENTRE') ;
  219.     aa = 'MAXIMUM' ('PSCAL' aa gradt ('MOTS' 'UX' 'UY')
  220.           ('MOTS' 'UX' 'UY')) 'ABS' ;
  221.     'SI' (aa > 1.0D-11) ;
  222.         'LISTE' aa ;
  223.         'MESSAGE' 'Probleme 1' ;
  224.         'ERREUR' 21 ;
  225.     'FINSI' ;
  226.     aa = 'REDU' nn ('DOMA' $facext 'CENTRE') ;
  227.     aa = 'MAXIMUM' ('PSCAL' aa gradt ('MOTS' 'UX' 'UY')
  228.           ('MOTS' 'UX' 'UY')) 'ABS' ;
  229.     'SI' ((aa '-' 1.0) > 1.0D-11) ;
  230.        'LISTE' aa ;
  231.        'MESSAGE' 'Probleme 2' ;
  232.        'ERREUR' 21 ;
  233.     'FINSI' ;
  234.     gradtcon = 'REDU' gradt ('DOMA' $faccon 'CENTRE') ;
  235.     gradtext  = 'REDU' gradt ('DOMA' $facext 'CENTRE') ;
  236.  'SINON' ;
  237. * 
  238. * Gradient exact sur le bord
  239. *
  240.     nn = 'DOMA' $mt 'XXNORMAF' ;
  241.     gradtcon = ('REDU' nn ('DOMA' $faccon 'CENTRE')) '*' 0.0 ;
  242.     gradtext  = ('REDU' nn ('DOMA' $facext 'CENTRE')) '*' 1.0 ;
  243.  'FINSI' ;
  244. *
  245. * Mise en place du calcul numérique
  246. *
  247. * Mise en place du calcul numérique
  248. *
  249. * équation de Laplace
  250. *
  251. * on utilise une méthode de Newton pour résoudre :
  252. * - \Delta T = 0     (\Delta opérateur laplacien)
  253. * - avec T  donné sur gauche (CL de Dirichlet)
  254. *        grad(T) \cdot next donné ailleurs
  255. *
  256. * T_0 : estimation initiale de la solution
  257. * On a T_1 = T_0 - {\Delta'}^{-1} (\Delta T_0)
  258. *
  259. * L'opérateur 'LAPN' 'VF' nous donne la matrice \Delta' et le
  260. * résidu \Delta T_0.
  261. * On n'inverse bien évidemment pas \Delta' mais on résoud le système:
  262. * \Delta' IncT = \Delta T_0
  263. * => IncT = {\Delta'}^{-1} (\Delta T_0)
  264. *
  265. * La méthode de Newton doit converger en un pas (on vérifie que le
  266. * résidu (\Delta T_1) est nul après le premier pas.
  267. * 
  268. *
  269.  rho0  = 'MANUEL' 'CHPO' ('DOMA' $mt 'CENTRE') 1 'SCAL' 1.0 ;
  270.  v0    = 'MANUEL' 'CHPO' ('DOMA' $mt 'CENTRE') 2 'UX' 0.0 'UY' 0.0 ;
  271.  cdirv = 'MANUEL' 'POI1' ('POIN' 1 ('DOMA' $cnt 'CENTRE')) ;
  272.  cvnv = 'DIFF' ('DOMA' $cnt 'CENTRE') cdirv ;
  273.  v0li1 = 'MANUEL' 'CHPO' cdirv 2 'UX' 0.0 'UY' 0.0 ;
  274.  v0li2 = 'MANUEL' 'CHPO'  cvnv 4 'P1DX' 0.0 'P1DY' 0.0
  275.     'P2DX' 0.0 'P2DY' 0.0  ;
  276.  taulim = 'MANUEL' 'CHPO' cvnv 3 'TXX' 0.0 'TYY' 0.0 'TXY' 0.0 ;
  277.  gradv0 mchamv = 'PENT' $mt 'FACE' 'DIAMAN2' ('MOTS' 'UX' 'UY')
  278.  ('MOTS' 'P1DX' 'P1DY' 'P2DX' 'P2DY') v0 v0li1 v0li2 ;
  279. *
  280.  t0 = 'MANU' 'CHPO' ('DOMA' $mt 'CENTRE') 1 'SCAL' 0.D0 ;
  281. *
  282. * We impose Dirichlet boundary conditions on cdir
  283. *
  284.  cdir = ('DOMA' $facint 'CENTRE') ;
  285. * cvn = set of FACE centers where we impose von Neumann boundary
  286. * conditions
  287.  cvn = (('DOMA' $facext 'CENTRE') 'ET' ('DOMA' $faccon 'CENTRE')) ;
  288.  'SI' graph ;
  289.    'TRACER' (cnt et cvn) 'TITRE' 'Von Neumann B.C.' ;
  290.    'TRACER' (cnt et cdir) 'TITRE' 'Dirichlet B.C.' ;
  291.  'FINSI' ;
  292.  tlim1 = 'REDU' solex cdir ;
  293.  gradtl = gradtext 'ET' gradtcon ;
  294.  tlim2 = 'NOMC'  ('MOTS' 'UX' 'UY')  ('MOTS' 'P1DX' 'P1DY')
  295.          gradtl ;
  296.  gradt0 mchamt = 'PENT'  $mt 'FACE' 'DIAMAN2' ('MOTS' 'SCAL')
  297.     ('MOTS' 'P1DX' 'P1DY') t0 tlim1 tlim2 ;
  298. * Jacobian
  299. * We use the 'NS' jacobian                        
  300.  listinco = 'MOTS' 'RN' 'RUXN' 'RUYN' 'RETN' ;
  301.  qlim =  -1.0 '*' kappa  '*' gradtl ;
  302.  jaco chpres dt = 'LAPN' 'VF' 'PROPCOST' 'RESI' 'IMPL'
  303.      $mt mu kappa cv rho0 v0 t0 gradv0 gradt0 mchamv mchamt
  304.      'VIMP' v0li1 'TAUI' taulim 'QIMP' qlim 'TIMP' tlim1 listinco ;
  305.  mamat = 'KOPS' 'MULT' -1.0D0 jaco ;
  306. * Identity matrix for momentum and density contribution 
  307.  mati = 'KOPS' 'MATIDE' ('MOTS' 'RN' 'RUXN' 'RUYN')
  308.       ('DOMA' $mt 'CENTRE') 'MATRIK' ;
  309.  matot = 'ET' mamat mati ;
  310. *
  311.  rv = 'EQEX' ;
  312.  rv . 'METHINV' . 'TYPINV'   = 3 ;
  313.  rv . 'METHINV' . 'PRECOND'  = 3 ;
  314.  rv . 'METHINV' . 'MATASS'   = matot ;
  315.  rv . 'METHINV' . 'MAPREC'   = matot ;
  316.  deltat = 'KRES' matot 'TYPI' (rv . 'METHINV')
  317.                  'SMBR' ('EXCO' chpres 'RETN' 'RETN')
  318.                  'IMPR' 0 ;
  319.  t1 = t0 '+' ('EXCO' deltat 'RETN' 'SCAL') ;
  320.  gradt1 mchamt = 'PENT'  $mt 'FACE' 'DIAMAN2' ('MOTS' 'SCAL')
  321.     ('MOTS' 'P1DX' 'P1DY') t1 tlim1 tlim2 ;
  322. * We check that the residuum is 0 if computed with
  323. * gradt1 and t1
  324.  jaco chpres1 dt1 = 'LAPN' 'VF' 'PROPCOST' 'RESI' 'IMPL'
  325.      $mt mu kappa cv rho0 v0 t1 gradv0 gradt1 mchamv mchamt
  326.      'VIMP' v0li1 'TAUI' taulim 'QIMP' qlim 'TIMP' tlim1 listinco ;
  327. * jacbid chpres1 dt = 'LAPN' 'VF' 'PROPCOST' 'RESI' 'IMPL'
  328. *    $mt mu kappa cv rho0 v0 t1 gradv0 gradt1 mchamv mchamt
  329. *   'QIMP' qlim 'TIMP' tlim1  listinco ;
  330.     mres1 = 'MAXIMUM' ('EXCO' chpres1 'RETN') 'ABS' ;
  331.  'MESSAGE' ('CHAINE' 'Maxi. chpres1 =' mres1) ;
  332.  'SI' ('>' mres1 1.e-5) ;
  333.     'MESSAGE' 'La méthode de Newton na pas converge en un pas.' ;
  334.     chm_err = 'KCHA' $mt 'CHAM' (chpres1 '-' chpres) ;
  335.     titt = 'CHAINE' 'Erreur sur le residu ' titglob ;
  336.     'TRACER' chm_err $mt 'TITRE' titt ;
  337.     'ERREUR' 5 ;
  338.  'FINSI' ;
  339. *
  340. * Résultats
  341. *
  342. 'SI' graph ;
  343. *
  344. * solutions exactes
  345. *
  346.   tn = solexc ;
  347.   chm_tnex = 'KCHA' $mt 'CHAM' tn ;
  348.   titt = 'CHAINE' 'Température exacte' titglob ;
  349.   'TRACER' chm_tnex $mt nbisov 'TITRE' titt ;
  350. *
  351. * graphe de convergence de la méthode itérative
  352. *
  353.     conver = (rv . 'METHINV' . 'CONVINV') ;
  354.     dimcon = 'DIME' conver ;
  355.     'SI' ('EGA' dimcon 1) ;
  356.        labs = 'PROG' 1. ;
  357.     'SINON' ;
  358.        labs = 'PROG' 1.D0 'PAS' 1.D0 dimcon ;
  359.     'FINSI' ;
  360.     lord = ('LOG' conver) '/' ('LOG' 10.D0) ;
  361.     evtot = 'EVOL' 'MANU' 'ITER' labs 'RESID' lord ;
  362.     titev = 'CHAINE' 'Historique de convergence' titglob ;
  363.     'DESSIN' evtot 'TITR' titev 'LEGE' ;
  364. *
  365. * solutions calculées
  366. *
  367.    tn = t1 ;
  368.    chm_tn = 'KCHA' $mt 'CHAM' tn ;
  369.    titt = 'CHAINE' 'Température calculée' titglob ;
  370.    'TRACER' chm_tn $mt nbisov 'TITRE' titt ;
  371. *
  372. * erreur
  373. *
  374.    titt = 'CHAINE' 'Abs (Température calculée - Température exacte)'
  375.          titglob ;
  376.    'TRACER' ('ABS' (chm_tnex '-' chm_tn)) $mt nbisov 'TITRE' titt ; 
  377.  'FINSI' ;
  378. *
  379. * Calcul des erreurs par rapport à la solution analytique
  380. *
  381.  vol = 'DOMA' $mt 'VOLUME' ;
  382.  echloc = (('MESURE' mt) '/' ('NBEL' mt)) ** 0.5 ;
  383.  tn = t1 ;
  384.  errlit = CALCERR  tn solexc ;
  385.  errl2t = CALCERR2 tn solexc vol ;
  386.  'MESSAGE' '-------------------------------------------------' ;
  387.  'MESSAGE' ('CHAINE' 'Erreur en norme LINF : ' errlit) ;
  388.  'MESSAGE' ('CHAINE' 'Erreur en norme L2   : ' errl2t) ;
  389.  'MESSAGE' '-------------------------------------------------' ;
  390. *'OPTION' 'DONN' 5 ;
  391.  'FINPROC' echloc errl2t ;
  392. * Fin de la procédure de calcul                             *
  393. *___________________________________________________________*
  394. *-----------------------------------------------------------
  395. * Paramètres du calcul
  396. *
  397. * lraff : nb raffinement du maillage (à chaque fois, on découpe
  398. *         les éléments en quatre).
  399.  'SI' complet ;
  400.    lraff  = 'LECT' 7 PAS 1 8 ;
  401.  'SINON' ;
  402.    lraff  = 'LECT' 25 PAS 1 28 ;
  403.  'FINSI' ;
  404. *
  405. *-----------------------------------------------------------*
  406. * Boucles sur les différents paramètres du calcul           *
  407.  precok = VRAI ;
  408. * ordre théorique en espace de la méthode
  409.  ordtth = 2 ;
  410. * erreur L2 max pour la solution (raffinement 2, complet=FAUX)
  411.  errtmax = 1.D-2 ;
  412. *
  413. *  Boucle sur les raffinements
  414. *
  415.      lh = 'PROG' ;
  416.      lerl2t = 'PROG' ;
  417.      'REPETER' iraff ('DIME' lraff)  ;
  418.         raff = 'EXTRAIRE' lraff &iraff ;
  419.         h errt = CALCUL raff ;
  420.         lh     = 'ET' lh     ('PROG' h ) ;
  421.         lerl2t = 'ET' lerl2t ('PROG' errt) ;
  422.      'FIN' iraff ;
  423.      lh = lh '/' ('EXTRAIRE' lh 1) ;
  424.      lh     = ('LOG' lh)     '/' ('LOG' 10.D0) ;
  425.      lerl2t = ('LOG' lerl2t) '/' ('LOG' 10.D0) ;
  426.      tl2 = 'EVOL' 'MANU' 'Long. carac.' lh
  427.                         'Err. tempér.' lerl2t ;
  428.  
  429. *
  430. * Recherche des ordres de convergence
  431. *
  432.      cpt tlipol = @POMI tl2 1 'IDEM' ;
  433.      ordt = cpt . 1 ;
  434.     'MESSAGE' ('CHAINE' 'ordre température=' ordt) ;
  435. *
  436. * Tracés graphiques
  437. *  
  438.     'SI' graph ;
  439.        tableg = 'TABLE' ;
  440.        tableg . 'TITRE' = 'TABLE' ;
  441.        tableg . 1 = 'MARQ CROI NOLI' ;
  442.        tableg . 'TITRE' . 1 = 'Erreur L2 calculée' ;
  443.        tableg . 2 = 'TIRR' ;                   
  444.        tableg . 'TITRE' . 2 = 'Erreur L2 interpolée' ;
  445.        titdest= 'CHAINE' 'Err L2 Tempér., ordre=' ordt ;
  446.        'DESSIN' (tl2 'ET' tlipol) 'TITRE' titdest tableg ;
  447.     'FINSI' ;
  448. *
  449. * Tests des ordres de convergence
  450. * Tests des erreurs L2 sur le maillage le plus fin dans le
  451. * cas complet=faux
  452. *
  453.        ordok = ordt > (ordtth '-' 0.9 ) ;
  454.       'SI' ('EGA' complet FAUX) ;
  455.        precok = 'ET' precok ('<' errt errtmax) ;
  456.      'FINSI' ;
  457.      'SI' ('NON' ordok) ;
  458.        'MESSAGE' 'On n_obtient pas un ordre de convergence correct' ;
  459.        'ERREUR' 5 ;
  460.      'FINSI' ;
  461.      'SI' ('NON' precok) ;
  462.        'MESSAGE' 'On n_obtient pas une précision correcte' ;
  463.        'ERREUR' 5 ;
  464.      'FINSI' ;
  465.  
  466.  'SI' interact ;
  467.     'OPTION' 'ECHO' 1 ;
  468.     'OPTION' 'DONN' 5 ;
  469.     'SI' logxmgr ;
  470. *     Sortie pour xmgr   
  471.        'OPTION' ECHO 0 ;
  472.        'OPTION' 'IMPR' 'file.txt' ;
  473.        ndim = 'DIME' lh ;
  474.        'REPETER' BL1 ndim ;
  475.          'MESSAGE' ('EXTRAIRE' lh &BL1) '  '  ('EXTRAIRE' lerl2t &BL1) ;
  476.        'FIN' BL1 ;
  477.        lh1 = 'EXTRAIRE' tlipol 'ABSC' ;
  478.        lerr = 'EXTRAIRE' tlipol 'ORDO' ;
  479.        ndim = 'DIME' lh1 ;
  480.        'OPTION' 'IMPR' 'file2.txt' ;
  481.        'REPETER' BL1 ndim ;
  482.           'MESSAGE' ('EXTRAIRE' lh1 &BL1) '  '  ('EXTRAIRE' lerr &BL1) ;
  483.        'FIN' BL1 ;
  484.        'OPTION' 'IMPR' 'poubelle.txt' ;
  485.        'FIN' ; 
  486.     'FINSI' ;
  487.  'FINSI' ;
  488.  
  489.  'MESSAGE' 'Tout s_est bien passé' ;
  490.  'FIN' ;
  491.  
  492.  
  493.  
  494.  
  495.  
  496.  
  497.  
  498.  
  499.  
  500.  
  501.  
  502.  
  503.  
  504.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales