Exemples de jeux de données Cast3M

** Petit test de l'operateur AGRE : fonctions d'agregation
 
 
** Plusieurs listes de nombres rassemblees dans une table
tl = TABL ;
*  une suite de nombres quelconques
tl . 1 = PROG 4. 8. 15. 16. 23. 42. ;
*  une suite aleatoire
tl . 2 = BRUI 'BLAN' 'GAUSS' 42. 12. 60 ;
*  une suite un peu singuliere
tl . 3 = PROG 50*3. 100. ;
 
 
** Pour chaque liste, on calcule l'ensemble des fonctions d'agregation disponibles
REPE bl (DIME tl) ;
  l1   = tl . &bl ;
  n1   = DIME l1 ;
  min  = MINI l1 ;
  max  = MAXI l1 ;
* Parametre pour les fonctions
  p    = 4. ;
  np   = ENTI p ;
* Calcul des fonctions
  som = AGRE 'SOMM' l1 ;
  pro = AGRE 'PROD' l1 ;
  moy = AGRE 'MOYE' l1 ;
  moh = AGRE 'MOHA' l1 ;
  mog = AGRE 'MOGE' l1 ;
  var = AGRE 'VARI' l1 ;
  sig = AGRE 'ECTY' l1 ;
  asy = AGRE 'ASYM' l1 ;
  kur = AGRE 'KURT' l1 ;
  med = AGRE 'MEDI' l1 ;
  mop = AGRE 'PMOM' l1 p ;
  pmo = AGRE 'PMOY' l1 p 'ROBU' ;
  pno = AGRE 'PNOR' l1 p 'ROBU' ;
  leh = AGRE 'LEHM' l1 p 'ROBU' ;
  ks1 = AGRE 'KSL'  l1 p 'ROBU' ;
  ks2 = AGRE 'KSU'  l1 p 'ROBU' ;
  bol = AGRE 'BOLT' l1 p 'ROBU' ;
  lagre = PROG som pro moy moh mog var sig asy kur med mop pmo pno leh ks1 ks2 bol ;
  lfonc = MOTS 'Somme' 'Produit' 'Moyenne' 'Moyenne harm' 'Moyenne geom' 'Variance' 'Ecart type' 'Asymetrie' 'Kurtosis' 'Mediane'
              (CHAI 'P Moment' np /13) (CHAI 'P Moyenne' np /13) (CHAI 'P Norme' np /13) (CHAI 'Lehmer' np /13)
              (CHAI 'KS-' np /13) (CHAI 'KS+' np /13) (CHAI 'Boltzmann' np /13) ;
* Calcul en Gibiane des memes fonctions
  gsom = SOMM l1 ;
  gmoy = gsom / n1 ;
  gpro = 1. ;
  REPE b1 n1 ;
    x1   = EXTR l1 &b1 ;
    gpro = gpro * x1 ;
  FIN b1 ;
  gvar = (SOMM ((l1 - gmoy) ** 2)) / n1 ;
  gsig = gvar ** 0.5 ;
  gasy = (SOMM (((l1 - gmoy) / gsig) ** 3)) / n1 ;
  gkur = (SOMM (((l1 - gmoy) / gsig) ** 4)) / n1 ;
  l2   = ORDO l1 ;
  SI (EGA (@MOD n1 2) 0) ;
    n12  = n1 / 2 ;
    gmed = ((EXTR l2 n12) + (EXTR l2 (n12 + 1))) / 2. ;
  SINON ;
    gmed = EXTR l2 ((n1 / 2) + 1) ;
  FINSI ;
  gmoh = n1 / (SOMM (1. / l1)) ;
  gmog = gpro ** (1. / n1) ;
  gmop = SOMM (l1 ** p) ;
  gpmo = (gmop / n1) ** (1. / p) ;
  gpno = (SOMM ((ABS l1) ** p)) ** (1. / p) ;
  gleh = gmop / (SOMM (l1 ** (p - 1))) ;
  gks1 = (LOG ((SOMM (EXP (p * l1))) / n1)) / p ;
  gks2 = (LOG (SOMM (EXP (p * l1)))) / p ;
  gbol = (SOMM (l1 * (EXP (p * l1)))) / (SOMM (EXP (p * l1))) ;
  lgibi = PROG gsom gpro gmoy gmoh gmog gvar gsig gasy gkur gmed gmop gpmo gpno gleh gks1 gks2 gbol ;
* Comparaison des valeurs
  OPTI 'ECHO' 0 ;
  SAUT 2 'LIGNE' ;
  MESS 'Valeurs de la liste:' ;
  LIST l1 ;
  MESS ;
  MESS '------------------------' ;
  MESS ' Minimum :' min ;
  MESS ' Maximum :' max ;
  MESS ;
  MESS       ' Fonction    (P) | Operateur AGRE  | Calcul Gibiane  | Ecart relatif' ;
  MESS       '--------------------------------------------------------------------' ;
  lerr = PROG ;
  REPE b1 (DIME lagre) ;
    fagr = EXTR lagre &b1 ;
    fgib = EXTR lgibi &b1 ;
    err  = (fagr - fgib) / fgib ;
    lerr = lerr ET err ;
    MESS ' ' (CHAI (EXTR lfonc &b1) '|' /17 fagr >2 '|' /35 fgib >2 '|' /53 err >2) ;
  FIN b1 ;
  MESS       '--------------------------------------------------------------------' ;
* Test d'erreur
  SI ((MAXI 'ABS' lerr) > 1.E-12) ;
    ERRE 'Probleme dans l''operateur AGRE :-(' ;
  FINSI ;
FIN bl ;
 
FIN ;