Télécharger enc2dke.dgibi

Retour à la liste

* fichier : enc2dke.dgibi similar with enc2d but with K-epsilon
* formulation (semi explicit EFM1) and wall functions
*
* Adiabatic and 2D axisymetric containment
* He and steam injections
*
* With wall functions, QUAF-MSOMMET and QUAF-CENTREP1 are not available.
*
'OPTI' 'DIME' 2 'ELEM' 'CU20' 'MODE' 'AXIS' 'TRAC' 'PSC' ;
*
COMPLET = FAUX ;
GRAPH   = FAUX ;
'SI' COMPLET ;
  nbit = 4000   ;
  DT0  = 8.D-3  ;
  n1 = 5  ;
  n2 = 10 ;
  n3 = 20 ;
'SINO' ;
  nbit = 100   ;
  DT0  = 8.D-3 ;
  n1 = 5  ;
  n2 = 10 ;
  n3 = 20 ;
'FINSI' ;
*
* Mesh
*
p1 = 0.  0. ;
p2 = 0.1 0. ;
p3 = 1.  0. ;
p4 = 1.  2. ;                                                                                
p5 = 0.  2. ;
*
breche = p1 'DROI' n1 p2 ;
bas    = p2 'DROI' n2 p3 ;
paroid = p3 'DROI' n3 p4 ;
plaf   = p4 'DROI' (n1 + n2) p5 ;
axe    = p5 'DROI' n3 p1 ;
vtp    = bas 'ET' paroid 'ET' plaf ;
mt     = 'DALLER' (breche 'ET' bas) paroid plaf axe ;
*
*- Data for execrxt.procedur
*
rxt = 'TABLE' ;
rxt . 'VERSION' = 'V0' ;
rxt . 'vtf'     = mt ;
rxt . 'axe'     = axe ;
rxt . 'epsi'   = 1.e-4 ;
*
rxt . 'pi'     = 0.5 0.5 ;
*
rxt . 'ALGO'  = 'EFM1'    ;
rxt . 'DISCR' = 'LINE'    ;
rxt . 'KPRE'  = 'MSOMMET' ;
rxt . 'DT0'   = DT0 ;
*
rxt . 'MODTURB' = 'KEPSILON'  ;
rxt . 'FPAROI'  = VRAI ;
rxt . 'YP'      = 5.e-3 ;
*
rxt . 'HE'     = VRAI ;
rxt . 'VAPEUR' = VRAI ;
rxt . 'TF0'    = 20.0  ;
rxt . 'PT0'    = 1.0e5 ;
rxt . 'Yhe0'   = 0.0   ;
rxt . 'Yvap0'  = 0.1   ;
*
rxt . 'Breches' = 'TABLE' ;
rxt . 'Breches' . 'A' = 'TABLE' ;
rxt . 'Breches' . 'A' . 'Maillage' = breche ;
rxt . 'Breches' . 'A' . 'diru'  = (0. 1.) ;
rxt . 'Breches' . 'A' . 'scenario'          = 'TABLE' ;
rxt . 'Breches' . 'A' . 'scenario' . 't'    = 'PROG' 0.0     100.0   ;
rxt . 'Breches' . 'A' . 'scenario' . 'qair' = 'PROG' 0.0     0.0     ;
rxt . 'Breches' . 'A' . 'scenario' . 'qhe'  = 'PROG' 0.0011  0.0011 ;
rxt . 'Breches' . 'A' . 'scenario' . 'qeau' = 'PROG' 0.0011  0.0011 ;
rxt . 'Breches' . 'A' . 'scenario' . 'tinj' = 'PROG' 20.0    20.0   ;
*
rxt . 'GRAPH'   = GRAPH ;
rxt . 'DETMAT'  = VRAI ;
rxt . 'RENU'    = 'RIEN' ;
*
*- Transient
*
EXECRXT  nbit rxt ;
*
*- Tests
*  FD : Pourquoi le lissage ELNO(NOEL(un)) ?
'SI' ('NON' COMPLET) ;
  ERR1 = 0 ;
  un = 'ELNO' ('NOEL' rxt . 'TIC' . 'UN' rxt . 'GEO' . '$vtf')
        rxt . 'GEO' . '$vtf' ;
  'MESS' ' Max U ' ('MAXI' un) ' Min U ' ('MINI' un) ;
  test = 'ABS' (('MAXI' un) '-' 1.69) ;
  'MESS' ' Test =' test ;
  'SI' (test '>' 1.  ) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
*
  tf = rxt . 'TIC' . 'TF' ;
  'MESS' ' Max Tf' ('MAXI' tf) ' Min Tf' ('MINI' tf) ;
  test = 'ABS' (('MAXI' tf) '-' 20.0) ;
  'MESS' ' Test =' test ;
  'SI' (test '>' 1.) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
*
*- Specific test for wall functions
*  Each ten points on the wall boundary we check the velocity
*  FD : Pourquoi la vitesse normale en paroi n'est-elle pas nulle ?
  evunv1 = 'EVOL' 'CHPO' un 'UX' rxt . 'GEO' . 'menvf' ;
  evunv2 = 'EVOL' 'CHPO' un 'UY' rxt . 'GEO' . 'menvf' ;
  Lunv1  = 'EXTR' ('LECT' 1 'PAS' 5 71) ('EXTR' evunv1 'ORDO') ;
  Lunv2  = 'EXTR' ('LECT' 1 'PAS' 5 71) ('EXTR' evunv2 'ORDO') ;
  'LIST' lunv1 ;
  'LIST' lunv2 ;
  LRunv1 = 'PROG'
*-4.46838E-02  3.23026E-02  2.64945E-03  1.81767E-04  1.24049E-05
* 2.99048E-05  2.43521E-04  5.12656E-05  2.70603E-05  1.28875E-04
* 2.05958E-04 -2.63387E-04 -4.21780E-03 -0.10094     -4.46838E-02 ;
 -4.47721E-02  3.26589E-02  2.45288E-03  1.77112E-04  4.00912E-06
  4.16036E-05  2.50142E-04  5.36523E-05  2.53774E-05  1.24365E-04 
  2.01109E-04 -2.52286E-04 -4.06199E-03 -0.10516     -4.47721E-02 ;
  LRunv2 = 'PROG'
* 0.49916       1.4908      3.88036E-02  5.05601E-03  6.10067E-04
* 1.07301E-05  9.98014E-05  3.13809E-05  3.38167E-04  1.44275E-04
*-1.57168E-03 -6.76880E-04 -8.67024E-04  1.79192E-02  0.49916     ;
  0.49531       1.4537      3.65787E-02  4.90346E-03  5.80395E-04
  2.19061E-05  9.61838E-05  2.85129E-05  3.34633E-04  1.66757E-04 
 -1.48587E-03 -6.43691E-04 -8.39996E-04  1.72301E-02  0.49531     ;
*
  ERPS1  = 'SOMM' ('ABS' (LRunv1 '-' Lunv1)) ;
  ERPS2  = 'SOMM' ('ABS' (LRunv2 '-' Lunv2)) ;
  'MESS' 'ERPS1=' ERPS1 '  ' 'ERPS2=' ERPS2 ;
  'SI' (ERPS1 '>' 5.e-4) ; ERR1 = ERR1 '+' 1  ; 'FINS' ;
  'SI' (ERPS2 '>' 5.e-4) ; 'ERRE' 5 ; 'FINS' ;
*
  'SI' ('NEG' ERR1 0) ;
    'ERRE' 5 ;
  'FINS' ;
'FINS' ;
*
*- Plots devoted to enc2d... cases
*
'SI' rxt . 'GRAPH' ;
  tbt = rxt . 'TBT' ;
  tic = rxt . 'TIC' ;
*
  $vtf = rxt . 'GEO' . '$vtf' ;
  vtf  = 'DOMA'  $vtf 'MAILLAGE' ;
  'SI' ('EXIS' tic 'TP') ;
    $vtp = rxt . 'GEO' . '$vtp' ;
    vtp  = 'DOMA'  $vtp 'MAILLAGE' ;    
  'FINS' ;
*   
  un   = tic . 'UN';
  ung  = 'VECT' un 0.1 'UX' 'UY' 'JAUN' ;
  tf   = tic . 'TF' ;
  rho  = tic . 'RHO' ;
  rair = tic . 'RAIR' ;
  'SI' tbt . 'THE'    ; rhe  = tic . 'RHE'  ; 'FINS' ;
  'SI' tbt . 'TH2'    ; rh2  = tic . 'RH2'  ; 'FINS' ;
  'SI' tbt . 'TCO'    ; rco  = tic . 'RCO'  ; 'FINS' ;
  'SI' tbt . 'TCO2'   ; rco2 = tic . 'RCO2' ; 'FINS' ;
  'SI' tbt . 'VAPEUR' ; rvp  = tic . 'RVP'  ; 'FINS' ;
*
  axe = 'CHAN' rxt . 'DISCR' axe ;
  ixe = 'INVE' axe ;
*
  evauz = 'EVOL' 'CHPO' ('EXCO' un 'UY') ixe ;
  'DESS' evauz
  'TITR' 'Velocity with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
*
  evatf = 'EVOL' 'CHPO' tf  ixe ;
  'DESS' evatf
  'TITR' 'Gas temperature with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  'TRAC' tf vtf vtp 'TITR' ' Temperature' ;
  evarh = 'EVOL' 'CHPO' rho ixe ;
  'DESS' evarh
  'TITR' 'Gas density with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  'TRAC' rho vtf ('CHAN' 'LINE' vtp) ung 'TITR' ' Density & velocity' ;
*
  'SI' tbt . 'THE'     ;
    evahe  = 'EVOL' 'CHPO' rhe  ixe ;
    'DESS' evahe
    'TITRE' 'Helium density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rhe vtf vtp 'TITR' ' He density' ;
  'FINS' ;
  'SI' tbt . 'TH2'     ;
    evah2  = 'EVOL' 'CHPO' rh2  ixe ;
    'DESS' evah2
    'TITR' 'Hydrogen density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rh2 vtf vtp 'TITR' ' H2 density' ;
  'FINS' ;
  'SI' tbt . 'TCO'     ;
    evaco  = 'EVOL' 'CHPO' rco  ixe ;
    'DESS' evaco
    'TITR' 'CO density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rco vtf vtp 'TITR' ' CO density' ;
  'FINS' ;
  'SI' tbt . 'TCO2'    ;
    evaco2 = 'EVOL' 'CHPO' rco2 ixe ;
    'DESS' evaco2
    'TITR' 'CO2 density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rco2 vtf vtp 'TITR' ' CO2 density' ;
  'FINS' ;
  'SI' tbt . 'VAPEUR' ;
    evavap = 'EVOL' 'CHPO' rvp ixe ;
    'DESS' evavap
    'TITR' 'Steam density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rvp vtf vtp 'TITR' ' Steam density' ;
  'FINS' ;
*
* Wall temperature or air density (in cases enc2d with wall temperature 
* only air is involved ; hence rair=rho and rho is plotted above))
  'SI' ('EXIS' tic 'TP') ;
    'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  'SINO' ;
    evarair = 'EVOL' 'CHPO' rair ixe ;
    'DESS' evarair
    'TITR' 'Air density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rair vtf vtp 'TITR' ' Air density' ;
  'FINS' ;
*
  'SI' ('EXIS' tic 'KN') ;
    'TRAC' tic . 'KN' vtf vtp 'TITR' ' KN' ;
    'TRAC' tic . 'EN' vtf vtp 'TITR' ' EN' ;
  'FINS' ;
*
'FINS' ;
*
* Specific plots for wall functions
'SI' rxt . 'GRAPH' ;
  TAB1 = 'TABLE' ;
  TAB1 . 'TITRE' = TABLE ;
  TAB1 . 'TITRE' . 1  = 'MOT' ' UX'  ;
  TAB1 . 'TITRE' . 2  = 'MOT' ' UY'  ;
  TAB1 . 1 = ' REGU MARQ TRIL' ;
  TAB1 . 2 = ' REGU MARQ TRIU' ;
  'DESS' (evunv1 'ET' evunv2)
  'TITR' 'Velocity with the wall curvilinear abscissa' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 's' 'TITY' ' m/s' 'LEGE' tab1 ;
'FINS' ;
*
FIN ;
 
 
 
 
 
 
 
 
 
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales