Télécharger la plaquette Cast3M


fr en

Télécharger condmass.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  condmass.dgibi
  2. *
  3. ********************* CAS TEST : condmass.dgibi ********************
  4. *
  5. * Test de la prise en compte de la condensation en masse dans la procédure métier execrxt.
  6. *
  7. * On considère une enceinte de 100 m3 isolée thermiquement. Initialement, la pression et la
  8. * température sont P0=3bar et T0=100°C ; l'enceinte contient un mélange air-vapeur d'eau saturé
  9. * en vapeur (l'humidité relative est donc de 100%, soit Pvap = Psat(T0)).
  10. *
  11. * La condensation en masse est provoquée par une injection massive d'azote froide par une brèche
  12. * de section Sinj localisée au centre du plafond de l'enceinte et dirigée vers le bas. La durée, le
  13. * débit massique et la température de l'azote sont les suivants : tinj=10s ; Qinj=10 kg/s ;
  14. * Tinj=-100°C.
  15. *
  16. * L'enceinte est 2D plan, de section carrée, de coté égal à 10m.
  17. * La longueur de la brèche Linj est de 0.1m.
  18. *
  19. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' 'TRAC' 'X' 'EPTR' 10 ;
  20. 'DENS' 1. ;
  21. *
  22. COMPLET = faux ;
  23. GRAPH   = faux ;
  24. CTRL    = faux ;
  25. *
  26. *
  27. * Mesh
  28. *
  29. *
  30. *
  31. * Cavité de taille LX*LY maillée avec des quadrangles
  32. * epsi0 = Characteristic length for points comparison
  33. * Linj  = Breach length
  34. * Ninj  = Number of elements at the half-breach length
  35. * MT    = Maillage du domaine fluide
  36. LX    = 10. ;
  37. LY    = 10. ;
  38. epsi0 = 1.e-5 ;
  39. Linj  = 0.1 ;
  40. Ninj  = 2 ;
  41. *
  42. *
  43. * PM0-------PMM--------PMI--P0--PPI--------PPM-------PP0
  44. PM0 = (-1. '*' LX '/' 2.)           0. ;
  45. PMI = (-1. '*' LINJ '/' 2.)         0. ;
  46. PMM = (LINJ '+' LX '/' 4. '*' -1.)  0. ;
  47. P0  = 0.                            0. ;
  48. PPI = (LINJ '/' 2.)                 0. ;
  49. PP0 = (LX '/' 2.)                   0. ;
  50. PPM = (LINJ '+' LX '/' 4.)          0. ;
  51.  
  52. Lfin  = Linj '/' Ninj '/' 2 ;
  53. Lgros = Lfin '*' 20 ; 
  54. C_MM  = pm0 'DROI' 'DINI' Lfin  'DFIN' Lgros pmm ;
  55. C_M   = pmm 'DROI' 'DINI' Lgros 'DFIN' Lfin  pmi ;
  56. C_INJ = pmi 'DROI' ninj p0 'DROI' ninj ppi ;
  57. C_P   = ppi 'DROI' 'DINI' Lfin  'DFIN' Lgros ppm ;
  58. C_PP  = ppm 'DROI' 'DINI' Lgros 'DFIN' Lfin pp0 ;
  59. C_HAU = C_MM 'ET' C_M 'ET' C_inj 'ET' C_P 'ET' C_PP ;
  60.  
  61. MT1    = c_hau 'TRAN' 'DINI' Lfin 'DFIN' Lgros (0. (-1. '*' (LY/2.))) ;
  62. C_DRO1 = 'COTE' 2 mt1 ;
  63. C_BAS1 = 'INVE' ('COTE' 3 mt1) ;
  64. C_GAU1 = 'COTE' 4 mt1 ;
  65. MT2    = c_bas1 'TRAN' 'DINI' Lgros 'DFIN' Lfin (0. (-1. '*' (LY/2.))) ;
  66. C_DRO2 = 'COTE' 2 mt2 ;
  67. C_BAS  = 'COTE' 3 mt2 ;
  68. C_GAU2 = 'COTE' 4 mt2 ;
  69. C_DRO  = c_dro1 'ET' c_dro2 ;
  70. C_GAU  = c_gau2 'ET' c_gau1 ;
  71. MT     = mt1 'ET' mt2 ;
  72.  
  73. *
  74. * Mesh Control
  75. 'SI' ctrl ;
  76.    'TRAC' (c_bas 'ET' c_dro 'ET' c_hau 'ET' c_gau) ;
  77.    'TRAC' mt ;
  78. 'FINS' ;
  79. *
  80. *
  81. * Data for execrxt.procedur
  82. *
  83. *
  84. rxt = 'TABLE' ;             
  85. rxt . 'VERSION' = 'V0' ;
  86. rxt . 'vtf'     = mt ;
  87. rxt . 'epsi'    = epsi0 ;
  88. rxt . 'pi'      = 0. (LY '/' -2.) ;
  89.  
  90. rxt . 'DISCR'   = 'LINE' ;
  91. rxt . 'KPRE'    = 'MSOMMET' ;
  92.  
  93. rxt . 'CORLIM'  = vrai ;
  94. rxt . 'CONDMAS' = vrai ;
  95. rxt . 'CORTEMP' = faux ;
  96.  
  97. rxt . 'MODTURB' = 'LMEL' ;
  98. rxt . 'LMEL'    = Linj '/' 2. ;
  99.  
  100. rxt . 'DETMAT'  = vrai ;
  101. rxt . 'RENU'    = 'RIEN' ;
  102.  
  103. *
  104. * Chronologie
  105. * DT0   = Time step (s)
  106. * epsdt = Delay between phases 1 and 2 (s)
  107. * tph1  = N2 inerting phase duration (s)
  108. * tph2  = Post-inerting relaxation phase duration (s)
  109. DT0   = 0.1 ;
  110. epsdt = DT0 ;
  111. 'SI' COMPLET ;
  112.   tph1  = 10. ;
  113.   tph2  = 40. ;
  114. 'SINO' ;
  115.   tph1  = 5. '*' DT0 ;
  116.   tph2  = 5. '*' DT0 ;
  117. 'FINS' ;
  118.  
  119. t0 = 0.D0 ;
  120. t1 = t0  '+' tph1 ; t11 = t1 '+' epsdt ;
  121. t2 = t11 '+' tph2 '-' epsdt ;
  122.  
  123. *
  124. * Initial conditions
  125. * PT0   = Pressure
  126. * TF0   = Temperature
  127. * Yvap0 = Steam mass fraction (Yair0=1-Yvap0)
  128. PT0   = 3.e5 ;
  129. TF0   = 373.15 - 273.15 ;
  130. Yvap0 = 0.243 ;
  131. *HR=0.5  rxt . 'Yvap0'  = 0.113 ;
  132. *HR=1.   rxt . 'Yvap0'  = 0.243 ;
  133. *HR=1.05 rxt . 'Yvap0'  = 0.257 ;
  134. *HR=1.5  rxt . 'Yvap0'  = 0.393 ;
  135.  
  136. rxt . 'PT0'    = PT0 ;
  137. rxt . 'TF0'    = TF0 ;
  138. rxt . 'N2'     = vrai ;
  139. rxt . 'Yn20'   = 0. ;
  140. rxt . 'VAPEUR' = vrai ;
  141. rxt . 'Yvap0'  = Yvap0 ;
  142.  
  143. *
  144. * Boundary conditions (Breches)
  145. Tn2_1 = -100. ; Tn2_2 = TF0 ;
  146. Qn2_1 = 10.   ; Qn2_2 = 0. ;
  147.  
  148. RXT . 'Breches' = table ;
  149. RXT . 'Breches' . 'A' = table ;
  150. RXT . 'Breches' . 'A' . 'Maillage' = c_inj ;
  151. RXT . 'Breches' . 'A' . 'diru'     = (0. -1.) ;
  152. RXT . 'Breches' . 'A' . 'scenario' = 'TABLE' ;
  153. RXT . 'Breches' . 'A' . 'scenario' . 't'    = 'PROG' t0    t1    t11   t2    ;  
  154. RXT . 'Breches' . 'A' . 'scenario' . 'qair' = 'PROG' 0.    0.    0.    0.    ;
  155. RXT . 'Breches' . 'A' . 'scenario' . 'qeau' = 'PROG' 0.    0.    0.    0.    ;
  156. RXT . 'Breches' . 'A' . 'scenario' . 'qn2'  = 'PROG' Qn2_1 Qn2_1 Qn2_2 Qn2_2 ;
  157. RXT . 'Breches' . 'A' . 'scenario' . 'tinj' = 'PROG' Tn2_1 Tn2_1 Tn2_2 Tn2_2 ;
  158.  
  159. 'SAUT' 2 'LIGN' ;
  160. 'MESS' '------------------------------------------------' ;
  161. 'MESS' 'Injection ' ;
  162. 'MESS' '------------------------------------------------' ;
  163. 'MESS' 't      :' ' ' t1    ' ' t2 ;
  164. 'MESS' 'Tinj   :' ' ' Tn2_1 ' ' Tn2_2 ;
  165. 'MESS' 'Azote  :' ' ' Qn2_1 ' ' Qn2_2 ;
  166. 'MESS' '------------------------------------------------' ;
  167.  
  168. 'SI' ctrl ;
  169.   rxt . 'GRAPH'  = faux ;
  170.   rxt . 'DT0'    = DT0 ;
  171.   execrxt  0 rxt ;
  172.   'MESS' ' Volume ' ('SOMT' rxt . 'GEO' . 'Diag') ;
  173. 'FINS' ;
  174. rxt . 'GRAPH' = GRAPH ;
  175.  
  176. *
  177. *
  178. * Transient computation
  179. *
  180. *
  181. * nbit = number of time steps
  182. *
  183. * The numerical diffusion is set to zero for the equation devoted to fluid temperature
  184. *'SI' COMPLET ;
  185. *   rxt . 'TBT' . 'RTF' . '1TSCA' . 'KOPT' . 'CMD' = 0. ;
  186. *'FINS' ;
  187.  
  188. *
  189. * N2 interting phase
  190. rxt . 'DT0'    = DT0 ;
  191. nbit  = 'ENTI' (t1 '-' t0 / DT0 '+' (DT0 '/' 100.)) ;
  192. execrxt  nbit rxt ;
  193. 'SI' ctrl ;
  194.   'OPTI' 'SAUV' 'condmass_1.sauv' ; 'SAUV' ;
  195. 'FINS' ;
  196.  
  197. TEMP_1 = rxt . 'TIC' . 'TF' ;
  198. PSAT_1 = 'VARI' 'PSATT' (rxt . 'TIC' . 'TF' + 273.15) ;
  199. RSAT_1 = 'VARI' 'ROVAP' PSAT_1 (rxt . 'TIC' . 'TF' + 273.15) ;
  200. HR_1   = rxt . 'TIC' . 'RVP' '/' RSAT_1 ;
  201. YN2_1  = rxt . 'TIC' . 'YN2' ;
  202. YVAP_1 = rxt . 'TIC' . 'YVAP' ;
  203.  
  204. *
  205. * Post-inerting phase (the breach is suppressed)
  206. *rxt = 'ENLE' rxt 'Breches' ;
  207. 'OUBL' rxt 'Breches' ;
  208. rxt . 'REINIT' = vrai ;
  209. nbit  = 'ENTI' (t2 '-' t1 / DT0 '+' (DT0 '/' 100.)) ;
  210. execrxt  nbit rxt ;
  211. 'SI' ctrl ;
  212.   'OPTI' 'SAUV' 'condmass_2.sauv' ; 'SAUV' ;
  213. 'FINS' ;
  214.  
  215. TEMP_2 = rxt . 'TIC' . 'TF' ;
  216. PSAT_2 = 'VARI' 'PSATT' (rxt . 'TIC' . 'TF' + 273.15) ;
  217. RSAT_2 = 'VARI' 'ROVAP' PSAT_2 (rxt . 'TIC' . 'TF' + 273.15) ;
  218. HR_2   = rxt . 'TIC' . 'RVP' '/' RSAT_2 ;
  219. YN2_2  = rxt . 'TIC' . 'YN2' ;
  220. YVAP_2 = rxt . 'TIC' . 'YVAP' ;
  221.  
  222. *
  223. *
  224. * Post-processing
  225. *
  226. *
  227. 'SI' GRAPH ;
  228.  
  229. GEO = rxt . 'GEO' ;
  230. VTotal = geo . 'VTotal' ;
  231. *VTotal  = 'MAXI' ('RESU' ('DOMA' GEO . '$vtf'   'VOLUME')) ;
  232.  
  233. *
  234. * 2D graphs
  235. 'TRAC' geo . 'vtf' geo . 'menvf' temp_1 'TITR' 'Phase 1 : Temperature TF' ;
  236. 'TRAC' geo . 'vtf' geo . 'menvf' temp_2 'TITR' 'Phase 2 : Temperature TF' ;
  237. 'TRAC' geo . 'vtf' geo . 'menvf' HR_1   'TITR' 'Phase 1 : Relative Humidity' ;
  238. 'TRAC' geo . 'vtf' geo . 'menvf' HR_2   'TITR' 'Phase 2 : Relative Humidity' ;
  239. 'TRAC' geo . 'vtf' geo . 'menvf' YN2_1  'TITR' 'Phase 1 : N2 mass fraction' ;
  240. 'TRAC' geo . 'vtf' geo . 'menvf' YN2_2  'TITR' 'Phase 2 : N2 mass fraction' ;
  241. 'TRAC' geo . 'vtf' geo . 'menvf' YVAP_1 'TITR' 'Phase 1 : Steam mass fraction' ;
  242. 'TRAC' geo . 'vtf' geo . 'menvf' YVAP_2 'TITR' 'Phase 2 : Steam mass fraction' ;
  243.  
  244. *
  245. * 1D graphs
  246. TAB1 = 'TABLE' ;
  247. TAB1 . 'TITRE' = 'TABLE' ;
  248. TAB1 . 1 = 'MOT' ' MARQ CROI REGU ';
  249. TAB1 . 2 = 'MOT' ' MARQ CARR REGU TIRC';
  250. TAB1 . 3 = 'MOT' ' MARQ LOSA REGU TIRC';
  251. TAB1 . 4 = 'MOT' ' MARQ TRIU REGU TIRC';
  252. TAB1 . 5 = 'MOT' ' MARQ TRID REGU TIRC';
  253. TAB1 . 'TITRE' . 1 = 'NAUTILUS';
  254.  
  255. Ltps = rxt . 'TIC' . 'LTPS' ;
  256. evrho2 = 'EVOL' 'MANU' Ltps rxt . 'TIC' . 'Rhomn' ;
  257. evm2   = evrho2 * VTotal ;
  258. evp2   = 'EVOL' 'MANU' Ltps rxt . 'TIC' . 'PT'    ;
  259. evt2   = 'EVOL' 'MANU' Ltps rxt . 'TIC' . 'Tfm'   ;
  260.  
  261. 'DESS' (evp2)
  262. 'TITR' 'Pressure' 'MIMA'
  263. 'GRIL' 'POIN' 'GRIS' 'TITX' 's' 'TITY' ' Pa' 'LEGE' tab1 ;
  264. 'DESS' (evt2)
  265. 'TITR' 'Mean gas temperature' 
  266. 'GRIL' 'POIN' 'GRIS' 'TITX' 's' 'TITY' ' C' 'LEGE' tab1 ;
  267. 'DESS' (evrho2)
  268. 'TITR' 'Mean gas density'                                     
  269. 'GRIL' 'POIN' 'GRIS' 'TITX' 's' 'TITY' 'kg/m3' 'LEGE' tab1 ;
  270. 'DESS' (evm2)
  271. 'TITR' 'Mass'                                     
  272. 'GRIL' 'POIN' 'GRIS' 'TITX' 's' 'TITY' 'kg' 'LEGE' tab1 ;
  273.  
  274. 'FINS' ;
  275.  
  276. *
  277. *
  278. * Non-régression
  279. *
  280. *
  281. max_1 = 'MAXI' hr_1 ; test_1 = max_1 '>' 1.05 ;
  282. 'MESS' 'Phase 1 :' ' ' max_1 ' ' test_1 ;
  283.  
  284. max_2 = 'MAXI' hr_2 ; test_2 = max_2 '>' 1.05 ;
  285. 'MESS' 'Phase 2 :' ' ' max_2 ' ' test_2 ;
  286.  
  287. 'SI' (test_1 'OU' test_2) ;
  288.    'ERRE' 5 ;
  289. 'FINS' ;
  290.  
  291. *'OPTI' donn 5 ;
  292. 'FIN' ;
  293.  
  294.  
  295.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales