Télécharger la plaquette Cast3M


fr en

Télécharger basmachT.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *****************************************************
  2. * fichier :  basmachT.dgibi                         *
  3. ** modifie le 15/06/2014 passage EQPR -> EQEX       *
  4. *****************************************************
  5.  
  6.  
  7. *******************************************************************
  8. * JEU DE DONNEES POUR TESTER LE BON FONCTIONNEMENT DES OPERATEURS *
  9. * NSKE, PRESSION, TSCAL. INJECTION D'UN MELANGE DE GAZ DANS UN    *
  10. * VOLUME FERME ET PRESSURISATION. ALGORITHME 'FAIBLES MACH' POUR  *
  11. * LES EQUATIONS NAVIER-STOKES FAIBLEMENT COMPRESSIBLES + MODELE   *
  12. * DE TURBULENCE K-E. ON TESTE SUR LA CONSERVATION DE LA MASSE     *
  13. * H. PAILLERE SEMT/TTMF AVRIL 1997                                *
  14. * FORMULATION EF ELEMENTS TRI6                                    *
  15. *******************************************************************
  16.  
  17. *************************************************************
  18. * PROCEDURE PROCINJ                                         *
  19. *************************************************************
  20.  
  21. DEBPROC PROCINJ ;
  22. ARGU RVX*'TABLE' ;
  23.  
  24. RV = RVX.'EQEX' ;
  25.  
  26. * recuperation des anciennes conditions aux limites :
  27.  
  28. cl_YH2 = 'EXCO' 'YH2' RV.'CLIM' 'YH2' ;
  29. cl_YO2 = 'EXCO' 'YO2' RV.'CLIM' 'YO2' ;
  30. cl_YH2O = 'EXCO' 'YH2O' RV.'CLIM' 'YH2O' ;
  31. cl_GNX = 'EXCO' '1GN' RV.'CLIM' '1GN' ;
  32. cl_GNY = 'EXCO' '2GN' RV.'CLIM' '2GN' ;
  33. cl_KN = 'EXCO' 'KN' RV.'CLIM' 'KN' ;
  34. cl_EN = 'EXCO' 'EN' RV.'CLIM' 'EN' ;
  35. cl_PSI = 'EXCO' 'PSIN' RV.'CLIM' 'PSIN' ;
  36.  
  37. * modification des conditions aux limites :
  38.  
  39. RHOJet = RV.INCO.'PM'/PSIJET ;
  40. UJet = GJet/RHOJet ;
  41.  
  42. KJet = 0.05*UJet*UJet ;
  43. EJet = 0.02*(UJet**3.)/DINJ ;
  44.  
  45. cl_KN = 0.D0 * cl_KN + KJet ;
  46. cl_EN = 0.D0 * cl_EN + EJet ;
  47.  
  48. * reimposition des conditions aux limites :
  49.  
  50. RV.'CLIM' = cl_YH2 + cl_YO2 + cl_YH2O + cl_GNX + cl_GNY +
  51.         cl_KN + cl_EN + cl_PSI ;
  52.  
  53. detr cl_YH2 ;
  54. detr cl_YO2 ;
  55. detr cl_YH2O ;
  56. detr cl_GNX ;
  57. detr cl_GNY ;
  58. detr cl_KN ;
  59. detr cl_EN ;
  60. detr cl_PSI ;
  61. *tc mise en commentaires du finsi cidessous
  62. *FINSI ;
  63.  
  64.  as2 ama1  = 'KOPS' 'MATRIK' ;
  65.  'FINPROC' as2 ama1 ;
  66.  
  67. *********************************************************************
  68. * PROCEDURE CALCUL1
  69. *********************************************************************
  70. DEBPROC CALCUL1 ;
  71. ARGU RVX*'TABLE' ;
  72. RV = RVX.'EQEX' ;
  73.  
  74. RV.PASDETPS.'DELTAT' = 0.01 ;
  75.  
  76. * filtres sur fractions massiques et calcul de la fraction massique d'azote
  77.  
  78. YH2  = RV.INCO.'YH2' ;
  79. YO2  = RV.INCO.'YO2' ;
  80. YH2O = RV.INCO.'YH2O' ;
  81. YH2  = KOPS YH2 '|<' 0. ;
  82. YO2  = KOPS YO2 '|<' 0. ;
  83. YH2O = KOPS YH2O '|<' 0. ;
  84.  
  85. RV.INCO.'YH2' =  YH2 ;
  86. RV.INCO.'YO2'  = YO2 ;
  87. RV.INCO.'YH2O' = YH2O ;
  88. RV.INCO.'YN2'  = KOPS 1.0 '-' RV.INCO.'YH2O' ;
  89. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YH2' ;
  90. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YO2' ;
  91.  
  92. * calcul de rho à partir de la loi d'état des gaz parfaits
  93.  
  94. RV.INCO.'RHO' = KOPS (RV.INCO.'PM') '/' (RV.INCO.'PSIN') ;
  95. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  96. RV.INCO.'RHOC' = KCHT $MT 'SCAL' 'CENTRE' (RV.INCO.'RHOC') ;
  97. RHOM = (SOMT (KOPS RV.INCO.'RHOC' '*' VOL))/VOLT ;
  98. RV.INCO.'RHOM' = RHOM ;
  99.  
  100. * calcul du terme (rho-rhom)*g de la QDM
  101.  
  102. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'RHOM') ;
  103. rogx = KCHT $MT SCAL CENTRE 0. ;
  104. rogy = KCHT $MT SCAL CENTRE (-9.81*DRHO) ;
  105. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  106. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  107. RV.INCO.'ROG' = KCHT $MT VECT CENTRE (rogx ET rogy) ;
  108.  
  109. * calcul la vitesse à partir de la qdm
  110.  
  111. GN = RV.INCO.'GN' ;
  112. gnx= kcht $MT scal sommet (exco 'UX' gn) ;
  113. gny= kcht $MT scal sommet (exco 'UY' gn) ;
  114. unx = kops gnx '/' RV.INCO.'RHO' ;
  115. uny = kops gny '/' RV.INCO.'RHO' ;
  116. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  117. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  118. un = kcht $MT vect sommet (unx et uny) ;
  119. RV.INCO.'UN' = un ;
  120.  
  121. * calcul de nut à partir de mut et de rho
  122.  
  123. RV.INCO.'NUT' = KOPS (RV.INCO.'MUT') '/' (RV.INCO.'RHOC') ;
  124.  
  125.  as2 ama1  = 'KOPS' 'MATRIK' ;
  126.  'FINPROC' as2 ama1 ;
  127.  
  128. *********************************************************************
  129. * PROCEDURE CALCUL2
  130. *********************************************************************
  131. DEBPROC CALCUL2 ;
  132. ARGU RVX*'TABLE' ;
  133.  
  134. RV = RVX.'EQEX' ;
  135.  
  136. * on récupère le pas de temps
  137.  
  138. Dt = RV.PASDETPS.'DELTAT' ;
  139. Dt = Dt * RV.'ALFA' ;
  140.  
  141. * calcul l'intégrale se trouvant dans le terme Dp/Dt.
  142.  
  143. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  144. ZT = KOPS ZT '/' Dt ;
  145. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  146.  
  147. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  148. ZZ = NOEL $MT ZZ ;
  149. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  150. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  151.  
  152. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  153.  
  154. * calcul de dPdt
  155.  
  156. q0 = 'DBIT' RV.INCO.'GN' $INJ ;
  157. RV.INCO.'DEBIT' = q0 ;
  158. dPdt = ZZT + q0 ;
  159. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'RHOM' ;
  160.  
  161. * terme source de l'équation d'énergie
  162.  
  163. zuzu = (gamma-1.)/gamma ;
  164.  
  165. QC = NOEL $MT RV.INCO.'Q' ;
  166. QC = KCHT $MT 'SCAL' 'CENTRE' QC ;
  167. TOTO = KOPS QC '+' dPdt ;
  168. TOTO = KOPS TOTO '/' RV.INCO.'RHOC' ;
  169. TOTO = KOPS TOTO '*' zuzu ;
  170. RV.INCO.'S' = KCHT $MT 'SCAL' 'CENTRE' TOTO ;
  171.  
  172. * terme source équation de Poisson
  173.  
  174. Z1 = dPdt/RV.INCO.'PM' ;
  175. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  176. ZS = KOPS ZP '-' ZZ ;
  177. ZZS = KOPS ZS '*' VOL ;
  178. ZZS = ZZS * (-1.0) ;
  179. RV.INCO.'ZS' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  180.  
  181. * calcul de l'évolution de la pression 
  182.  
  183. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  184.  
  185. * affichage informations toutes les 5 iterations
  186.  
  187. DD = RV.PASDETPS.'NUPASDT' ;
  188. NN = DD/5 ;
  189. LO = (DD-(5*NN)) EGA 0 ;
  190. SI ( LO ) ;
  191. MESSAGE '==========================================================' ;
  192. MESSAGE 'TEMPS = ' RV.PASDETPS.'TPS' ' PRESSION = ' RV.INCO.'PM' ;
  193. MESSAGE 'MASSE INI =' MASINI ' MASSE TOTALE = ' (RV.INCO.'RHOM'*VOLT) ;
  194. PT = PROG RV.'PASDETPS'.'TPS' ;
  195. PP = PROG RV.INCO.'PM' ;
  196. PMTO = PROG (RV.INCO.'RHOM'*VOLT) ;
  197. RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  198. RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  199. RV.INCO.'MTOTA' = RV.INCO.'MTOTA' ET PMTO ;
  200. MESSAGE '==========================================================' ;
  201. FINSI ;
  202.  
  203.  as2 ama1  = 'KOPS' 'MATRIK' ;
  204.  'FINPROC' as2 ama1 ;
  205.  
  206. ***************************************************************
  207. * JEU DE DONNEES NURETH-8 : CALCUL DE DISTRIBUTION/COMBUSTION *
  208. * ALGORITHME 'COMPRESSIBLE FAIBLE MACH' SEMI-IMPLICITE        *
  209. *                    === DISTRIBUTION ===                     *
  210. ***************************************************************
  211.  
  213. opti elem tri6 ;
  214. opti isov suli ;
  215.  
  216. DISCR  = 'MACRO'  ;
  217. KPRES  = 'CENTRE' ;
  218. BETAP  = 1.       ;
  219.  
  220.  
  221. *========================================================*
  222. *               GENERATION DU MAILLAGE                   *
  223. *========================================================*
  224.  
  225. L_A = 4.0 ;
  226. H_A = 4.0 ;
  227. L_B = 4.0 ;
  228. H_B = H_A ;
  229.  
  230. HINJ = 1.0 ;
  231. DINJ = 1.0 ;
  232.  
  233. HAB = 1. ;
  234. DAB = 2.0 ;
  235. LAB = 1. ;
  236.  
  237. DX = 1. ;
  238. DY = 1. ;
  239.  
  240. epsi = (DX/10.) ;
  241.  
  242. ******************
  243. * COMPARTIMENT A *
  244. ******************
  245.  
  246. A7 = 0. 0. ;
  247. A8 = HINJ 0. ;
  248. A1 = (HINJ+DINJ) 0. ;
  249. A2 = L_A 0.0 ;
  250. A3 = L_A HAB ;
  251. A4 = L_A (HAB+DAB) ;
  252. A5 = L_A H_A ;
  253. A6 = 0. H_A ;
  254.  
  255. N78 = 'ENTIER' (HINJ/DX) ;
  256. N81 = 'ENTIER' (DINJ/DX) ;
  257. N12 = 'ENTIER' ((L_A-HINJ-DINJ)/DX) ;
  258. N23 = 'ENTIER' (HAB/DY) ;
  259. N34 = 'ENTIER' (DAB/DY) ;
  260. N45 = 'ENTIER' ((H_A-HAB-DAB)/DY) ;
  261. N56 = N78 + N81 + N12 ;
  262. N67 = N23 + N34 + N45 ;
  263.  
  264. A7A8 = A7 'DROI' N78 A8 ;
  265. A8A1 = A8 'DROI' N81 A1 ;
  266. A1A2 = A1 'DROI' N12 A2 ;
  267. A2A3 = A2 'DROI' N23 A3 ;
  268. A3A4 = A3 'DROI' N34 A4 ;
  269. A4A5 = A4 'DROI' N45 A5 ;
  270. A5A6 = A5 'DROI' N56 A6 ;
  271. A6A7 = A6 'DROI' N67 A7 ;
  272.  
  273. BAS_A = A7A8 ET A8A1 ET A1A2 ;
  274. DRO_A = A2A3 ET A3A4 ET A4A5 ;
  275. HAU_A = A5A6 ;
  276. GAU_A = A6A7 ;
  277.  
  278. COMP_A = 'DALLER' BAS_A DRO_A HAU_A GAU_A 'PLAN' ;
  279.  
  280. ******************
  281. * COMPARTIMENT B *
  282. ******************
  283.  
  284. B1 = (L_A+LAB) 0. ;
  285. B2 = (L_A+LAB+L_B) 0. ;
  286. B3 = (L_A+LAB+L_B) H_B ;
  287. B6 = (L_A+LAB) H_B ;
  288. B7 = (L_A+LAB) (HAB+DAB) ;
  289. B8 = (L_A+LAB) HAB ;
  290.  
  291. N23 = 'ENTIER' (H_B/DY) ;
  292. N36 = 'ENTIER' (L_B/DX) ;
  293. N67 = 'ENTIER' ((H_B-HAB-DAB)/DY) ;
  294. N78 = 'ENTIER' (DAB/DY) ;
  295. N81 = N23 - N67 - N78 ;
  296. N12 = N36 ;
  297.  
  298. B1B2 = B1 'DROI' N12 B2 ;
  299. B2B3 = B2 'DROI' N23 B3 ;
  300. B3B6 = B3 'DROI' N36 B6 ;
  301. B6B7 = B6 'DROI' N67 B7 ;
  302. B7B8 = B7 'DROI' N78 B8 ;
  303. B8B1 = B8 'DROI' N81 B1 ;
  304.  
  305. BAS_B = B1B2 ;
  306. DRO_B = B2B3 ;
  307. HAU_B = B3B6 ;
  308. GAU_B = B6B7 ET B7B8 ET B8B1 ;
  309.  
  310. COMP_B = 'DALLER' BAS_B DRO_B HAU_B GAU_B 'PLAN' ;
  311.  
  312. ***************
  313. * JONCTION AB *
  314. ***************
  315.  
  316. NX = 'ENTIER' (LAB/DX) ;
  317. NY = 'ENTIER' (DAB/DY) ;
  318.  
  319. BAS_AB = A3 'DROI' NX B8 ;
  320. DRO_AB = B8 'DROI' NY B7 ;
  321. HAU_AB = B7 'DROI' NX A4 ;
  322. GAU_AB = A4 'DROI' NY A3 ;
  323.  
  324. J_AB = 'DALLER' BAS_AB DRO_AB HAU_AB GAU_AB 'PLAN' ;
  325.  
  326. ********************
  327. * MAILLAGE COMPLET *
  328. ********************
  329.  
  330. COMP_A = COMP_A 'COUL' 'ROUG' ;
  331. COMP_B = COMP_B 'COUL' 'VERT' ;
  332.  
  333. J_AB = J_AB 'COUL' 'BLAN' ;
  334.  
  335. MT = COMP_A ET COMP_B ET J_AB ;
  336. 'ELIM' epsi MT ;
  337.  
  338. 'ORIE' MT ;
  339. CNT = 'CONT' MT ;
  340.  
  341. ******************
  342. * TABLES DOMAINE *
  343. ******************
  344.  
  345. Mmt     = 'CHAN' mt     'QUAF' ;
  346. Minj    = 'CHAN' BAS_A  'QUAF' ;
  347. MCOMP_A = 'CHAN' comp_A 'QUAF' ;
  348. MCOMP_B = 'CHAN' comp_B 'QUAF' ;
  349. MJ_AB   = 'CHAN' J_AB   'QUAF' ;
  350.  
  351. 'ELIM' (Mmt 'ET' Minj 'ET' MCOMP_A 'ET' MCOMP_B 'ET' MJ_AB) epsi;
  352.  
  353. $MT     = 'MODE' MMT     'NAVIER_STOKES' DISCR  ;
  354. $INJ    = 'MODE' Minj    'NAVIER_STOKES' DISCR  ;
  355. $COMP_A = 'MODE' MCOMP_A 'NAVIER_STOKES' DISCR  ;
  356. $COMP_B = 'MODE' MCOMP_B 'NAVIER_STOKES' DISCR  ;
  357. $J_AB   = 'MODE' MJ_AB   'NAVIER_STOKES' DISCR  ;
  358.  
  359. MT      = 'DOMA' $MT     'MAILLAGE' ;
  360. inj     = 'DOMA' $INJ    'MAILLAGE' ;
  361. comp_A  = 'DOMA' $COMP_A 'MAILLAGE' ;
  362. comp_B  = 'DOMA' $COMP_B 'MAILLAGE' ;
  363. j_AB    = 'DOMA' $J_AB   'MAILLAGE' ;
  364.  
  365.  
  366. VOL = 'DOMA' $MT 'VOLUME' ;
  367. VOLT = 'SOMT' VOL ;
  368. VOL = KCHT $MT 'SCAL' 'CENTRE' VOL ;
  369.  
  370. 'MESSAGE' 'VOLUME TOTAL = ' VOLT ;
  371.  
  372. ******************************************
  373. * FRONTIERES POUR CONDITIONS AUX LIMITES *
  374. ******************************************
  375.  
  376. MUR_HOR = A7A8 ET A1A2 ET BAS_AB ET B1B2 ET B3B6 
  377.           ET HAU_AB ET A5A6 ;
  378. MUR_VER = A2A3 ET B8B1 ET B2B3 ET B6B7 ET A4A5 ET A6A7 ;
  379. BRECHE = A8A1 ;
  380.  
  381. MUR_HOR = MUR_HOR 'COUL' 'VERT' ;
  382. MUR_VER = MUR_VER 'COUL' 'ROUG' ;
  383. BRECHE = BRECHE 'COUL' 'JAUNE' ;
  384.  
  385. *========================================================*
  386. *               DONNEES DU CALCUL DE DISTRIBUTION        *
  387. *========================================================*
  388.  
  389. *--------------------------------------
  390. * masses molaires et constantes des gaz
  391. *--------------------------------------
  392. MH2 = 2.0E-3 ;
  393. MO2 = 32.0E-3 ;
  394. MN2 = 28.0E-3 ;
  395. MH2O = 18.0E-3 ;
  396.  
  397. Rg = 8.313 ;
  398.  
  399. RH2 = Rg/MH2 ;
  400. RO2 = Rg/MO2 ;
  401. RN2 = Rg/MN2 ;
  402. RH2O = Rg/MH2O ;
  403.  
  404. *----------------------------------------------------------
  405. * fractions molaires des differents constituants du melange
  406. *----------------------------------------------------------
  407. XH2 = 0.0 ;
  408. XH2O = 0.1 ;
  409. XO2 = 0.21*(1.0 - XH2 - XH2O) ;
  410. XN2 = 1.0 - XH2 - XH2O - XO2 ;
  411.  
  412. *---------------------------------------------
  413. * masse molaire du melange et constante du gaz
  414. *---------------------------------------------
  415. M = (XH2*MH2) + (XO2*MO2) + (XN2*MN2) + (XH2O*MH2O) ;
  416. R = Rg/M ;
  417.  
  418. *------------------------------------------------------------
  419. * pression, temperature et densite du melange (loi d'etat GP)
  420. *------------------------------------------------------------
  421. P = 1.0E5 ;
  422. T = 400.0 ;
  423. PSI = R*T ;
  424. RHO = P/PSI ;
  425.  
  426. *------------------------
  427. * Caractéristiques du jet
  428. *------------------------
  429.  
  430. XH2Jet = 0.1 ;
  431. XH2OJet = 0.3 ;
  432. XO2Jet = 0.21*( 1.0 - XH2Jet - XH2OJet ) ;
  433. XN2Jet = 1.0 - XH2Jet - XH2OJet - XO2Jet ;
  434. MJet = (XH2Jet*MH2) + (XH2OJet*MH2O) + (XO2Jet*MO2) +
  435.        (XN2Jet*MN2) ;
  436. RJet = Rg/MJet ;
  437. TJet = 650.0 ;
  438. PSIJet = Rjet*Tjet ;
  439. RhoJet = P/PSIJet ;
  440. GJet = 10.*DINJ/(DINJ+(DX*0.5)) ;
  441. UJet = GJet/RhoJet ;
  442. KJet = 0.05*UJet*UJet ;
  443. EJet = 0.02*(UJet**3.)/DINJ ;
  444.  
  445. *------------------------------------------------
  446. * fractions massiques des differents constituants
  447. *------------------------------------------------
  448. YH2 = XH2*MH2/M ;
  449. YO2 = XO2*MO2/M ;
  450. YN2 = XN2*MN2/M ;
  451. YH2O = XH2O*MH2O/M ;
  452. YH2Jet = XH2Jet*MH2/MJet ;
  453. YH2OJet =XH2OJet*MH2O/MJet ;
  454. YO2Jet = XO2Jet*MO2/MJet ;
  455. YN2Jet =XN2Jet*MN2/MJet ;
  456.  
  457. *------------------------------------------------------------------
  458. * Cp des différents constituants et du mélange (supposés constants)
  459. *------------------------------------------------------------------
  460. CPH2 = 13514.04 + (1.684537*T) ;
  461. CPH2O = 1715.632 + (0.552805*T) ;
  462. CPN2 = 1006.15 + (0.1387166*T) ;
  463. CPO2 = 907.580 + (0.1420522*T) ;
  464.  
  465. CP = (YH2*CPH2) + (YH2O*CPH2O) + (YO2*CPO2) + (YN2*CPN2) ;
  466.  
  467. gamma = CP/(CP-R) ;
  468.  
  469. *----------------------------------------------------
  470. * calcul d'une vitesse de référence (pour les tracés)
  471. *----------------------------------------------------
  472.  
  473. uref = gamma*R*T ;
  474. uref = uref**0.5 ;
  475. uref = 0.01*uref ;
  476. ampl = 1./uref ;
  477.  
  478. *------------------------------------------------------------------------
  479. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  480. * coefficients de diffusion moléculaire  
  481. *------------------------------------------------------------------------
  482. Pr = 0.7 ;
  483. Prt = 1.0 ;
  484. Sct = 1.0 ;
  485.  
  486. Mu = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  487. Nu = Mu/RHO ;
  488. Lambda = Mu*CP/Pr ;
  489.  
  490. alpha = Lambda/RHO/CP ;
  491.  
  492. DH2O = 2.55E-5 ;
  493. DH2 = 7.12E-5 ;
  494. DO2 = 2.06E-5 ;
  495.  
  496. *==============================================================
  497. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE :           
  498. *  0) FILTRE K-E
  499. *  1) QUANTITE DE MOUVEMENT     --- OPERATEUR NSKE
  500. *  2) EQUATION DE L'ENERGIE     --- OPERATEUR TSCAL
  501. *  3) TRANSPORT DES ESPECES     --- OPERATEUR TSCAL
  502. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME
  503. * 'FAIBLE MACH'
  504. *  4) CONDITIONS AUX LIMITES
  505. *==============================================================
  506.  
  507. RV = 'EQEX' $MT 'ITMA' 30 'ALFA' 0.9
  508.  'ZONE' $MT 'OPER'      'PROCINJ'  
  509.  'ZONE' $MT 'OPER'      'CALCUL1'
  510.  'ZONE' $MT 'OPER'      'FILTREKE' UJet DINJ 'INCO' 'KN' 'EN'
  511.  'OPTI' 'CONS'
  512.  'ZONE' $MT 'OPER'      'NSKE' 'RHOC' MU 'MUT' 'UN' 'ROG'
  513.                                 'INCO' 'GN' 'KN' 'EN'
  514.  'OPTI' 'NOCONS'
  515.  'ZONE' $MT 'OPER'      'TSCAL' alpha 'UN' 'S' 'NUT' Prt 
  516.                                 'INCO' 'PSIN'  ;
  517.  
  518. RV = 'EQEX' RV
  519.  'ZONE' $MT 'OPER'      'TSCAL' DH2 'UN' 0.0 'NUT' SCT 
  520.                                 'INCO' 'YH2'
  521.  'ZONE' $MT 'OPER'      'TSCAL' DO2 'UN' 0.0 'NUT' SCT 
  522.                                 'INCO' 'YO2'
  523.  'ZONE' $MT 'OPER'      'TSCAL' DH2O 'UN' 0.0 'NUT' SCT 
  524.                                 'INCO' 'YH2O' 
  525.  'ZONE' $MT 'OPER'      'CALCUL2' ;
  526.  
  527.   RV=EQEX RV OPTI EFM1 'CENTREE'
  528.   'ZONE' $MT      'OPER' 'DFDT' 1. 'GN' 'DELTAT' 'INCO' 'GN'
  529.   'ZONE' $MT      'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  530.   'ZONE' $MT      'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN'
  531.   'ZONE' $MT      'OPER' 'DFDT' 1. 'PSIN' 'DELTAT' 'INCO' 'PSIN'
  532.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YH2' 'DELTAT' 'INCO' 'YH2'
  533.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YO2' 'DELTAT' 'INCO' 'YO2'
  534.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YH2O' 'DELTAT' 'INCO' 'YH2O' ;
  535.  
  536.  
  537. RV = 'EQEX' RV
  538.  'CLIM' 'GN' 'UIMP' MUR_VER 0.0 
  539.         'GN' 'VIMP' MUR_HOR 0.0
  540.         'GN' 'UIMP' BRECHE  0.0 
  541.         'GN' 'VIMP' BRECHE  GJet 
  542.         'KN' 'TIMP' BRECHE  KJet
  543.         'EN' 'TIMP' BRECHE  EJet ;
  544. RV = 'EQEX' RV
  545.  'CLIM' 'PSIN' 'TIMP' BRECHE  PSIJet 
  546.         'YH2' 'TIMP' BRECHE YH2Jet
  547.         'YO2' 'TIMP' BRECHE YO2Jet 
  548.         'YH2O' 'TIMP' BRECHE YH2OJet ;
  549.  
  550. *===========================================================
  551. * TABLE EQPR POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE) 
  552. *===========================================================
  553.  
  554. RVP = EQEX 'OPTI' 'EF' KPRES
  555.  'ZONE' $MT    OPER  KBBT  -1. betap  INCO 'GN' 'PRES'
  556.            'OPTI' 'EF' 'CENTREE' 'INCOD' KPRES
  557.  'ZONE' $MT    OPER  FIMP  'ZS'   'INCO' 'PRES'
  558. ;
  559.  
  560.     rvp.'METHINV'.TYPINV=1 ;
  561.     rvp.'METHINV'.IMPINV=0 ;
  562.     rvp.'METHINV'.NITMAX=300;
  563.     rvp.'METHINV'.PRECOND=3 ;
  564.     rvp.'METHINV'.RESID  =1.e-8 ;
  565.     rvp.'METHINV' . 'FCPRECT'=100 ;
  566.     rvp.'METHINV' . 'FCPRECI'=100 ;
  567.  
  568. *==========================================================
  569. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME 
  570. *==========================================================
  571.  
  572.   RV.'NOMVI' = 'GN' ;
  573.  
  574.   RV.'INCO' = 'TABLE' 'INCO' ;
  575.   RVP.'INCO' = RV.'INCO' ;
  576.  
  577. * vitesse et quantité de mouvement
  578.   RV.INCO.'UN' = kcht $MT VECT SOMMET (0. 0.);
  579.   RV.INCO.'GN' = kcht $MT VECT SOMMET (0. 0.);
  580. * pression
  581.   RV.INCO.'PRES' = kcht $MT SCAL KPRES   0.   ;
  582. * température
  583.   RV.INCO.'PSIN' = kcht $MT SCAL SOMMET   PSI ;
  584.   RV.INCO.'PSI1' = kcht $MT SCAL SOMMET   PSI ;
  585. * variables modèle de turbulence
  586.   RV.INCO.'EN' = kcht $MT SCAL SOMMET   1.E-5 ;
  587.   RV.INCO.'KN' = kcht $MT SCAL SOMMET   1.E-5 ;
  588.   RV.INCO.'MUT' = kcht $MT SCAL CENTRE  Mu ;
  589.   RV.INCO.'NUT' = kcht $MT SCAL CENTRE  Nu ;
  590. * masse volumique
  591.   RV.INCO.'RHO' = kcht $MT SCAL SOMMET  RHO    ;
  592.   RV.INCO.'RHOC'= kcht $MT SCAL CENTRE  RHO    ;
  593.   RV.INCO.'RHOM'= RHO ;
  594. * fractions massiques
  595.   RV.INCO.'YH2' = kcht $MT SCAL SOMMET  YH2   ;
  596.   RV.INCO.'YO2' = kcht $MT SCAL SOMMET  YO2   ;
  597.   RV.INCO.'YN2' = kcht $MT SCAL SOMMET  YN2   ;
  598.   RV.INCO.'YH2O'= kcht $MT SCAL SOMMET  YH2O   ;
  599. * termes sources (Poisson/énergie/QDM)
  600.   RV.INCO.'S'=kcht $MT SCAL CENTRE   0.    ;
  601.   RV.INCO.'Q'=kcht $MT SCAL SOMMET   0.    ;
  602.   RV.INCO.'ROG'=kcht $MT VECT CENTRE   (0. 0.)     ;
  603.   RV.INCO.'ZS' = KCHT $MT SCAL CENTRE 0.0 ;
  604. * pression
  605.   RV.INCO.'PM' = P ;
  606. * progressions contenant certaines données
  607.   RV.INCO.'TEMPS' = PROG 0. ;
  608.   RV.INCO.'PRESS' = PROG P ;
  609.   RV.INCO.'MTOTA' = PROG (RHO*VOLT) ;
  610. * debit de masse
  611.   RV.INCO.'DEBIT' = 0. ;
  612.  
  613. MASINI = KOPS RV.INCO.'RHOC' '*' VOL ;
  614. MASINI = SOMT MASINI ;
  615.  
  616. RVP.BETA = 1000. ;
  617.  
  618. exec rv ;
  619.  
  620. MTHEO = MASINI + (RV.INCO.'DEBIT' * RV.PASDETPS.'TPS') ;
  621. MESSAGE MTHEO ;
  622. SI ( (MAXI RV.INCO.'MTOTA') <  (0.95*MTHEO) ) ;
  623.         ERREUR 5 ;
  624. FINSI ; 
  625.  
  626. FIN ;
  627.  
  628.  
  629.  
  630.  
  631.  
  632.  
  633.  
  634.  
  635.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales