Télécharger la plaquette Cast3M


fr en

Télécharger aitr_2D.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  aitr_2D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. GRAPH = FAUX ;
  6. *
  7. *----------------------- aitr_2D.dgibi
  8. *
  9. * Scénario de type LOVA dans ITER
  10. *
  11. *
  12. ELI1 = 1.D-5 ;
  13. D1   = 6 ;
  14. *GRAPH = VRAI ;
  15. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' ;
  16. 'OPTI' 'TRAC' 'PSC'           ;
  17. *
  18. *=========
  19. * Maillage
  20. *=========
  21. *
  22. *
  23. *= Points definition
  24. *
  25. *
  26. *-----------------------> Vacuum Vessel
  27. *      Modif pour avoir un raccord avec le LP plus propre
  28. P1  =  5.6 -4.8 ;
  29. P01 =  6.8 -4.1 ;
  30. *                                      P1  = 5.00 -4.80 ;
  31. *                                      P01 = 6.50 -4.30 ;
  32. P2  =  7.3 -3.1 ;
  33. P3  =  6.1 -2.9 ;
  34. P4  =  7.9 -0.3 ;
  35. P02 =  7.9  0.8 ;
  36. P5  =  7.9  1.9 ;
  37. P6  =  7.1  3.4 ;
  38. *                         Modif pour n avoir que des QUA4
  39. P7  =  6.5  4.2 ;
  40. *                                       P7  =  6.3  4.2 ;
  41. *                 Modif pour avoir avec le UP plus propre
  42. P8  =  5.6  4.6 ;
  43. *                                      P8  = 5.60  4.80 ;
  44. P9  =  4.7  4.8 ;
  45. P10 =  4.0  4.2 ;
  46. P11 =  4.0  1.9 ;
  47. P03 =  4.0  0.8 ;
  48. P12 =  4.0 -0.3 ;
  49. P13 =  4.0 -1.3 ;
  50. P14 =  4.3 -2.3 ;
  51. P15 =  4.0 -2.3 ;
  52. P16 =  4.0 -3.4 ;
  53. *
  54. *-----------------------> Lower Port
  55. L1  =  9.8 -5.4 ;
  56. L2  = 10.7 -5.4 ;
  57. L3  = 10.7 -3.4 ;
  58. L4  =  9.8 -3.4 ;
  59. *
  60. *-----------------------> Equatorial Port
  61. E1  = 10.7 -0.3 ;
  62. E2  = 10.7  1.9 ;
  63. *
  64. *-----------------------> Upper Port
  65. U1  = 10.7  5.0 ;
  66. U2  = 10.5  6.1 ;
  67. *
  68. *
  69. *= Lines definition
  70. *
  71. *
  72. *-----------------------> Vacuum Vessel
  73. P01P2  = P01 'DROI' D1 P2  ;
  74. P2P3   = P2  'DROI' D1 P3  ;
  75. P3P4   = 'CERC' (3*D1) P3 (5. 0.) P4 ;
  76. *
  77. *P4P02  = P4  'DROI' D1 P02 ;
  78. *
  79. PI1  =  7.9 -0.05 ;
  80. PI2  =  7.9  0.05 ;
  81. NN2  =  ENTIER (D1/2.) ;
  82. P4PI1  = P4  'DROI' NN2 PI1 ;
  83. PI1PI2 = PI1 'DROI' 4   PI2 ;
  84. PI2P02 = PI2 'DROI' NN2 P02 ;
  85. P4P02  = P4PI1 'ET' PI1PI2 'ET' PI2P02 ;
  86. *
  87. P02P5  = P02 'DROI' D1 P5 ;
  88. P5P7   = 'CER3' (3*D1) P5 P6 P7 ;
  89. P7P8   = P7  'DROI' D1 P8 ;
  90. P8P9   = P8  'DROI' D1 P9 ;
  91. P9P10  = P9  'DROI' D1 P10;
  92. P10P11 = P10 'DROI' (3*D1) P11 ;
  93. P11P03 = P11 'DROI' D1 P03 ;
  94. *
  95. *P03P12 = P03 'DROI' D1 P12 ;
  96. *
  97. PI3  =  4.0  0.05 ;
  98. PI4  =  4.0 -0.05 ;
  99. P03PI3 = P03 'DROI' NN2 PI3 ;
  100. PI3PI4 = PI3 'DROI' 4   PI4 ;
  101. PI4P12 = PI4 'DROI' NN2 P12 ;
  102. P03P12 = P03PI3 'ET' PI3PI4 'ET' PI4P12 ;
  103. *
  104. P12P13 = P12 'DROI' D1 P13 ;
  105. P13P14 = P13 'DROI' (2*D1) P14 ;
  106. *                 Suppression du support de blanket (mur interne)
  107. P14P16 = P14 'DROI' (2*D1) P16 ;
  108. *                                    P14P15 = P14 'DROI' D1 P15 ;
  109. *                                    P15P16 = P15 'DROI' D1 P16 ;
  110. *                   Suppression du support de blanket (ancien 2D)
  111. *                                P13P16 = P13 'DROI' (3*D1) P16 ;
  112. P16P1  = 'CERC' (3*D1) P16 (5. -3.1) P1 ;
  113. P1P01  = 'CERC' D1 P1 (5. -3.1) P01 ;
  114. *
  115. * P02P03: Séparation entre les 2 parties hautes du VV
  116. * P14P3 : Séparation entre les parties haute et basses du VV
  117. * P1P3  : Séparation entre les 2 parties basses du VV
  118. *
  119. P02P03 = P02 'DROI' (3*D1) P03 ;
  120. P03P02 = 'INVE' P02P03         ;
  121. P14P3  = P14 'DROI' (3*D1) P3  ;
  122. P3P14  = 'INVE' P14P3          ;
  123. P1P3   = P1  'DROI' (2*D1) P3  ;
  124. P3P1   = 'INVE' P1P3           ;
  125. *
  126. * P1P2 : LP Entry
  127. * P4P5 : EP Entry
  128. * P7P9 : UP Entry
  129. *
  130. P1P2   = P1P01  'ET' P01P2  ;
  131. P4P5   = P4P02  'ET' P02P5  ;
  132. P7P9   = P7P8   'ET' P8P9   ;
  133. *                                           Ancienne définition du VV
  134. *                               (en une fois via SURF -> TRI3 & QUA4)
  135. *                             CBOT0  = P16P1  'ET' P1P2   'ET' P2P3 ;
  136. *                             CROUT0 = P3P4   'ET' P4P5   'ET' P5P7 ;
  137. *                                        CTOP0  = P7P9   'ET' P9P10 ;
  138. *   CRIN0  = P10P11 'ET' P11P03 'ET' P03P12 'ET' P12P13 'ET' P13P16 ;
  139. *                CONT0  = CBOT0  'ET' CROUT0 'ET' CTOP0  'ET' CRIN0 ;
  140. *                                                 VV00 = SURF CONT0 ;
  141. *
  142. *                        Ancienne définition de la partie haute du VV
  143. *                                      (en une fois via DALL -> QUA4)
  144. *                                                    CBOT0  = P14P3 ;
  145. *                             CROUT0 = P3P4   'ET' P4P5   'ET' P5P7 ;
  146. *                                        CTOP0  = P7P9   'ET' P9P10 ;
  147. *   CRIN0  = P10P11 'ET' P11P03 'ET' P03P12 'ET' P12P13 'ET' P13P14 ;
  148. *                        VV01   = 'DALL' CBOT0 CROUT0  CTOP0  CRIN0 ;
  149. CTOP0H  = P7P9   'ET' P9P10 ;
  150. CRIN0H  = P10P11 'ET' P11P03 ;
  151. CBOT0H  = P03P02 ;
  152. CROUT0H = P02P5  'ET' P5P7 ;
  153. VV01H   = 'DALL' CBOT0H CROUT0H CTOP0H CRIN0H ;
  154. CTOP0B  = P02P03 ;
  155. CRIN0B  = P03P12 'ET' P12P13 'ET' P13P14 ;
  156. CBOT0B  = P14P3 ;
  157. CROUT0B = P3P4   'ET' P4P02 ;
  158. VV01B   = 'DALL' CBOT0B CROUT0B CTOP0B CRIN0B ;
  159. VV01    = VV01H 'ET' VV01B ;
  160. *
  161. VV021   = 'DALL' P16P1 P1P3 P3P14 P14P16 ;
  162. VV022   = 'SURF' (P1P2 'ET' P2P3 'ET' P3P1) ;
  163. VV02    = (VV021 'ET' VV022) 'COUL' 'JAUN' ;
  164. VV00    = VV01 ET VV02 ;
  165. *
  166. *-----------------------> Upper Port
  167. P7U1 = P7 'DROI' (4*D1) U1 ;
  168. U1U2 = U1 'DROI' (2*D1) U2 ;
  169. U2P9 = U2 'DROI' (4*D1) P9 ;
  170. P9P7 = 'INVE' P7P9 ;
  171. *
  172. UP00 = 'DALL' P7U1 U1U2 U2P9 P9P7 ;
  173. UP00 = UP00 'COUL' 'TURQ' ;
  174. *
  175. *-----------------------> Equatorial Port
  176. P4E1 = P4 'DROI' (4*D1) E1 ;
  177. E1E2 = E1 'DROI' (2*D1) E2 ;
  178. E2P5 = E2 'DROI' (4*D1) P5 ;
  179. P5P4 = 'INVE' P4P5 ;
  180. *
  181. EP00 = 'DALL' P4E1 E1E2 E2P5 P5P4 ;
  182. EP00 = EP00 'COUL' 'ROUG' ;
  183. *
  184. *-----------------------> Lower Port + Raccord Bas du VV
  185. P1L1 = P1 'DROI' (3*D1) L1 ;
  186. L1L2 = L1 'DROI' D1 L2 ;
  187. L2L3 = L2 'DROI' (2*D1) L3 ;
  188. L3L4 = L3 'DROI' D1 L4 ;
  189. L4P2 = L4 'DROI' (3*D1) P2 ;
  190. P1L2 = P1L1 'ET' L1L2 ;
  191. L3P2 = L3L4 'ET' L4P2 ;
  192. P2P1 = 'INVE' P1P2 ;
  193. LP00 = 'DALL' P1L2 L2L3 L3P2 P2P1 ;
  194. LP00 = LP00 'COUL' 'VERT' ;
  195. *
  196. *- Tracé du maillage 2D
  197. *
  198. *
  199. *TRAC (VV00 ET LP00 ET EP00 ET UP00) ;
  200. *
  201. * Maillage de la brêche
  202. VV0   = VV00  ELEM 'JAUNE' ;
  203. VV0   = 'DIFF' VV00 VV0 ;
  204. X1 Y1 = 'COOR' VV0;
  205. Xmax  = 'MAXI' X1;
  206. *
  207. * Géométrie considéré : VV + UP
  208. VV0 = VV0 'ET' UP00 ;
  209. *
  210. EVV2 = 'CONT' VV0 ;
  211. VV2  = EVV2 'ELEM' 'TURQ' ;
  212. EVV0 = 'DIFF' EVV2 VV2 ;
  213. *
  214. Pt0  = Xmax 0.0  ;
  215. pjg  =  'POIN' EVV0 'PROC' Pt0                 ;
  216. jg   = ('ELEM' EVV0 'APPUYE' 'LARGEMENT' pjg) 'COUL' 'VERT';
  217. jg   = ('ELEM' EVV0 'APPUYE' 'LARGEMENT'  jg) 'COUL' 'VERT';
  218. jg2  = ('ELEM' EVV0 'APPUYE' 'LARGEMENT'  jg) 'COUL' 'VERT';
  219. *
  220. EVV1 = DIFF EVV0 jg2 ;
  221. src  = jg ;
  222. *
  223. *=================
  224. * DATA du scenario
  225. *=================
  226. *
  227. *
  228.  rxt          =  table                                        ;
  229.  rxt.'VERSION'= 'V0'                                          ;
  230.  rxt.'vtf'    =  VV0                                          ;
  231. *
  232. * Definition du mur chaud :
  233.  rxt.'TIMP'                    = table                             ;
  234.  rxt.'TIMP'.'TIMP1'            = table                             ;
  235.  rxt.'TIMP'.'TIMP1'.'MAILLAGE' = EVV1                              ;
  236.  rxt.'TIMP'.'TIMP1'.'t'        =
  237.  prog 0.0   40.0  160.0 350.0 718.0 1150. 1400. ;
  238.  rxt.'TIMP'.'TIMP1'.'TIMP'     =
  239.  prog 1080. 1077. 1077. 1070. 1000. 935.0 900.0 ;
  240.  rxt.'TIMP'.'TIMP1'.'ECHAN'    = 10. ;
  241. *
  242. * Definition de la breche :
  243. *
  244. * Point intérieur
  245.  rxt.'pi'     =  (5.0 2.0)                                   ;
  246. *
  247.  rxt.'VAPEUR' =  VRAI                                        ;
  248.  rxt.'FRPREC' = 3                                            ;
  249.  rxt.'IMPR'   = 1                                            ;
  250. *
  251. * Conditions initiales (data bidon)
  252.  rxt.'TF0'      =       500.0             ;
  253.  rxt.'PT0'      =       0.02E5            ;
  254.  rxt.'Yvap0'    =       0.95              ;
  255. *
  256. * Scenario
  257.  rxt . 'Breches' = 'TABLE' ;
  258.  rxt . 'Breches' . 'A' = 'TABLE' ;
  259.  rxt . 'Breches' . 'A' . 'Maillage' =  src ;
  260.  rxt . 'Breches' . 'A' . 'diru'     =  (-1.0 0.0) ;
  261.  rxt . 'Breches' . 'A' . 'scenario' = 'TABLE' ;
  262.  rxt . 'Breches' . 'A' . 'scenario' . 't'    =
  263.  PROG 0.0  100. 330.0  335.0 1300. ;
  264.  rxt . 'Breches' . 'A' . 'scenario' . 'qair' =
  265.  PROG 0.0  0.0  0.0    0.0   0.0   ;
  266.  rxt . 'Breches' . 'A' . 'scenario' . 'qeau' =
  267.  PROG 0.011 0.005 0.001  0.0005 0.0002 ;
  268.  rxt . 'Breches' . 'A' . 'scenario' . 'tinj' =
  269.  PROG 150.  150. 150.  150.  150.  ;
  270. *
  271. * Eléments Vitesse/pression
  272.  rxt.'DISCR'  =  'LINE'                  ;
  273.  rxt.'KPRE'   =  'MSOMMET'                ;
  274. *
  275.  rxt.'epsi'   =  1.0e-2                   ;
  276. *
  277. * Viscosite turbulente (m2/s)
  278.  rxt.'MODTURB' =  'NUTURB'      ;
  279.  rxt.'NUT'     =  8.E-2         ;
  280. *
  281.  rxt.'GRAPH' =  FAUX                    ;
  282.  rxt.'DT0'    = 0.2                     ;
  283. *
  284. *
  285. *==========
  286. * Execution
  287. *==========
  288. *
  289. *
  290.  execrxt 10  rxt                        ;
  291.  rxt.'GRAPH' =  GRAPH                   ;
  292.  execrxt 10  rxt                        ;
  293. *
  294. *
  295. *================
  296. * Post-traitement
  297. *================
  298. *
  299. *
  300. 'SI' GRAPH ;
  301.    vtf = rxt . 'GEO' . 'vtf' ;
  302.    tps = rxt . 'TIC' . 'Tps' ;
  303. *
  304. ***   -----------------------    TRACE DE LA TEMPERATURE
  305.      TF   = rxt.'TIC'.'TF'   ;
  306.      TIT1 = 'CHAINE' 'Temperature a t = ' tps;
  307.      'TRAC' TF vtf ('CONT' vtf) 'TITR' TIT1 ;
  308. *
  309. ***   -----------------------    TRACE DE LA VITESSE
  310.      UN=rxt.'TIC'.'UN';
  311.      UNG2 = VECT UN  0.3 UX UY  'ROUGE'  ;
  312.      TIT1 = 'CHAINE' 'Vecteur vitesse a t = ' tps;
  313.      'TRAC' UNG2 vtf ('CONT' vtf) 'TITR' TIT1 ;
  314. *
  315. ***   -----------------------    TRACE DE YVAP
  316.      YVAP = rxt.'TIC'.'YVAP'   ;
  317.      TIT1 ='CHAINE' 'Fraction massique de Vapeur a t = ' tps;
  318.      'TRAC' YVAP vtf ('CONT' vtf) 'TITR' TIT1 ;
  319. *
  320. ***   -----------------------    TRACE DE YAIR
  321.      YAIR  = rxt.'TIC'.'YAIR'   ;
  322.      TIT1='CHAINE' 'Fraction massique d air a t = ' tps;
  323.      trace YAIR vtf (CONT vtf) 'TITR' TIT1 ;
  324. 'FINSI';
  325. *
  326. *========================
  327. * Tests de non-regression
  328. *========================
  329. *
  330. ERR = 0 ;
  331. *
  332. * Tests sur les fractions massiques
  333. YAIR  = rxt.'TIC'.'YAIR'   ;
  334. MinYa = MINI YAIR          ;
  335. MaxYa = MAXI YAIR          ;
  336. YVAP  = rxt.'TIC'.'YVAP'   ;
  337. MinYv = MINI YVAP          ;
  338. MaxYv = MAXI YVAP          ;
  339. V1    = MinYa + MaxYv      ;
  340. V2    = MaxYa + MinYv      ;
  341. 'SI' (('ABS' (V1 - 1.0)) > 1d-15)      ;
  342.    ERR = ERR + 1              ;
  343.    'MESS' 'Erreur sur les fractions massiques' ;
  344. 'FINSI';
  345. 'SI' (('ABS' (V2 - 1.0)) > 1d-15)      ;
  346.    ERR = ERR + 1              ;
  347.    'MESS' 'Erreur sur les fractions massiques' ;
  348. 'FINSI';
  349. *
  350. * Test sur la pression, température, vitesse maxi
  351. * à la fin du calcul (t=4s)
  352. *
  353. * v2016 (avec transport de l'air)
  354. PT4    = 3249.0 ;
  355. Tfm4   = 723.35 ;
  356. LMAXU4 = 8.7475 ;
  357. *
  358. * 2021/06 (passage de TIMP1 à TIMP et sans transort de l'air)
  359. PT4    = 3249.7 ;
  360. Tfm4   = 723.60 ;
  361. LMAXU4 = 8.7458 ;
  362. *
  363. N1     = 'DIME' (rxt.'TIC'.'LTPS') ;
  364. PTc    = 'EXTR' (rxt.'TIC'.'PT')    N1 ;
  365. Tfmc   = 'EXTR' (rxt.'TIC'.'Tfm')   N1 ;
  366. LMAXUc = 'EXTR' (rxt.'TIC'.'LMAXU') N1 ;
  367. 'LIST' ptc ; 'LIST' Tfmc ; 'LIST' LMAXUc ;
  368. *
  369. EPSS   = 1.E-4 ;
  370. *
  371. ERRPT  = (PTc-PT4)/PT4 ; 'LIST' ERRPT ; 'LIST' PT4 ;
  372. 'SI' ( ('ABS' ERRPT) '>EG' EPSS ) ;
  373.    ERR = ERR + 1 ;
  374.    'MESS' 'Erreur sur la pression'     ;
  375. 'FINSI';
  376. ERRTF = (Tfmc-Tfm4)/Tfm4 ; 'LIST' ERRTF ; 'LIST' Tfm4 ;
  377. 'SI' ( ('ABS' ERRTF) '>EG' EPSS )   ;
  378.    ERR = ERR + 1 ;
  379.    'MESS' 'Erreur sur la temperature'  ;
  380. 'FINSI';
  381. ERRVM = (LMAXUc-LMAXU4)/LMAXU4 ; 'LIST' ERRVM ; 'LIST' LMAXU4 ;
  382. 'SI' ( ('ABS' ERRVM) '>EG' EPSS  )   ;
  383.    ERR = ERR + 1              ;
  384.    'MESS' 'Erreur sur la vitesse maxi' ;
  385. 'FINSI';
  386. *
  387. 'SI' (ERR > 0);
  388. 'MESS' 'Il y a ' ERR ' erreurs';
  389. 'ERRE' 5 ;
  390. 'FINSI';
  391. *
  392. 'FIN';
  393.  
  394.  
  395.  
  396.  
  397.  
  398.  
  399.  
  400.  
  401.  
  402.  
  403.  
  404.  
  405.  
  406.  
  407.  
  408.  
  409.  
  410.  
  411.  
  412.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales