Télécharger compar_syco_plast.dgibi

Retour à la liste

* fichier : compar_syco_plast.dgibi 
************************************************************************
************************************************************************
*******************************************************
**-------------------------------------------------------------------
MESS ' COMPARAISON ' ;
MESS '      CALCUL DYNAMIQUE COMPORTEMENT VISCOPLASTIQUE SYCO1 ';
MESS '      avec parametre p de la loi SYCO1 valant 1 ';
MESS '      CALCUL DYNAMIQUE COMPORTEMENT ELASTOPLASTIQUE ';
MESS '                        en  2D defo plane ' ;
MESS '                    Unites: N  Pa  m  kg  s' ;
MESS '' ;
**--------------------------------------------------------------------
*** Options de calcul 
opti dime 2 elem QUA4 mode plan defo ;
 
*******************************************************
*** maillage 
  pa1 = 0. 0.;
  pa2 = 5. 0.;
  pa3 = 5. 3.;
  pa4 = 0. 3.;
  li12 = pa1 droi 1 pa2;
  li23 = pa2 droi 1 pa3;
  li34 = pa3 droi 1 pa4;
  li41 = pa4 droi 1 pa1;
  su1 = dall li12 li23 li34 li41;
  elim 0.001 su1;
*
 
**********************************************************
***   MODELE & MATERIAU   ***
**********************************************************
 
Epsprog0 = ('PROG' 
0. 0.01 0.1 0.5 );
Sigprog0 = ('PROG'
0. 500. 1000. 1200.) * 1.e6;
lcxx = 'EVOL' 'MANU' 'Epsilon' Epsprog0 'Sigma' Sigprog0 ;
*
ab1 = extr lcxx 'ABSC';
ord1 = extr lcxx 'ORDO';
eey1 = (extr ord1 2)/(extr ab1 2);
lsm1 = ord1 enle 1 ;
lep1 = (ab1 enle 1) - (lsm1 / eey1) ;
evec = evol vert manu eps lep1 sig lsm1 ;
*dess (lcxx et evec) titr ' Courbes de traction et d ecrouissage (vert)' ;
*
nu0 = 0.3 ;
rho0= 7800.;
**********************************************************
*** Modele & materiau  ***
*
* elements standards
  mod1 = 'MODELISER' su1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 
  'VISCOPLASTIQUE' 'SYCO1' 'QUA4'; 
  mat1 = 'MATERIAU' mod1 'YOUN' eey1 'NU' nu0 'RHO' rho0 
  'ECRO' evec 'PSYC' 1. 'DSYC' 1.d8 ;
*
 
**********************************************************
***   CL et DEPLACEMENTS IMPOSES   ***
**********************************************************
 
cl1 = bloq (pa1 et pa4) 'UX';
cl2 = bloq (pa1 et pa2) 'UY';
cl3 = bloq (pa2 et pa3) 'UX';
cltot =  (cl1 'ET' cl2 'ET' cl3 ) ;
*
*... chargement en deplacement impose
umax = 1.;
uimp = depi cl3 umax;
 
*
xx1 = prog 0. 1.;
yy1 = prog 0. 50.;
evochar = evol manu 'temps' xx1 'charge' yy1;
char1 = char meca uimp evochar;
*
*
*=======================================================*
*                                                       *
*                     RESOLUTION                        *
*                                                       *
*=======================================================*
 
xx0 = prog 0. 1.15e-3  1.25e-2;
*
tab1 = table;
tab1.dynamique = vrai;
tab1.modele = mod1;
tab1.caracteristiques = mat1;
tab1.blocages_mecaniques = cltot;
tab1.chargement = char1;
tab1.temps_calcules = xx0;
tab1.precision = 1.e-5;
pasapas tab1;
*
*post traitement
sig1 = tab1.contraintes. 2;
ut1 = tab1.deplacements. 2;
vt1 = tab1.vitesses. 2;
tt1 = tab1.temps. 2;
var1 = tab1.variables_internes. 2;
*
*
val1 = extr var1 'EPSE' 1 1 3;
val2 = extr var1 'VP' 1 1 3;
val3 = extr ut1 'UY' pa3;
 
*******************************************************
*
*******************************************************
**-------------------------------------------------------------------
MESS '' ;
MESS '      CALCUL DYNAMIQUE COMPORTEMENT ELASTOPLASTIQUE ';
MESS '                        en  2D defo plane ' ;
MESS '                    Unites: N  Pa  m  kg  s' ;
MESS '' ;
**--------------------------------------------------------------------
*** Options de calcul 
opti dime 2 elem QUA4 mode plan defo;
 
*******************************************************
*** maillage 
  pa1 = 0. 0.;
  pa2 = 5. 0.;
  pa3 = 5. 3.;
  pa4 = 0. 3.;
  li12 = pa1 droi 1 pa2;
  li23 = pa2 droi 1 pa3;
  li34 = pa3 droi 1 pa4;
  li41 = pa4 droi 1 pa1;
  su1 = dall li12 li23 li34 li41;
  elim 0.001 su1;
*
 
**********************************************************
***   MODELE & MATERIAU   ***
**********************************************************
 
nu0 = 0.3 ;
rho0= 7800.;
**********************************************************
*** Modele & materiau  ***
*
* elements standards
*
  mod1 = 'MODELISER' su1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 
 'PLASTIQUE' ; 
  mat1 = 'MATERIAU' mod1 'YOUN' eey1 'NU' nu0 'RHO' rho0 
  'ECRO' evec  ;
 
**********************************************************
***   CL et DEPLACEMENTS IMPOSES   ***
**********************************************************
 
cl1 = bloq (pa1 et pa4) 'UX';
cl2 = bloq (pa1 et pa2) 'UY';
cl3 = bloq (pa2 et pa3) 'UX';
cltot =  (cl1 'ET' cl2 'ET' cl3 ) ;
*
*... chargement en deplacement impose
umax = 1.;
uimp = depi cl3 umax;
 
*
xx1 = prog 0. 1.;
yy1 = prog 0. 50.;
evochar = evol manu 'temps' xx1 'charge' yy1;
char1 = char meca uimp evochar;
*
*=======================================================*
*                                                       *
*                     RESOLUTION                        *
*                                                       *
*=======================================================*
 
xx0 = prog 0. 1.15e-3  1.25e-2;
*
tab2 = table;
tab2.dynamique = vrai;
tab2.modele = mod1;
tab2.caracteristiques = mat1;
tab2.blocages_mecaniques = cltot;
tab2.chargement = char1;
tab2.temps_calcules = xx0;
tab2.precision = 1.e-5;
pasapas tab2;
*
*post traitement
sig1 = tab2.contraintes. 2;
ut1 = tab2.deplacements. 2;
vt1 = tab2.vitesses. 2;
tt1 = tab2.temps. 2;
var1 = tab2.variables_internes. 2;
*
*
xal1 = extr var1 'EPSE' 1 1 3;
xal3 = extr ut1 'UY' pa3;
 
aa1 = ABS(val1 - xal1);
aa3 = ABS(val3 - xal3);
*
mess 'aa1, aa3 =' aa1 aa3 ;
si (aa1 >EG 1.e-8);
erre 5;
finsi;
si (aa3 >EG 1.e-8);
erre 5;
finsi;
fin;
 
 
 
 
 
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales