Télécharger la plaquette Cast3M


fr en

Télécharger back_pression_1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *****************************************************
  2. * fichier :  back_pression_1.dgibi                  *
  3. ** modifie le 15/06/2014 passage EQPR -> EQEX       *
  4. *****************************************************
  5. ************  CAS TEST : back_pression_1.dgibi  ********************
  6. *
  7. * Ce test permet de vérifier le bon fonctionnement des opérateurs
  8. * utilisés pour la résolution des équations de NAVIER_STOKES en EF
  9. * par un algorithme semi-explicite
  10. *
  11. * Le cas étudié est celui d'un écoulement laminaire dans un canal
  12. * en présence d'une marche descendante. On teste la position du
  13. * point de réattachement par rapport au pied de la marche.
  14. *
  15. * Référence : K. Morgan, J. Périaux anf F. Thomasset, editors,
  16. * Analysis of laminar flow over a backward facing step, Vol9 of
  17. * Notes on numerical Fluid Mechanics, Vieweg, 1984.
  18. *
  19. *-------------------------------------------------------------------
  20. * Auteur : F.Dabbene (LTMF)                                    03/03
  21. *-------------------------------------------------------------------
  22. *
  23. 'SAUT' 'PAGE' ;
  24. 'OPTION' 'DIME' 2 'ELEM' 'QUA8' 'ECHO' 0 ;
  25. *
  26. *- Pilotage du calcul
  27. *
  28. *  DISCR : Element en vitesse (LINE/MACRO, pas QUAF)
  29. *  KPRES : Element en pression (CENTRE, pas CENTREP1/MSOMMET)
  30. *  KSUPG : Méthode de décentrement pour NS (CENTREE/SUPG/SUPGDC)
  31. *          (DFDT en CENTREE en semi-explicite EFM1)
  32. *
  33. *  EPS0    : Test d'arret
  34. *  RAF     : Taille de maille définie par 0.1*raf
  35. *
  36. *  FREQ0   : Fréquence d'évaluation du résidu
  37. *  GRAPH   : Booleen pour les tracés
  38. *  COMPLET : Booleen volume de calcul
  39. *
  40. DISCR = 'MACRO'  ;
  41. KPRES = 'CENTRE' ;
  42. BETAP = 1.       ;
  43. 'SI' ('EGA' discr 'QUAF') ;
  44.      'ERRE' 'VITESSE QUAF interdite en semi-explicite' 5 ;
  45. 'SINON' ;
  46.      'SI' (('NEG' kpres 'CENTRE') 'ET' ('NEG' kpres 'CENTREP1'));
  47.           'ERRE' 'PRESSION CENTRE obligatoire  en semi-explicite' 5 ;
  48.      'FINSI' ;
  49. 'FINSI' ;
  50. KSUPG = 'SUPG' ;
  51. GRAPH   = FAUX ;
  52. COMPLET = FAUX ;
  53. 'SI' COMPLET ;
  54.    FREQ0 = 500  ;
  55.    EPS0  = 1.D-6 ;
  56.    RAF   = 1. ;
  57. 'SINO' ;
  58.    FREQ0 = 20  ;
  59.    EPS0  = 1.D-2 ;
  60.    RAF   = 3. ;
  61. 'FINSI' ;
  62. *
  63. *---------------------------------------------------------------------------
  64. * Recherche du point de réattachement (point où dUx/dy=0)
  65. *---------------------------------------------------------------------------
  66. * 1/ Après avoir calculé le gradient de Ux, on ne conserve que les valeurs
  67. *    sur la frontière qui nous intéresse sous la forme d'une évolution.
  68. * 2/ On borne l'évolution au voisinage du point de réattachement afin
  69. *    d'avoir une variation monotone sur l'intervale de dUx/dy.
  70. * 3/ On recherche par interpolation le zero de la fonction (dUx/dy(s),s)
  71. *    La valeur obtenu est l'abscisse curviligne cherchée
  72. *
  73. * Remarques :
  74. *    (i)  1/ permettrait de calculer le coeff de frottement à la paroi :
  75. *         il suffirait de diviser EV1 par le bon coefficient (Re/2 ici)
  76. *    (ii) Il est impératif que dUx/dy soit monotone sur l'intervale 2/ afin
  77. *         qu'il y ait unicité du zero (principe des valeurs intermédiaires)
  78. *---------------------------------------------------------------------------
  79. *
  80. 'DEBPROC' attac ;
  81. * 1/
  82. Ux    = 'KCHT' $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UX' 0. RV.'INCO'.'UN' ;
  83. DUxDY = 'EXCO' 'UY' ('KOPS' Ux 'GRADS' $DOMTOT) 'SCAL' ;
  84. EV1   = 'EVOL' 'CHPO' DUxDY BOTTOM ;
  85. * 2/
  86. EV2   = 'EXTR' EV1 'APRE' 5.  ;
  87. EV3   = 'EXTR' EV2 'AVAN' 10. ;
  88. * 3/
  89. LX1   = 'EXTR' EV3 'ABSC' ;
  90. LY1   = 'EXTR' EV3 'ORDO' ;
  91. LY1 = 'ORDO' LY1 ;
  92. Ymin  = 'MINI' LY1 ;
  93. Ymax  = 'MAXI' LY1 ;
  94. Delta = Ymin * Ymax ;
  95. 'SI' (Delta < 0.) ;
  96.    Y0 = 0. ;
  97. 'SINON' ;
  98.    'MESS' 'Fonction non monotone' ;
  99.    Y0 = Ymin '+' Ymax '/' 2. ;
  100. *   'ERRE''Fonction non monotone' 5 ;
  101. 'FINSI' ;
  102. V1 = 'IPOL' Y0  LY1 LX1 ;
  103. 'FINP' V1 ;
  104. *
  105. *==================================================================
  106. * Calcul du résidu basé sur la composante horizontale de la vitesse
  107. * et arrêt suivant un critère transmis
  108. *==================================================================
  109. * E/  : RVX      : TABLE     : TABLE des données créées par EQEX
  110. *                  ARG1      : Fréquence d'impression
  111. *                  ARG2      : Critère d'arrêt
  112. *                  ARG3      : Booleen de tracé
  113. *  /S : MAT1     : MATRIK    : Objet vide
  114. *  /S : CHP1     : CHPO      : Objet vide
  115. *------------------------------------------------------------------
  116. * MAT1 et CHP1 permettent d'assurer la compatibilité des opérateurs
  117. * de discrétisation avec les procédures personnelles
  118. *------------------------------------------------------------------
  119. 'DEBPROC' residu rvx*table ;
  120.    RV    = RVX . 'EQEX' ;
  121.    FREQ  = RVX . 'ARG1' ;
  122.    EPS0  = RVX . 'ARG2' ;
  123.    GRAPH = RVX . 'ARG3' ;
  124.    NITER = RV . 'NITER' ;
  125.    DD = RV . 'PASDETPS' . 'NUPASDT' ;
  126.    NN = DD '/' FREQ ;
  127.    L0 = 'EGA' (DD '-' (FREQ*NN)) 0 ;
  128.    'SI' L0 ;
  129.       RANG0 = RV . 'PASDETPS' . 'NUPASDT' ;
  130.       TIME0 = RV . 'PASDETPS' . 'TPS'     ;
  131.       UN0   = 'EXCO' 'UX' RV . 'INCO' . 'UN'  'SCAL' ;
  132.       UNM0  = 'EXCO' 'UX' RV . 'INCO' . 'UN2' 'SCAL' ;
  133.       ERR0  = ('MAXIMUM' ('ABS' (UN0 '-' UNM0))) '+' 1.D-20 ;
  134.       ERR10 = ('LOG' ERR0 ) '/' ('LOG' 10.) ;
  135.       'MESSAGE' 'Résidu en vitesse suivant X au pas'
  136.            RANG0 '(t=' TIME0 ') :' ERR0 ':' ERR10 ;
  137.       RV . 'INCO' . 'IT'  = RV . 'INCO' . 'IT' 'ET' ('PROG' RANG0) ;
  138.       RV . 'INCO' . 'TI'  = RV . 'INCO' . 'TI' 'ET' ('PROG' TIME0) ;
  139.       RV . 'INCO' . 'ER'  = RV . 'INCO' . 'ER' 'ET' ('PROG' ERR10) ;
  140.       V1 = attac ;
  141.       RV . 'INCO' . 'POSI' = RV . 'INCO' . 'POSI' 'ET' ('PROG' V1) ;
  142.       Y1 = ('LOG' EPS0) '/' ('LOG' 10) ; Y2 = 0. ;
  143.      'SI' GRAPH ;
  144.           EV1 = 'EVOL' 'MANU' (RV . 'INCO' . 'IT')(RV . 'INCO' . 'ER') ;
  145.          'DESSIN' EV1 'YBOR' Y1 Y2 'NCLK' ;
  146.       'FINSI' ;
  147.       'SI' ((ERR10 < Y1) 'ET' (DD > ('MAXI' ('LECT' 10 FREQ)))) ;
  148.          RV . 'TFINAL' = RV . 'PASDETPS' . 'TPS' ;
  149.       'FINSI' ;
  150.    'FINSI' ;
  151.    RV . 'INCO' . 'UN2' = 'COPIER' RV . 'INCO' . 'UN' ;
  152.    mat1 chp1 = 'KOPS' 'MATRIK' ;
  153. 'FINP' mat1 chp1 ;
  154.  
  155. *
  156. *==========
  157. * Maillage
  158. *==========
  159. *
  160. *
  161. *-----------------------------------------------------------------------
  162. *
  163. *
  164. *  <    L1     X                L2 - L1                           >
  165. *
  166. *  7___________6__________________________________________________5
  167. *          ^                                     ^
  168. *  INLET   H1
  169. *          v                                     H2               OUTLET
  170. *  1___________2
  171. *              |                                 v
  172. *              3__________________________________________________4
  173. *                                   BOTTOM
  174. *
  175. *
  176. *-----------------------------------------------------------------------
  177. *
  178. *
  179. * L1   : Longueur de la section d'entrée (avant la marche)
  180. * L2   : Longueur de la totalité du dispositif
  181. * H1   : Hauteur de la section d'entrée
  182. * H2   : Hauteur de la section de sortie
  183. * d1   : Dimension caractéristique d'une maille
  184. L1 = 3.0  ;
  185. L2 = 22.0 ;
  186. H1 = 1.0  ;
  187. H2 = 1.5  ;
  188. d1 = 0.1 * raf ;
  189. *
  190. * H2-H1 : Hauteur de la marche servant à l'adimensionnalisation
  191. HDIM = H2 - H1 ;
  192. L1 = L1 / HDIM ;
  193. L2 = L2 / HDIM ;
  194. H1 = H1 / HDIM ;
  195. H2 = H2 / HDIM ;
  196. d1 = d1 / HDIM ;
  197. *
  198. * Points du maillage
  199. p1 = 0. (H2-H1) ;
  200. p2 = L1 (H2-H1) ;
  201. p3 = L1 0. ;
  202. p4 = L2 0. ;
  203. p5 = L2 H2 ;
  204. p6 = L1 H2 ;
  205. p7 = 0. H2 ;
  206. p8 = L2 (H2-H1) ;
  207. *
  208. * Section d'éntrée
  209. p1p2  = p1 'DROIT' 'DINI' d1 'DFIN' d1 p2 ;
  210. p2p6  = p2 'DROIT' 'DINI' d1 'DFIN' d1 p6 ;
  211. p6p7  = p6 'DROIT' 'DINI' d1 'DFIN' d1 p7 ;
  212. p7p1  = p7 'DROIT' 'DINI' d1 'DFIN' d1 p1 ;
  213. mesh1 = 'DALL' p1p2 p2p6 p6p7 p7p1 'PLAN' ;
  214. *
  215. * Section de sortie
  216. p6p2  = 'INVE' p2p6 ;
  217. p2p3  = p2 'DROIT' 'DINI' d1 'DFIN' d1 p3 ;
  218. p3p4  = p3 'DROIT' 'DINI' d1 'DFIN' d1 p4 ;
  219. p4p8  = p4 'DROIT' 'DINI' d1 'DFIN' d1 p8 ;
  220. p8p5  = p8 'DROIT' 'DINI' d1 'DFIN' d1 p5 ;
  221. p5p6  = p5 'DROIT' 'DINI' d1 'DFIN' d1 p6 ;
  222. mesh2 = 'DALL' (p6p2 'ET' p2p3) p3p4 (p4p8 'ET' p8p5) p5p6 'PLAN' ;
  223. *
  224. *
  225. *=======================
  226. * Modèles NAVIER_STOKES
  227. *=======================
  228. *
  229. *
  230. * Définition des équations
  231. * $DOMTOT : Modèle volumique défini sur le maillage complet
  232. *
  233. * Conditions aux limites en vitesse :
  234. * $INLET  : Modèle surfacique défini à l'entrée fluide (Poiseuille)
  235. * $WALL   : Modèle surfacique défini sur les murs (adhérence en paroi)
  236. *
  237. * Conditions aux limites en pression :
  238. * $OUTLET : Modèle surfacique défini à la sortie fluide (sert à imposer
  239. *           la pression de sortie en pression continue MSOMMET)
  240. *
  241. * Post-traitement
  242. * $BOTTOM : Modèle surfacique défini sur le plancher après la marche
  243. *           (sert à évaluer la position du point de réattachement)
  244. *
  245. DOMTOT  = 'CHAN' 'QUAF' (mesh1 ET mesh2) ;
  246. $DOMTOT = 'MODE' DOMTOT 'NAVIER_STOKES' DISCR ;
  247. $INLET  = 'MODE' p7p1   'NAVIER_STOKES' DISCR ;
  248. $OUTLET = 'MODE' (p4p8 'ET' p8p5) 'NAVIER_STOKES' DISCR ;
  249. $BOTTOM = 'MODE' p3p4 'NAVIER_STOKES' DISCR ;
  250. $WALL   = 'MODE' (p1p2 ET p2p3 ET p3p4 ET p5p6 ET p6p7)
  251.                  'NAVIER_STOKES' DISCR ;
  252. *
  253. * Elimination ad hoc
  254. * (En 2D, il faut éliminer les points centres des modèles surfaciques
  255. * avec les points faces des modèles volumiques à cause des MACROs)
  256. FDOMTOT = 'DOMA' $DOMTOT 'FACE'   ;
  257. CINLET  = 'DOMA' $INLET  'CENTRE' ;
  258. COUTLET = 'DOMA' $OUTLET 'CENTRE' ;
  259. CBOTTOM = 'DOMA' $BOTTOM 'CENTRE' ;
  260. CWALL   = 'DOMA' $WALL   'CENTRE' ;
  261. 'ELIM' (FDOMTOT 'ET' CINLET 'ET' COUTLET 'ET' CWALL 'ET' CBOTTOM) EPS0 ;
  262. *
  263. * On écrase les anciens maillages afin d'éviter toute ambiguitée
  264. DOMTOT = 'DOMA' $DOMTOT 'MAILLAGE' ;
  265. INLET  = 'DOMA' $INLET  'MAILLAGE' ;
  266. OUTLET = 'DOMA' $OUTLET 'MAILLAGE' ;
  267. BOTTOM = 'DOMA' $BOTTOM 'MAILLAGE' ;
  268. WALL   = 'DOMA' $WALL   'MAILLAGE' ;
  269. *
  270. * Maillage pour d'éventuelles conditions aux limites en pression
  271. 'SI' ('EGA' kpres 'MSOMMET') ;
  272.    OUTLETP = 'DOMA' $outlet KPRES ;
  273. 'SINON' ;
  274.    OUTLETP = 'DOMA' $domtot KPRES ;
  275. 'FINSI' ;
  276. *
  277. *===========================
  278. * Description des équations
  279. *===========================
  280. *
  281. * Grandeurs adimensionnées
  282. Umax = 1.0  ;
  283. Re   = 150. ;
  284. *
  285. * Profil de vitesse parabolique à l'entrée
  286. YINLET = 'COOR' 2 INLET ;
  287. YMAX   = 'MAXI' YINLET ;
  288. YMIN   = 'MINI' YINLET ;
  289. UIN = (YINLET '-' YMAX) '*' (YINLET '-' YMIN) ;
  290. UIN = UIN '*' (-4.0*Umax/((YMAX-YMIN)*(YMAX-YMIN))) ;
  291. UIN = 'NOMC' 'UX' UIN 'NATU' 'DISCRET' ;
  292. VIN = 'KCHT' $INLET 'SCAL' 'SOMMET' 'COMP' 'UY' 0.  ;
  293. *
  294. * Description du système en vitesse-pression
  295. RV = 'EQEX' $DOMTOT 'ITMA' 50000 'ALFA' 0.75 'FIDT' 100
  296.            'OPTI' 'EFM1' 'EXPL'  KSUPG KPRES
  297.            'ZONE' $DOMTOT 'OPER' residu FREQ0 EPS0 GRAPH
  298.            'ZONE' $DOMTOT 'OPER' 'NS'   (1./Re) 'INCO' 'UN'
  299. *                                          Conditions aux limites par défaut
  300. *                           'ZONE' $OUTLET 'OPER' 'TOIM' (0. 0.) 'INCO' 'UN'
  301.            'OPTI' 'EFM1' 'CENTREE'
  302.            'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'UN' 'DELTAT' 'INCO' 'UN'
  303. ;
  304.  
  305. RVP = EQEX 'OPTI' 'EF' KPRES
  306.  'ZONE' $DOMTOT  OPER  KBBT  -1. betap  INCO 'UN' 'PRES'
  307. ;
  308.  
  309.     rvp.'METHINV'.TYPINV=1 ;
  310.     rvp.'METHINV'.IMPINV=0 ;
  311.     rvp.'METHINV'.NITMAX=300;
  312.     rvp.'METHINV'.PRECOND=3 ;
  313.     rvp.'METHINV'.RESID  =1.e-8 ;
  314.     rvp.'METHINV' . 'FCPRECT'=100 ;
  315.     rvp.'METHINV' . 'FCPRECI'=100 ;
  316.  
  317. * Algorithme de résolution : méthode semi-explicite
  318.   RV.'PROJ'     =RVP ;
  319.  
  320. *                      En milieu ouvert, pression discontinue il est inutile
  321. *                                          d'imposer la pression en un point
  322. *                                 'CLIM' 'PRES' 'TIMP' (OUTLETP 'ELEM' 1) 0.
  323. ;
  324. *
  325. * Description des conditions aux limites
  326. RV = 'EQEX' RV
  327.            'CLIM' 'UN' 'UIMP' WALL  0.  'UN' 'VIMP' WALL  0.
  328.                   'UN' 'UIMP' INLET UIN 'UN' 'VIMP' INLET VIN
  329. ;
  330. *
  331. * Déclaration des inconnues et initialisations (table INCO)
  332. RV . 'INCO'          = 'TABLE' 'INCO' ;
  333. RV . 'INCO' . 'UN'   = 'KCHT' $DOMTOT 'VECT' 'SOMMET' (0. 0.) ;
  334. RV . 'INCO' . 'PRES' = 'KCHT' $DOMTOT 'SCAL'  KPRES   0.      ;
  335. *
  336. * Champs supplémentaires pour la procédure residu
  337. RV . 'INCO' . 'IT'   = 'PROG' ;
  338. RV . 'INCO' . 'TI'   = 'PROG' ;
  339. RV . 'INCO' . 'ER'   = 'PROG' ;
  340. RV . 'INCO' . 'POSI' = 'PROG' ;
  341. RV . 'INCO' . 'UN2'  = 'KCHT' $DOMTOT 'VECT' 'SOMMET' (1.D-3 1.D-3) ;
  342. *
  343. *
  344. EXEC RV ;
  345. *
  346. *=================
  347. * Post-traitement
  348. *=================
  349. *
  350. * Localisation du point de réattachement
  351. * Tracés de la vitesse et de la pression
  352. *
  353. CNT1 = WALL ;
  354. NLI0 = 14   ;
  355. *
  356. * Point de réattachement (point où dUx/dy=0)
  357. V1    = attac ;
  358. 'SAUT' 10 'LIGNE' ;
  359. 'MESS' 'ABSCISSE DU POINT DE REATTACHEMENT :' V1 ;
  360. 'SI' GRAPH ;
  361.   EV1 = 'EVOL' 'MANU' RV . 'INCO' . 'TI' RV . 'INCO' . 'POSI' ;
  362.   'DESS' EV1 'MIMA' 'GRIL' 'TITR' 'Localisation reattachement = f(t)' ;
  363. *
  364. * Vitesse
  365.   un  = RV . 'INCO' . 'UN' ;
  366.   vun = 'VECT' UN 0.5 'UX' 'UY' 'JAUNE' ;
  367.   trace vun DOMTOT CNT1 'TITR' 'Vitesse' ;
  368. *
  369. * Pression
  370.   pn = 'ELNO' $domtot RV . 'INCO' . 'PRESSION' ;
  371. *                                 Champ créé si tout se passe bien
  372. *                                         pn = RV . 'INCO' . 'PN' ;
  373.   trace pn domtot CNT1 NLI0 'TITR' 'Pression' ;
  374. 'FINSI' ;
  375. *
  376. *========================
  377. * Test de non régression
  378. *========================
  379. *
  380. 'SI' COMPLET ;
  381.    TEST = ('ABS' (V1 '-' 6.158)) < 0.0005 ;
  382. 'SINON' ;
  383.    TEST = ('ABS' (V1 '-' 9.117)) < 0.0005 ;
  384. 'FINSI' ;
  385. 'MESSAGE' 'Element Vitesse  : ' DISCR ;
  386. 'MESSAGE' 'Element Pression : ' KPRES ;
  387. 'MESSAGE' 'Décentrement     : ' KSUPG ;
  388. 'SI' TEST ;
  389.    'ERREUR' 0 ;
  390. 'SINON' ;
  391.     'ERREUR' 5 ;
  392. 'FINSI' ;
  393. *
  394. 'FIN' ;
  395.  
  396.  
  397.  
  398.  
  399.  
  400.  
  401.  
  402.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales