Télécharger la plaquette Cast3M


fr en

Télécharger adve_01.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : adve_01.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas-test de l'operateur ADVEction dans la formulation THERMIQUE      *
  5. *                                                                      *
  6. * Comparaison a une solution analytique.                               *
  7. *                                                                      *
  8. * On calcule la temperature d'un fluide qui s'ecoule dans un tuyau     *
  9. * chauffe sur toute sa longueur.                                       *
  10. * On verifie la temperature du fluide en sortie du tuyau.              *
  11. *                                                                      *
  12. * La puissance lineique est de    : 500 W/m                            *
  13. * La temperature en entree est de : 20°C                               *
  14. * La vitesse d'ecoulement est de  : 25 cm/s                            *
  15. * La section du tuyau est de      : 5.e-5 m2, diametre ~ 8 mm          *
  16. * La longueur du tuyau est de     : 5 m                                *
  17. *                                                                      *
  18. * La temperature attendue en sortie est de : 70°C                      *
  19. *                                                                      *
  20. * On utilise les elements lineaires et quadratiques (TUY2,TUY3)        *
  21. *                                                                      *
  22. * On met une conduction legere pour eviter les problemes de pivot nul  *
  23. * dans la matrice                                                      *
  24. *                                                                      *
  25. *----------------------------------------------------------------------*
  26. 'OPTI' 'DIME' 3 'ELEM' 'SEG2' ;
  27. *                                                                      *
  28. * Commentez cette ligne pour voir les traces :                         *
  29. 'OPTI' 'TRAC' 'PSC' ;
  30. *                                                                      *
  31. O1       = 0 0 0 ;
  32. X1       = 1 0 0 ;
  33. P1       = 2.5 * X1 ;
  34. P2       = 5.0 * X1 ;
  35. Y1       = 0 1 0 ;
  36. Z1       = 0 0 1 ;
  37. *                                                                      *
  38. L1       = O1 'DROI' 10 P1 'COUL' 'VERT' ;
  39. L2       = P1 'DROI' 5   P2 ;
  40. L2       = 'CHAN' 'QUAD' L2 'COUL' 'BLEU' ;
  41. 'TITR' ' Maillage du tuyau, longueur = 5 m (Vert=SEG2,Bleu=SEG3) ' ;
  42. 'TRAC' 'QUAL' (L1 'ET' L2) ;
  43. *                                                                      *
  44. mo1      = 'MODE' L1 thermique conduction advection 'TUY2' ;
  45. mo2      = 'MODE' L2 thermique conduction advection 'TUY3' ;
  46. mo1      = mo1 'ET' mo2 ;
  47. *                                                                      *
  48. L0       = L1 'ET' L2 ;
  49. *                                                                      *
  50. * Le flux advectee dans un tuyau est J = Rho.Cp.Sect.V :               *
  51. ma1      = 'MATE' mo1  'RHO' 1.e3 'C' 4.e3 'VITE' 0.25 'SECT' 5.e-5 
  52.                        'K' 1d-7 ;
  53. *                                                                      *
  54. sq1      = 'SOUR' mo1 ma1 L0 (5.e2 / 5.e-5) ;
  55. list (MAXI (resu sq1));
  56. 'TITR' ' Terme source le long du tuyau ' ;
  57. 'DESS' ('EVOL' 'VERT' 'CHPO' sq1 L0 'Q') 'YBOR' 0. 300.  ;
  58. *                                                                      *
  59. KA1      = 'ADVE' mo1 ma1 ;
  60. KC1      = 'COND' mo1 ma1;
  61. *                                                                      *
  62. cl1      = 'BLOQ' T O1 ;
  63. dcl1     = 'DEPI' cl1 20. ;
  64. *                                                                      *
  65. cht2     = 'RESO'           (ka1 'ET' KC1 'ET' cl1) (sq1 'ET' dcl1);
  66. *                                                                      *
  67. 'TITR' ' Evolution de la temperature le long du tuyau ' ;
  68. 'DESS' ('EVOL' 'VERT' 'CHPO' cht2 L0 T) ;
  69. *                                                                      *
  70. * Test :
  71. tref1    = 70. ;
  72. tp1      = 'EXTR' cht2 T P2 ;
  73. err1     = 'ABS' (TREF1 - tp1) / tp1 ;
  74. *                                                                      *
  75. 'OPTI' 'ECHO' 0 ;
  76. 'MESS' ;
  77. mot1     = 'CHAI' ' > Temperature calculee en  sortie = '
  78.   'FORMAT' '(F3.0)' tp1 '°C pour 70°C attendu ' ;
  79. 'MESS' mot1 ;
  80. 'MESS' ' > Erreur relative = ' err1 ;
  81. 'MESS' ;
  82. 'OPTI' 'ECHO' 1 ;
  83. *                                                                      *
  84. 'SI' (err1 > 1.e-5) ;
  85.   'ERRE' 5 ;
  86. 'SINO' ;
  87.   'OPTI' 'ECHO' 0 ;
  88.   'MESS' ;
  89.   'MESS' ' > Test reussi ' ;
  90.   'MESS' ;
  91. 'FINS' ;
  92. *                                                                      *
  93. 'FIN' ;
  94.  
  95.  
  96.  
  97.  
  98.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales