Télécharger la plaquette Cast3M


fr en

Télécharger ddi.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  ddi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *             Test Ddi.dgibi: Jeux de données         *
  5. *             -------------------------------         *
  6. *                                                     *
  7. OPTI ECHO 0 DIME 2 ELEM QUA8 MODE AXIS;                                  
  8. *                                                                               
  9. *******************************************************          
  10. *                TEST DE VALIDATION                   *
  11. *                ------------------                   *
  12. *        MATERIAU VISCO-PLASTIQUE ENDOMMAGEABLE       *                 
  13. *     MODELE A DEUX DEFORMATIONS INELASTIQUES (DDI)   *
  14. *                                                     *
  15. *  MAILLAGE:                                          *
  16. *     EPROUVETTE CYLINDRIQUE (AXISYMETRIQUE)          * 
  17. *                                                     *
  18. *  CHARGEMENT:                                        *
  19. *     DEPLACEMENT IMPOSE MONOTONE CROISSANT           *
  20. *******************************************************          
  21. *
  22. *              
  23.    P1 = 0 0;          P2 = 5E-3 0;    
  24.    P3 = 5E-3 50E-3;   P4 = 0 50E-3;              
  25. *                                                                               
  26.    L1 = P1 P2 DROIT 1  ;                                                        
  27.    L2 = P2 P3 DROIT 1 ;                                                         
  28.    L3 = P3 P4 DROIT 1  ;                                                        
  29.    L4 = P4 P1 DROIT 1 ;                                                         
  30. *
  31. * Maillage
  32. * --------                                                                               
  33.    EPROU = L1 L2 L3 L4 DALLER PLAN ;                                            
  34. *
  35. * Conditions aux limites
  36. * ----------------------                                                                             
  37.    CL1 = BLOQ L1 UZ ;                                                                                                                      
  38.    CL2 = BLOQ L3 UZ;                                                                                              
  39.    CL3 = BLOQ L4 UR ;                                                           
  40.    CL = CL1 ET CL2 ET CL3 ;                                                                                                             
  41. *  
  42. * Modele de calcul 
  43. * ----------------                                                                            
  44. mo = 'MODE' eprou 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'   
  45.        'VISCOPLASTIQUE' 'DDI' ; 
  46. *
  47. * Materiau: Zirconium alpha 200°C
  48. * -------------------------------
  49. ma = 'MATE' mo 'YOUN' 8.2D10 'NU' 0.36   
  50.        'RP0' 135.D6 'QP' -60.D6 'BP' 120 
  51.        'CP1' 34000.D6 'DP1' 250.
  52.        'CP2' 60000.D6 'DP2' 3000. 'KS' 960.D6 'N' 3.4
  53.        'RV0' 70.D6 'QV' -20.D6 'BV' 10. 
  54.        'CV1' 24000.D6 'DV1' 300.
  55.        'CV2' 9000.D6 'DV2' 3000. 'CVP1' 0. 'CVP2' 0.;
  56. *
  57. * Temps
  58. * -----
  59.    EPSMAX=0.01;
  60.    EPSPT=0.001;
  61.    NCALC=20;
  62.    TFIN=EPSMAX/EPSPT;
  63.    DT0=TFIN/NCALC;
  64. *
  65. * Chargement
  66. * ----------
  67.    DEP0=DEPI CL2 (EPSMAX*0.05);
  68.    LI1 = PROG 0. tfin ;
  69.    LI2 = PROG 0. 1. ;                            
  70.    EV = EVOL MANU T LI1 LOAD LI2 ;                                            
  71.    CHA = CHAR 'DIMP' DEP0 EV ;
  72. *                                                                                           
  73. * Calcul
  74. * ------
  75.    TAB = TABLE ;
  76.    TAB.'BLOCAGES_MECANIQUES' = CL;
  77.    TAB.'CARACTERISTIQUES' = MA;
  78.    TAB.'MODELE' = MO;
  79.    TAB.'CHARGEMENT' = CHA;
  80.    LIS=PROG 0. pas dt0 tfin;
  81.    TAB.'TEMPS_CALCULES' = LIS;         
  82.    PASAPAS TAB ;
  83. *  
  84. *  Comparaison avec les valeurs de reference 
  85. *  -----------------------------------------
  86.   dim0 = 'DIME' ( tab .'TEMPS' ) - 1;
  87.   var0 = tab .'VARIABLES_INTERNES'. dim0 ;
  88.   sigm0= tab .'CONTRAINTES'.dim0; 
  89.   p0 =  MAXI (EXCO var0 'VIPW');
  90.   v0 =  MAXI ( EXCO var0 'V');
  91.   sig0 = MAXI ('EXCO' sigm0 'SMZZ'); 
  92. *
  93.   p_th = 4.17896E-03;
  94.   v_th = 3.14432E-03;
  95.   sig_th = 2.19491E+08;
  96.   errp = 100. * (ABS((p_th - p0)/p_th));
  97.   errv = 100. * (ABS((v_th - v0)/v_th));
  98.   errsig = 100. * (ABS((sig_th - sig0)/sig_th));
  99. *
  100.   SI ( (errp > 0.1) OU (errv > 0.1) OU (errsig > 0.1));
  101.     ERRE 5 ;
  102.   SINON;
  103.     ERRE 0 ;  
  104.   FINSI;
  105. *
  106. FIN;
  107.  
  108.  
  109.  
  110.  
  111.  
  112.  
  113.  
  114.  
  115.  
  116.  
  117.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales