Test elas3 Description sheet

Test name

Calculation type

Finite element type

Topic

The problem is similar to elas2, but the cylinder is free and not embedded.

The boundary conditions must reproduce the symmetrical geometry. Just 1/4 of this structure is modelled.
A diametrical load is applied.

Goal

Reference CASTEM

Version

Model description

Test elas3 Results

RESULTS

CASTEM FIGURES

*           Test Elas3.dgibi: Jeux de données         *
*           ---------------------------------         *
*
OPTION ECHO 0;                                                                  
GRAPH='N';                                                                      
SAUT PAGE ;                                                                     
*****************************************************       
* TEST ELAS3                                                                  
*                                                                               
* Meme probleme que DFICH10 mais avec une extrémité 
* libre au lieu d'etre encastrée (la géométrie est 
* différente).                                      
*                                                                               
* Un cylindre est pincé à une extrémité, l'autre reste
* libre.                   
*                                                                               
* Pour des raisons de symétrie seul 1/4 de la structure
* est discrétisé.         
* Les conditions aux limites respectent cette symétrie.                         
*                                                                               
* Une force ponctuelle est appliquée diamétralement.                            
*                                                                               
* La déflexion suivant Z au point d'application de la
* force est comparée à la déflexion théorique (-0.452).                                            
*                                                                               
*****************************************************    
*
OPTION ECHO 0 ;
OPTION DIME 3 ELEM TRI3 ;DENS 0.75 ;
OPTI ISOV LIGNE;
TITR 'CYLINDRE PINCE A BORDS LIBRES' ;
TEMPS ;
*----------------------------------------------------
* DEFINITION DE LA GEOMETRIE
*----------------------------------------------------
P1=4.953 0 0 ;P2=0 0 4.953 ;C1=0 0 0 ;VECT=0 5.175 0 ;
LIG1=C   P1 C1 P2 ;SURF=LIG1 TRAN    VECT ;
LIG1 LIG2 LIG3 LIG4=COTE SURF ;P3=LIG2 POIN FINA ;
*----------------------------------------------------
* TRACE
*----------------------------------------------------
OEIL1 = 100 100 100;
SI(NEG GRAPH 'N');
   TRAC OEIL1 SURF;
FINSI;
*----------------------------------------------------
* DEFINITION DU MODELE ET DES CARACTERISTIQUES
*----------------------------------------------------

MOD1=MODL SURF MECANIQUE ELASTIQUE DKT;
MAT1=MATR MOD1 YOUN 10.5E6 NU 0.3125 RHO 1. EPAI 0.094 ;

*----------------------------------------------------
* CALCUL RIGIDITE ET MASSE ;
*----------------------------------------------------
*
RIG1=RIGI MOD1 MAT1;
*
*----------------------------------------------------
* CONDITIONS AUX LIMITES
*----------------------------------------------------
ENC1=BLOQ LIG4 UZ ;ENC2=BLOQ LIG4 RX ;ENC3=BLOQ LIG4 RY ;
ENC4=BLOQ LIG2 UX ;ENC5=BLOQ LIG2 RY ;ENC6=BLOQ LIG2 RZ ;
ENC7=BLOQ LIG3 UY ;ENC8=BLOQ LIG3 RX ;ENC9=BLOQ LIG3 RZ ;
ENC10=ENC1 ET ENC2 ET ENC3 ET ENC4 ET ENC5 ET ENC6 ET ENC7 ET ENC8
ET ENC9 ;
*----------------------------------------------------
* FORCE
*----------------------------------------------------
F1=0 0 -100 ;
EFOR=FORC F1 P3 ;
RIG2=RIG1 ET ENC10;
*----------------------------------------------------
* RESOLUTION
*----------------------------------------------------
DE1=RESOU RIG2 EFOR;
D3Z = EXTR DE1 UZ P3;

*----------------------------------------------------
* RESULTATS (isovaleurs de d{placement en Z)
*----------------------------------------------------
SAUT PAGE ;

SURF1=DEFO SURF DE1;
SI(NEG GRAPH 'N');
    TRAC OEIL1 DZ SURF1;
FINSI;
*
MESS ' DEPLACEMENT EN Z THEORIQUE :   -0.452 ';
MESS ' DEPLACEMENT EN Z CALCULE   :   ' D3Z ;
TEMPS ;
*            CODE FONCTIONNEMENT
DZREF=-0.452;
RESI=ABS((D3Z-DZREF)/DZREF);
SI(RESI <EG 5E-2);
     ERRE  0;
SINO;
     ERRE  5;
FINSI;
FIN;

Test elas3 Comments

1. Creation of a new field

   DZ = EXCO UZ DE1;
   The operator EXCO creates, from the field DE1 a new field of the same type by extracting one or more components. Here, the new field DZ is made up of the UZ component of DE1.

2. Deformed object

   SURF1 = DEFO SURF DE1;
   The operator DEFO(RME) constructs an object of type DEFORME from an initial geometry (SURF) and a displacement field (DE1).

3. Isovalues

   OPTI ISOV LIGNE;
   TRAC OEIL1 DZ SURF1 ;
   The directive OPTI followed by ISOV LIGNE specifies that the operator TRAC will draw the isovalues with lines. The operator TRAC represents the field DZ on the deformed object SURF1 using lines of isovalues.