Exemples de jeux de données Cast3M

* fichier :  elem.dgibi
'OPTI' echo 0 ;
************************************************************************
************************************************************************
************************************************************************
* NOM         : ELEM
* DESCRIPTION : Test de verification de l'operateur ELEM
*               En particulier l'option APPUYE ELEM qui est nouvelle
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stephane GOUNAND (CEA/DES/ISAS/DM2S/SEMT/LTA)
*               mel : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 01/08/2025, version initiale
* HISTORIQUE : v1, 01/08/2025, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact=faux ;
*
lok = vrai ;
*
'DEBP' egamail mail1*'MAILLAGE' mail2*'MAILLAGE' ;
   lega = 'EGA' (nbel ('DIFF' mail1 mail2)) 0 ;
'FINP' lega ;
*
* Restitue la plus longue en premier
'DEBP' lis2 n*'ENTIER' ;
'SI' ('EGA' n (n '/' 2 '*' 2)) ;
   'SI' ('EGA' n 2) ;
      l1 = 'LECT' 1 ; l2 = 'LECT' 2 ;
   'SINO' ;
      l1 = 'LECT' 1 'PAS' 2 ('-' n 1) ;
      l2 = 'LECT' 2 'PAS' 2 n ;
   'FINS' ;
'SINO' ;
   'SI' ('EGA' n 1) ;
      l1 = 'LECT' 1 ;
      l2 = 'LECT' ;
   'SINO' ;
      l1 = 'LECT' 1 'PAS' 2 n ;
      l2 = 'LECT' 2 'PAS' 2 ('-' n 1) ;
   'FINS' ;
'FINS' ;
'FINP' l1 l2 ;
*
'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
'OPTI' 'DENS' 0.2 ;
*'OPTI' 'DENS' 0.333333 ;
pA = 0. 0. ; pB = 1. 0. ; pC = 1. 1. ; pD = 0. 1. ;
*
lAB = 'DROI' pA pB ; lBC = 'DROI' pB pC ;
lCD = 'DROI' pC pD ; lDA = 'DROI' pD pA ;
mt = 'DALL'  lAB  lBC  lCD  lDA ;
*
nmt = 'NBEL' mt ;
l2 l1 = lis2 nmt ;
mt1 = 'ELEM' mt l1 ; mt2 = 'ELEM' mt l2 ;
mt2n = 'CHAN' mt2 'TRI3' ;
mtn = mt1 'ET' mt2n ;
cmtn = 'CONT' mtn ;
*
* Test 1 : 1 arête du bord : 1 seul element associe
*
are = 'ELEM' cmtn ('/' ('+' ('NBEL' cmtn) 1) 2) ;
eleare = 'ELEM' mtn appuye elements are ;
tst = 'EGA' ('NBEL' eleare) 1 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre nb. elem appuye are .neq. 1' ; 'FINS' ;
lok = lok 'ET' tst ;
pare = 'CHAN' are 'POI1' ;
peleare = 'CHAN' eleare 'POI1' ;
pint = 'INTE' pare peleare ;
tst = egamail pint pare ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre pt. elem appuye are .neq. pt inte' ; 'FINS' ;
lok = lok 'ET' tst ;
*
* Test 2 : 1 arête interne : 2 elements associes
*
aretot = 'CHAN' 'LIGNE' mtn ;
areint = 'DIFF' aretot cmtn ;
areint1 = 'ELEM' areint ('/' ('+' ('NBEL' areint) 1) 2) ;
eleare1 = 'ELEM' mtn appuye elements areint1 ;
tst = 'EGA' ('NBEL' eleare1) 2 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre nb. elem appuye areint .neq. 2' ; 'FINS' ;
lok = lok 'ET' tst ;
pareint1 = 'CHAN' areint1 'POI1' ;
peleare1 = 'CHAN' eleare1 'POI1' ;
pint1 = 'INTE' pareint1 peleare1 ;
tst = egamail pint1 pareint1 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre pt. elem appuye areint .neq. pt inte' ; 'FINS' ;
lok = lok 'ET' tst ;
*
* Test 3 : 1 bord sans coin de n elements : n elements associes
*
elebas = 'ELEM' mtn appuye elements lAB ;
nelebas = 'NBEL' elebas ;
nlAB = 'NBEL' lAB ;
tst = 'EGA' nelebas nlAB ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre elem appuye lAB' ; 'FINS' ;
lok = lok 'ET' tst ;
pAB = 'CHAN' lAB 'POI1' ;
pelebas = 'CHAN' elebas 'POI1' ;
pintbas = 'INTE' pAB pelebas ;
tst = egamail pintbas pAB ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre pt. elem appuye lAB .neq. pt inte' ; 'FINS' ;
lok = lok 'ET' tst ;
*
* Test 3 : n elements quadratiques : n elements lineaire associes
*
mtn3 = 'ELEM' mtn 'TRI3' ; mtn4 = 'DIFF' mtn mtn3 ;
lis3 lis3b = lis2 ('NBEL' mtn3) ;
lis4 lis4b = lis2 ('NBEL' mtn4) ;
*
mtnx = ('ELEM' mtn3 lis3) 'ET' ('ELEM' mtn4 lis4) ;
*
mtnq = 'CHAN' mtn quad ;
mtnq6 = 'ELEM' mtnq 'TRI6' ;
mtnq8 = 'ELEM' mtnq 'QUA8' ;
mtnqx1 = ('ELEM' mtnq6 lis3) 'ET' ('ELEM' mtnq8 lis4) ;
mtnqx2 = 'ELEM' mtnq 'APPU' 'ELEM' mtnx ;
*
tst = egamail mtnqx1 mtnqx2 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre elem quad appuye line' ; 'FINS' ;
lok = lok 'ET' tst ;
*
mtnf = 'CHAN' mtnq quaf ;
mtnf7 = 'ELEM' mtnf 'TRI7' ;
mtnf9 = 'ELEM' mtnf 'QUA9' ;
mtnfx1 = ('ELEM' mtnf7 lis3) 'ET' ('ELEM' mtnf9 lis4) ;
mtnfx2 = 'ELEM' mtnf 'APPU' 'ELEM' mtnx ;
*
tst = egamail mtnfx1 mtnfx2 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre elem quaf appuye line' ; 'FINS' ;
lok = lok 'ET' tst ;
*
mtnfx3 = 'ELEM' mtnf 'APPU' 'ELEM' mtnqx1 ;
*
tst = egamail mtnfx3 mtnfx2 ;
'SI' ('NON' tst) ; 'MESS' '!!!! erre elem quaf appuye quad' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
'SI' ('NON' lok) ;
   'MESSAGE' ('CHAINE' 'Il y a eu des erreurs') ;
   'ERREUR' 5 ;
'SINON' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file ELEM
*
'FIN' ;