Test precont1 Description sheet

Test name

Calculation type

Finite element type

Topic

The structure is a reinforced concrete beam. The reinforcement is made of tendon. The beam is subjected to pressure on upper surface, and embedded on its lower side.

Goal

Reference

Version

Model description

Test precont1 Results

CASTEM FIGURES

*         Test Precont1.dgibi: Jeux de données        *
*         -----------------------------------         *
*                                                     *
*---------------------------------------------------*
* CALCUL AVEC ARMATURE PASSIVE.
* PROGRAMME UTILISANT :
*    - KABL
*    - EQUI RIGI
*   
*---------------------------------------------------*
*  J.S. Fleuret 08/96
*---------------------------------------------------*
titr 'precont1.dgibi';
opti echo 1;
graph='n';
opti dime 2 elem qua4 mode plan;
* 
* GEOMETRIE
*
*---BETON
pa=0.0 0.0;
pb=10.0 0.0;
pc=10.0 1.0;
pd=0.0 1.0;
nb1=40;
nb2=6;
c1=pa droi nb1 pb; 
c2=pb droi nb2 pc; 
c3=pc droi nb1 pd; 
c4=pd droi nb2 pa; 
sur1=dall c1 c2 c3 c4;
*---ARMATURE
pm=0.0 0.1;
pn=10.0 0.1;
***nca = 17 ;
nca = 10 ;
d1 = pm droi nca pn;
*---GEOMETRIE TOTALE
* MODELE
*
modb=modl sur1 mecanique elastique;
d2= (kabl sur1 d1  ) coul roug ;
mod2=modl d2 mecanique elastique armature barr;
*
********d2 = extr mod2 mail;
*
d5= sur1 et d2 ;
si(neg graph 'n');
 titr 'Maillage armature apres KABL';
 trac elem d2;
finsi;
*
* CARACTERISTIQUES
*
mat1=matr modb youn 0.4e11 nu 0.0;
mat2=matr mod2 youn 2.0e11 sect 0.02;
mt=mat1 et mat2;
*
* CONDITIONS AUX LIMITES
*
cl1 = bloq pa ux;
cl2 = bloq pa uy;
cl3 = bloq pb uy;
cltot = cl1 et cl2 et cl3;
*
* CHARGEMENT EN PRESSION
*
cha0 = pres mass modb c3 2.e6;
*
* VERIFICATION QUE PREC ET EQUI FORCES 
* NE PLANTE PAS S'IL MANQUE DES VALEURS
* on n'utilise pas le chargement de precontrainte 
* dans la suite du programme puisque ce calcul
* concerne une armature passive
*
pre1=prec mod2 mat2 0.4e6 pm;
cha1 = -1 * (bsig pre1 mod2 mat2) ;
list cha1 ;
*
* RESOLUTION BETON SOUS PRESSION
*
*---resolution
ri0 = rigi modb mat1;
rig0cl = ri0 et cltot;
dep0 = reso rig0cl cha0;
*  dep0a = proi arma dep0 modb mod2;
   dep0a = proi  d2  ( chan cham dep0 modb ) ;
*---trace de la deformee
de0 = deform (sur1 et d2) dep0 0.  blan;
de1 = deform sur1 dep0 2.0 roug;
de1a = deform d2 dep0a 2.0 roug;
si(neg graph 'n');
 titr 'deformee du beton sous pression';
 trac (de0 et de1 et de1a);
finsi;
*---affichage des valeurs de fleche
pf = sur1 poin proc (5. 0.);
uf = extr dep0 uy pf;
err0 = abs(((abs(uf) - 0.07794)/0.07794)*100);
mess err0;
*---Code de bon fonctionnement
si ( err0 <  6.E-3  ) ;
   erre 0 ;
sinon ;
   erre 5 ;
finsi ;
*
* RESOLUTION AVEC BETON ET ARMATURE SOUS PRESSION
*
*---resolution
rib = rigi modb mat1;
rik = rigi mod2 mat2 ;
tbzon = extr mod2 ZONE ;
makabl = tbzon . 2 ;
ra = rela makabl ACCROCHER sur1 ;
ritot = rib et rik et ra et cltot ;

fotot = cha0 ;

dep1=reso ritot fotot ;
* dep1a = proi arma dep1 modb mod2;
  dep1a = proi  d2  ( chan cham dep1 modb ) ;
*---trace de la deformee

de0=deform (sur1 et d2) dep1 0.  blan;
de1=deform sur1 dep1 2.0 rouge;
de1a=deform d2 dep1a 2.0 rouge;
si(neg graph 'n');
 titr 'deformee avec beton et armature sous pression';
 trac (de0 et de1 et de1a);
finsi;

*---affichage des valeurs de fleche

pf = sur1 poin proc (5. 0.);
uf = extr dep1 uy pf;
mess 'Déplacement calculé =' uf ;
err1 = abs(((abs(uf) - 0.06695)/0.06695)*100);
mess 'Erreur relative commise =' err1 '%' ;

*---Code de bon fonctionnement

si ( err1 <  6.E-3  ) ;
   erre 0 ;
sinon ;
   erre 5 ;
finsi ;
*
* FIN DU FICHIER
*
fin;
*------------------------------------------------------

Test precont1 Comments

1. The ELASTIC ARMATURE material

   MOD1 = MODE D1 MECANIQUE ELASTIQUE ARMATURE BARR ;
   MAT2 = MATE MOD2 YOUN 2.0E11 SECT 0.02 ;
   

   This model concerns the tendons of reinforced concrete (BARR on SEG2). The parameter names for an ELASTIQUE ARMATURE material are as follow:
   In the case of passive tendons, the parameters are:
   

   

   
   In the case of active tendons (surrounding concrete), the additionnal parameters to be defined are:
   For the loss of prestress by friction:
   

   

   
   For the loss of prestress at the anchoring point:
   

   

   
   For the loss of tensile stress of the tendon:
   

   

2. The KABL operator

   MODB = MODE SUR1 MECANIQUE ELASTIQUE ;
   MOD1 = MODE D1 MECANIQUE ELASTIQUE ARMATURE BARR ;
   MOD2 = KABL MODB MOD1 ;
   

   The KABL operator calculates the intersection points between a concrete mesh and cables and creates new uniaxial tendon elements accordingly. The parameters to input are:
   

   

   The KABL operator is usually used with the EQUI, PREC and PROI operators.
   

3. The EQUI operator

   RI1  = EQUI RIGI MODB MOD2 MT ;
   CHA1 = EQUI FORCES MODB MOD2 PRE1 ;
   

   The operator EQUI calculates the stiffness of tendons equivalent to prestresses expressed at the nodes of the concrete.
   

   

4.

The PREC operator

PRE1 = PREC MOD2 MAT2 0.4E6 PM ;

The PREC operator calculates the loss of prestress and the actions of a tendon on the surrounding concrete.

5.

The PROI operator

DEP1A  = PROI ARMA DEP1 MODB MOD2 ;

With the "ARMA" option, the PROI operator projects onto a reinforcement (model MOD2), the displacements of a concrete structure (model MOD1).
The interpolation is done using shape functions of the concrete elements.