Exemples de jeux de données Cast3M

Télécharger PoutreConsole_Plas_EcrouCineLine.dgibi
* fichier : poutrconsole_plas_ecroucineline.dgibi
**-------------------------------------------------------------**
**                POUTRE CONSOLE EN FLEXION                    **
** MATERIAU ELASTOPLASTIQUE A ECROUISSAGE CINEMATIQUE LINEAIRE **
**-------------------------------------------------------------**
* Option de trace : VRAI/FAUX
B_GRAPH = FAUX ;
 
'OPTION' 'ECHO' 0 ;
 
'OPTION' 'DIME' 3 'ELEM' 'SEG2' ;
 
p1 = 'POIN' 0. 0. 0. ;
p2 = 'POIN' 10. 0. 0. ;
l1 = 'DROI' 1 p1 p2 ;
 
mod1 = 'MODELISER' l1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'CINEMATIQUE' 'POUT' ;
mat1 = 'MATERIAU' mod1 'YOUN' 1.E7 'NU' 0.3 'SIGY' 1.E4 'H' 1.E6
                       'SECT' 0.1 'INRY' 8.3333E-5 'INRZ' 8.33333E-3 'TORS' 1.E-4
                       'VECT' (0. 1. 0.) 'DX' 0. 'DY' 0. 'DZ' 0.3333 ;
 
f1  = 'FORC' (0. +10. 0.) p2 ;
cl1 = 'BLOQ' 'DEPL' 'ROTA' p1 ;
 
lis1 = 'PROG' 0. 3. 6. 9. 12. ;
lis2 = 'PROG' 0. 3. 0. -3. 0.;
ev   = 'EVOL' 'MANU' 'Temps' lis1 'F(t)' lis2 ;
cha1 = 'CHAR' 'MECA' f1 ev ;
 
tab1 = 'TABL' ;
tab1 . 'MODELE'              = mod1 ;
tab1 . 'CARACTERISTIQUES'    = mat1 ;
tab1 . 'CHARGEMENT'          = cha1 ;
tab1 . 'BLOCAGES_MECANIQUES' = cl1 ;
tab1 . 'TEMPS_CALCULES'      = 'PROG' 0. 'PAS' 0.10 12. ;
tab1 . 'STABILITE'           = FAUX ;
tab1 . 'K_SIGMA'             = FAUX ;
tab1 . 'GRANDS_DEPLACEMENTS' = FAUX ;
tab1 . 'PRECISION'           = 1.E-8 ;
 
PASAPAS tab1 ;
 
* Quelques depouillements :
* Passage Reactions -> Force imposee * -1.  (ev_FY = 10. * ev !)
ev_t_FY = (EVOL 'TEMP' tab1 'REACTIONS'    'FY' p1) '*' -1. ;
 
ev_t_UY = EVOL 'TEMP' tab1 'DEPLACEMENTS' 'UY' p2 ;
 
ev_UY_FY = EVOL 'MANU' ('EXTR' ev_t_UY 'ORDO') 'DEPLACEMENT'
                       ('EXTR' ev_t_FY 'ORDO') 'FORCE' ;
 
ev_t_EPSE = EVOL 'TEMP' tab1 'VARIABLES_INTERNES' 'EPSE' 1 1 1 ;
 
** lister ev_t_FY ; lister ev_t_UY ; lister ev_UY_FY ; lister ev_t_EPSE ;
 
* Quelques traces eventuels
* Attention : selon la discretisation temporelle retenue (TEMPS SAUVES), on peut 
* "ne pas avoir" l'instant correspondant a la limite d'elasticite ! 
'SI' B_GRAPH ;
  'DESSIN' ev_t_FY   'GRIL' 'POIN' 'TITR' 'Courbe Force - Temps' ;
  'DESSIN' ev_t_UY   'GRIL' 'POIN' 'TITR' 'Courbe Deplacement - Temps' ;
  'DESSIN' ev_UY_FY  'GRIL' 'POIN' 'TITR' 'Courbe Force - Deplacement' ;
  'DESSIN' ev_t_EPSE 'GRIL' 'POIN' 'TITR' 'Courbe Epse - Temps' ;
'FINSI' ;
 
* Tests de verification :
l_UY_1 = 'IPOL' lis1 ev_t_UY ;
l_FY_2 = 'IPOL' lis1 ev_t_FY ;
l_EP_3 = 'IPOL' lis1 ev_t_EPSE ;
 
** list l_UY_1 ; list l_FY_2 ; list l_EP_3 ;
 
ref_UY_1 = 'PROG' 0.0000    0.31990      0.19990     -0.31990     -0.19990 ;
ref_FY_2 = 'PROG' 0.0000     30.000      0.00000     -30.000      0.00000 ;
ref_EP_3 = 'PROG' 0.0000   1.99880E-03  1.99880E-03  5.99641E-03  5.99641E-03 ;
 
'MESS' ;
'MESS' 'Les comparaisons sont faites pour un maillage avec 1 ELEMENT !' ;
'MESS' ;
r_z = 'MAXI' ('ABS' (l_UY_1 '-' ref_UY_1)) ;
'MESS' 'Comparaison fleche calculee/reference :' ' ' r_z ;
'SI' ('>EG' r_z 7.E-7) ;
  'MESS' 'ERREUR sur la fleche calculee' ; 'ERREUR' 5 ;
'FINSI' ;
r_z = 'MAXI' ('ABS' (l_FY_2 '-' ref_FY_2)) ;
'MESS' 'Comparaison force imposee calculee/reference :' ' ' r_z ;
'SI' ('>EG' r_z 5.E-12) ;
  'MESS' 'ERREUR ANORMALE sur la force imposee' ; 'ERREUR' 5 ;
'FINSI' ;
r_z = 'MAXI' ('ABS' (l_EP_3 '-' ref_EP_3)) ;
'MESS' 'Comparaison deformation plastique cumulee calculee/reference :' ' ' r_z ;
'SI' ('>EG' r_z 6.E-9) ;
  'MESS' 'ERREUR sur la deformation plastique cumulee' ; 'ERREUR' 5 ;
'FINSI' ;
'MESS' ;
 
'FIN' ;