Télécharger la plaquette Cast3M


fr en

Télécharger NeoHookeen_Traction3D.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : NeoHookeen_Traction3D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE NEOHOOKEEN COMPRESSIBLE                *
  6. *                  EN GRANDES TRANSFORMATIONS                          *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2006, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  24.  
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27. * Mettre 1 ou 2 selon le type de calcul voulu
  28. ICALCUL = 1 ;
  29. *
  30. 'SI' ('>' ICALCUL 2) ;
  31.   'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  32.   'ERREUR' 5 ;
  33. 'FINSI' ;
  34.  
  35. title = 'CHAINE' 'NEO-HOOKEEN - ' 'TRACTION UNIAXIALE Z' ;
  36.  
  37. *======================================================================*
  38. *             Geometrie - Maillage                                     *
  39. *======================================================================*
  40. * Longueur (direction x) du pave :
  41. Lg_x = 1. ;
  42. * Largeur (direction y) du pave :
  43. Lg_y = 1. ;
  44. * Hauteur (direction z) du pave :
  45. Lg_z = 1. ;
  46. * Nombre d'elements selon les directions x, y et z :
  47. 'SI' ('EGA' ICALCUL 1) ;
  48.   Nel_x = 1 ;
  49.   Nel_y = 1 ;
  50.   Nel_z = 3 ;
  51.   'OPTION' 'ELEM' 'CUB8' ;
  52. 'FINSI' ;
  53. 'SI' ('EGA' ICALCUL 2) ;
  54.   Nel_x = 3 ;
  55.   Nel_y = 3 ;
  56.   Nel_z = 7 ;
  57.   'OPTION' 'ELEM' 'CU20' ;
  58. 'FINSI' ;
  59. *
  60. P1 =  0.    0. 0. ;
  61. P2 = Lg_x   0. 0. ;
  62. P3 = Lg_x Lg_y 0. ;
  63. P4 =  0.  Lg_y 0. ;
  64. *
  65. L1 = 'DROITE' Nel_x P1 P2 ;
  66. L2 = 'DROITE' Nel_y P2 P3 ;
  67. L3 = 'DROITE' Nel_x P3 P4 ;
  68. L4 = 'DROITE' Nel_y P4 P1 ;
  69. *
  70. SBas = 'DALLER' L1 L2 L3 L4 ;
  71. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  72. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  73. 'SI' GRAPH ;
  74.   'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  75. 'FINSI' ;
  76.  
  77. *======================================================================*
  78. *             Modele - Materiau - Caracteristiques (en Pa)             *
  79. *======================================================================*
  80. * Ne pas oublier de definir les parametres lies a l'elasticite.
  81. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  82. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  83. *
  84. LCMAT = 'MOTS' 'YOUN' 'NU  ' 'C1'  'D  ' ;
  85. MO = 'MODELISER' Pave  'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  86.                        'NON_LINEAIRE' 'UTILISATEUR'
  87.                        'NUME_LOI' 32  'C_MATERIAU' LCMAT ;
  88. *
  89. * Parametres du modele Neo-Hookeen (en Pa)
  90. * CoeC1 = 1. MPa  et  CoeD = 1.E-4 MPa**-1  !
  91. * Lorsque CoeD tend vers 0, on retrouve un modele de type Mooney-Rivlin
  92. * incompressible. Ici on met une valeur "petite" de CoeD pour pouvoir 
  93. * utiliser la solution analytique du modele de Mooney-Rivlin correspon-
  94. * dant pour les tests de comparaison. Si CoeD a une valeur trop "impor-
  95. * tante", il faut modifier la valeur du coefficient de Poisson, qui 
  96. * s'eloigne alors de 0.5 (incompressibilite).
  97. * On fixe le coefficient de Poisson ("proche" de 0.5 si D est "petit").
  98. * Le module de Young initial est alors connu :
  99. * (le module de cisaillement vaut pour ce modele : mu = 2.CoeC1)
  100. * La valeur du module de Young utilise pour les estimations elastiques
  101. * doit etre superieure au module tangent pour le niveau de deformation
  102. * atteint en fin de calcul (sinon risque de non convergence).
  103. CoeC1 = 1. * 1.E+6 ;
  104. YOUini = 2. * (2.*CoeC1) * (1. + 0.5) ;
  105. 'SI' ('EGA' ICALCUL 1) ;
  106.   XNU = 0.497 ;
  107.   CoeD  = 1.E-4 / 1.E+6 ;
  108.   YOU = 100. * YOUini ;
  109. 'FINSI' ;
  110. 'SI' ('EGA' ICALCUL 2) ;
  111.   XNU = 0.495 ;
  112.   CoeD  = 1.E-2 / 1.E+6 ;
  113.   YOU = 200. * YOUini ;
  114. 'FINSI' ;
  115. *
  116. MA = 'MATERIAU' MO  'YOUN' YOU    'NU  ' XNU
  117.                     'C1  ' CoeC1  'D   ' CoeD ;
  118.  
  119. *==================================================================*
  120. *                      Conditions aux limites                      *
  121. *==================================================================*
  122. BL1 = 'BLOQUER' 'UZ  ' Shau ;
  123. BL2 = 'BLOQUER' 'UZ  ' Sbas ;
  124. BL3 = 'BLOQUER' 'UX  ' L4 ;
  125. BL4 = 'BLOQUER' 'UY  ' L1 ;
  126. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  127. *
  128. * Definition des instants du chargement :
  129. t_deb = 0. ;   t_fin = 10. ;
  130. L_tps = 'PROG' t_deb t_fin ;
  131. * Deplacement suivant Z :
  132. L_UZ = 'PROG' 0. (3.0 * Lg_z) ;
  133. FF_z = 'DEPIMP' BL1 1. ;
  134. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMZ' L_UZ ;
  135. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  136.  
  137. *======================================================================*
  138. *             Initialisation de la table pour appel a PASAPAS          *
  139. *======================================================================*
  140. TAB1 = 'TABLE' ;
  141. TAB1.'MODELE' = MO ;
  142. TAB1.'CARACTERISTIQUES' = MA ;
  143. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  144. TAB1.'CHARGEMENT' = CHARTOT ;
  145. *TAB1.'PRECISION' = 1.E-5 ;
  146. *TAB1.'FTOL' = 1.E-5 ;
  147. *TAB1.'MTOL' = 1.E-5 ;
  148. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  149. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  150. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  151. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  152. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  153. *
  154. L_abs = TAB1.'TEMPS_SAUVES' ;
  155. n_abs = 'DIMENSION' L_abs ;
  156. tab1.'REAC_GRANDS' = 500.;
  157. *
  158. PASAPAS TAB1 ;
  159. *
  160. * Quelques traces de controle apres calculs
  161. 'SI' GRAPH ;
  162.   Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  163.   Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  164.   'TRACER' (Defo_0 'ET' Defo_1)
  165.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  166.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  167.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  168. 'FINSI' ;
  169. *
  170. *======================================================================*
  171. *             Construction de la solution analytique                   *
  172. *======================================================================*
  173. * Definitions :
  174. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  175. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  176. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  177. * Dans le cas du modele Neo-Hookeen :
  178. *   W = CoeC1*(I1-3.) , soit dW/dI1 = CoeC1 et dW/dI2 = 0.
  179. *
  180. * Les contraintes de Cauchy sont calculables analytiquement :
  181. * - SCxx = 0.
  182. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  183. * - SCxy = 0  (pas de cisaillement)
  184. * - SCzz = 0  (hypothese des contraintes planes)
  185. *
  186. L_Un  = 'PROG' n_abs '*' 1. ;
  187. Lamz  = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  188. *
  189. SCxx_th = 0. * L_Un ;
  190. SCyy_th = 0. * L_Un ;
  191. L_z1 = Lamz * Lamz ;  L_z2 = L_Un / Lamz ;
  192. SCzz_th = (L_z1 - L_z2) * (2.*CoeC1) ;
  193. SCxy_th = 0. * L_Un ;
  194. SCxz_th = 0. * L_Un ;
  195. SCyz_th = 0. * L_Un ;
  196.  
  197. *======================================================================*
  198. *             Comparaison des resultats avec la solution analytique    *
  199. *======================================================================*
  200. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  201. * calculees et les solutions analytiques correspondantes.
  202. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  203. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  204. *
  205. TabD = TAB1.'DEPLACEMENTS' ;
  206. TabS = TAB1.'CONTRAINTES' ;
  207. Confini = 'FORM' ;
  208. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  209. *
  210. SCxx = 'PROG' 0. ;
  211. SCyy = 'PROG' 0. ;
  212. SCzz = 'PROG' 0. ;
  213. SCxy = 'PROG' 0. ;
  214. SCxz = 'PROG' 0. ;
  215. SCyz = 'PROG' 0. ;
  216. 'REPETER' Boucle (n_abs - 1) ;
  217.   'FORM' (TabD.&Boucle) ;
  218.   VolSU = 'INTG' MO ChmUn ;
  219.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  220.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  221.   SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  222.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  223.   SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  224.   SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  225.   'FORM' Confini ;
  226. 'FIN' Boucle ;
  227. *
  228. 'SI' GRAPH ;
  229.   tlege = 'TABLE' ;
  230.   tlege. 1 = 'MARQ CROI' ;
  231.   tlege.'TITRE' = 'TABLE' ;
  232.   tlege.'TITRE'. 1 = 'Numerique' ;
  233.   tlege.'TITRE'. 2 = 'Analytique' ;
  234.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  235.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  236.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  237.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  238.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  239.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  240.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  241.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  242.   Evzz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  243.   Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  244.   'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  245.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  246.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  247.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  248.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  249.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  250.   Evxz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  251.   Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  252.   'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  253.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  254.   Evyz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  255.   Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  256.   'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  257.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  258. 'FINSI' ;
  259. *
  260. * Tests de bon fonctionnement :
  261. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  262. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  263. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  264. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  265. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  266. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  267. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  268. *
  269. MESS ' RESULTATS : ' title ;
  270. MESS ' ------------------------------------------------- ';
  271. 'SAUTER' 1 'LIGNE' ;
  272. 'MESS' '  Tests de bon fonctionnement :' ;
  273. 'MESS' ' -------------------------------' ;
  274. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  275. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  276. 'MESS' '                          et la solution analytique' ;
  277. 'MESS' ' Composante XX : ' r_xx ;
  278. 'MESS' ' Composante YY : ' r_yy ;
  279. 'MESS' ' Composante ZZ : ' r_zz ;
  280. 'MESS' ' Composante XY : ' r_xy ;
  281. 'MESS' ' Composante XZ : ' r_xz ;
  282. 'MESS' ' Composante YZ : ' r_yz ;
  283. 'SAUTER' 1 'LIGNE' ;
  284. * Ecart relatif maximal tolere
  285. 'SI' ('EGA' ICALCUL 1) ;
  286.   Sigref = 1.E-3 ;
  287. 'FINSI' ;
  288. 'SI' ('EGA' ICALCUL 2) ;
  289.   Sigref = 1.E-2 ;
  290. 'FINSI' ;
  291. *
  292. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  293. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  294.   'MESS' ' ---------------------' ;
  295.   'MESS' '  ECHEC DU CAS-TEST !' ;
  296.   'MESS' ' ---------------------' ;
  297.   'ERREUR' 5 ;
  298. 'SINON' ;
  299.   'MESS' ' ----------------------' ;
  300.   'MESS' '  SUCCES DU CAS-TEST !' ;
  301.   'MESS' ' ----------------------' ;
  302. 'FINSI' ;
  303. 'SAUTER' 1 'LIGNE' ;
  304.  
  305. 'FIN' ;
  306.  
  307.  
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales