Exemples de jeux de données Cast3M

* fichier : enc2dQ.dgibi (similar to enc2d except quadratic elements QUAF)
*
* Adiabatic and 2D axisymetric containment
* H2, He and CO2 injections
*
'OPTI' 'DIME' 2 'ELEM' 'CU20' 'MODE' 'AXIS' 'TRAC' 'PSC' 'DENS' 1. ;
*
COMPLET = FAUX ;
GRAPH   = FAUX ;
'SI' COMPLET ;
  nbit = 100 ;
  DT0  = 1.  ;
  n1 = 5  ;
  n2 = 10 ;
  n3 = 20 ;
'SINO' ;
  nbit = 40 ;
  DT0  = 0.1 ;
  n1 = 3  ;
  n2 = 5 ;
  n3 = 10 ;
'FINSI' ;
*
* Mesh
*
p1 = 5.D-4 0. ;
p2 = 0.1   0. ;
p3 = 1.    0. ;
p4 = 1.    2. ;                                                                                
p5 = 5.D-4 2. ;
*
breche = p1 'DROI' n1 p2 ;
bas    = p2 'DROI' n2 p3 ;
paroid = p3 'DROI' n3 p4 ;
plaf   = p4 'DROI' (n1 + n2) p5 ;
axe    = p5 'DROI' n3 p1 ;
vtp    = bas 'ET' paroid 'ET' plaf ;
mt     = 'DALLER' (breche 'ET' bas) paroid plaf axe ;
*
*- Data for execrxt.procedur
*
rxt = 'TABLE' ;
rxt . 'VERSION' = 'V0' ;
rxt . 'vtf'     = mt ;
rxt . 'axe'     = axe ;
rxt . 'epsi'   = 1.e-4 ;
*
rxt . 'pi'     = 0.5 0.5 ;
*
rxt . 'DISCR' = 'QUAF' ;
rxt . 'KPRE'  = 'MSOMMET' ;
rxt . 'DT0'   = DT0 ;
rxt . 'CORTEMP' = faux ;
*
rxt . 'MODTURB' = 'LMEL'  ;
rxt . 'LMEL'    = 0.05  ;
*
rxt . 'HE'    = VRAI ;
rxt . 'H2'    = VRAI ;
rxt . 'CO2'   = VRAI ;
rxt . 'TF0'   = 20.0  ;
rxt . 'PT0'   = 1.0e5 ;
rxt . 'Yhe0'  = 0.0   ;
rxt . 'Yh20'  = 0.0   ;
rxt . 'Yco20' = 0.0   ;
*
rxt . 'Breches' = 'TABLE' ;
rxt . 'Breches' . 'A' = 'TABLE' ;
rxt . 'Breches' . 'A' . 'Maillage' = breche ;
rxt . 'Breches' . 'A' . 'diru'  = (0. 1.) ;
rxt . 'Breches' . 'A' . 'scenario'          = 'TABLE' ;
rxt . 'Breches' . 'A' . 'scenario' . 't'    = 'PROG' 0.0     100.0   ;
rxt . 'Breches' . 'A' . 'scenario' . 'qair' = 'PROG' 0.0     0.0     ;
rxt . 'Breches' . 'A' . 'scenario' . 'qhe'  = 'PROG' 0.0011  0.0011 ;
rxt . 'Breches' . 'A' . 'scenario' . 'qh2'  = 'PROG' 0.0011  0.0011 ;
rxt . 'Breches' . 'A' . 'scenario' . 'qco2' = 'PROG' 0.0011  0.0011 ;
rxt . 'Breches' . 'A' . 'scenario' . 'tinj' = 'PROG' 20.0    20.0   ;
*
rxt . 'GRAPH'   = GRAPH ;
rxt . 'DETMAT'  = VRAI ;
rxt . 'RENU'    = 'RIEN' ;
*
*- Transient
*
EXECRXT  nbit rxt ;
*
*- Tests
*
*  probleme en 32 bits avec gfortran 14.1
'SI' ('NON' COMPLET) ;
 ERR1 = 0 ;
'SI' (2**31 > 0) ;
  un = rxt . 'TIC' . 'UN';
  'MESS' ' Max U ' ('MAXI' un) ' Min U ' ('MINI' un) ;
  test = 'ABS' (('MAXI' un) - 2.1261) ;
  'MESS' ' Test =' test ;
  'SI' (test '>' 0.6  ) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
'FINSI';
*
  tf = rxt . 'TIC' . 'TF' ;
  'MESS' ' Max Tf' (maxi tf) ' Min Tf' (mini tf) ;
  test = abs ((maxi tf) - 20.972);
  'MESS' ' Test =' test;
  'SI' (test '>' 1.0) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  list test;
  list (test '>' 1.0);
  list err1;
*
  'SI' ('NEG' ERR1 0) ;
    'ERRE' 5 ;
  'FINS' ;
'FINS' ;
*
*- Plots devoted to enc2d... cases
*
'SI' rxt . 'GRAPH' ;
  tbt = rxt . 'TBT' ;
  tic = rxt . 'TIC' ;
*
  $vtf = rxt . 'GEO' . '$vtf' ;
  vtf  = 'DOMA'  $vtf 'MAILLAGE' ;
  'SI' ('EXIS' tic 'TP') ;
    $vtp = rxt . 'GEO' . '$vtp' ;
    vtp  = 'DOMA'  $vtp 'MAILLAGE' ;    
  'FINS' ;
*   
  un   = tic . 'UN';
  ung  = 'VECT' un 0.1 'UX' 'UY' 'JAUN' ;
  tf   = tic . 'TF' ;
  rho  = tic . 'RHO' ;
  rair = tic . 'RAIR' ;
  'SI' tbt . 'THE'    ; rhe  = tic . 'RHE'  ; 'FINS' ;
  'SI' tbt . 'TH2'    ; rh2  = tic . 'RH2'  ; 'FINS' ;
  'SI' tbt . 'TCO'    ; rco  = tic . 'RCO'  ; 'FINS' ;
  'SI' tbt . 'TCO2'   ; rco2 = tic . 'RCO2' ; 'FINS' ;
  'SI' tbt . 'VAPEUR' ; rvap = tic . 'RVAP' ; 'FINS' ;
*
  axe = 'CHAN' rxt . 'DISCR' axe ;
  ixe = 'INVE' axe ;
*
  evauz = 'EVOL' 'CHPO' ('EXCO' un 'UY') ixe ;
  'DESS' evauz
  'TITR' 'Velocity with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
*
  evatf = 'EVOL' 'CHPO' tf  ixe ;
  'DESS' evatf
  'TITR' 'Gas temperature with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  'TRAC' tf vtf vtp 'TITR' ' Temperature' ;
  evarh = 'EVOL' 'CHPO' rho ixe ;
  'DESS' evarh
  'TITR' 'Gas density with the z axis' 'MIMA'
  'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  'TRAC' rho vtf ('CHAN' 'LINE' vtp) ung 'TITR' ' Density & velocity' ;
*
  'SI' tbt . 'THE'     ;
    evahe  = 'EVOL' 'CHPO' rhe  ixe ;
    'DESS' evahe
    'TITRE' 'Helium density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rhe vtf vtp 'TITR' ' He density' ;
  'FINS' ;
  'SI' tbt . 'TH2'     ;
    evah2  = 'EVOL' 'CHPO' rh2  ixe ;
    'DESS' evah2
    'TITR' 'Hydrogen density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rh2 vtf vtp 'TITR' ' H2 density' ;
  'FINS' ;
  'SI' tbt . 'TCO'     ;
    evaco  = 'EVOL' 'CHPO' rco  ixe ;
    'DESS' evaco
    'TITR' 'CO density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rco vtf vtp 'TITR' ' CO density' ;
  'FINS' ;
  'SI' tbt . 'TCO2'    ;
    evaco2 = 'EVOL' 'CHPO' rco2 ixe ;
    'DESS' evaco2
    'TITR' 'CO2 density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rco2 vtf vtp 'TITR' ' CO2 density' ;
  'FINS' ;
  'SI' tbt . 'VAPEUR' ;
    evavap = 'EVOL' 'CHPO' rvap ixe ;
    'DESS' evavap
    'TITR' 'Steam density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rvap vtf vtp 'TITR' ' Steam density' ;
  'FINS' ;
*
* Wall temperature or air density (in cases enc2d with wall temperature 
* only air is involved ; hence rair=rho and rho is plotted above))
  'SI' ('EXIS' tic 'TP') ;
    'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  'SINO' ;
    evarair = 'EVOL' 'CHPO' rair ixe ;
    'DESS' evarair
    'TITR' 'Air density with the z axis' 'MIMA'
    'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
    'TRAC' rair vtf vtp 'TITR' ' Air density' ;
  'FINS' ;
*
  'SI' ('EXIS' tic 'KN') ;
    'TRAC' tic . 'KN' vtf vtp 'TITR' ' KN' ;
    'TRAC' tic . 'EN' vtf vtp 'TITR' ' EN' ;
  'FINS' ;
'FINS' ;
*
FIN ;