Test name
elas2
Calculation type
MECHANICS ELASTICITY 3D
Finite element type
DKT
Topic
A cylindrical solid embedded, subjected to a diametrical load .
The cylindrical structure is pinched at one end while the other one is embedded.
For symmetry reasons, just 1/4 of this structure is modelled. The boundary conditions should reproduce the symmetry.
A diametrical load is applied.
Goal
Find the displacement on X at the point P1 (7,0,0) and the displacement on Z at
point P3 (0,70,0) where the diametrical force is applied.
Reference CASTEM
Test NAFEMS : ME6 : Modélisation des structures élastiques dans CASTEM 2000.
Version
97' customer version
Model description
Test elas2 Results
RESULTS
CASTEM FIGURES
* Test Elas2.dgibi: Jeux de données *
* --------------------------------- *
*
*******************************************************
OPTION ECHO 0;
GRAPH='N';
SAUT PAGE ;
*******************************************************
* TEST ELAS2
*
* Un cylindre est pincé à une de ses extrémités,
* l'autre extrémité étant encastrée.
*
* Pour des raisons de symétrie seul 1/4 de la structure
* a est modélisé.
*
* Les conditions aux limites sont imposées pour
* respecter les symétries.
* Une force ponctuelle est appliquée diametralement.
*
* Le déplacement en X d'un point de la base est comparé
* au déplacement théorique (déplacement nul puisque
* encastré).
* Le déplacement en Z du point d'application de force
* est comparé à la valeur théorique (-1.140)
*
*******************************************************
*
OPTION DIME 3 ELEM TRI3 ;
OPTION ECHO 1 ;
TITRE 'CYLINDRE PINCE A BORDS ENCASTRES' ;
TEMPS ;
*-----------------------------------------------------
* DEFINITION DE LA GEOMETRIE
*-----------------------------------------------------
P1=7 0 0 ;P2=0 0 7 ;C1=0 0 0 ;VECT=0 70 0 ;
LIG1=C 6 P1 C1 P2 ;SURF=LIG1 TRAN 30 VECT ;
LIG1 LIG2 LIG3 LIG4=COTE SURF ;P3=LIG2 POIN FINA ;
*
OEIL1 = 100 100 100;
SI(NEG GRAPH 'N');
TRAC OEIL1 SURF;
FINSI;
*-----------------------------------------------------
* DEFINITION DU MODELE
*-----------------------------------------------------
MOD1=MODL SURF MECANIQUE ELASTIQUE DKT ;
MAT1=MATR MOD1 YOUN 3.E7 NU 0.3 ;
EPEE=CARB MOD1 EPAI 0.1 ;
MAT1=MAT1 ET EPEE;
*-----------------------------------------------------
*** CALCUL RIGIDITE ET MASSE ;
*-----------------------------------------------------
*
RIG1=RIGI MOD1 MAT1;
*
*-----------------------------------------------------
* CONDITIONS AUX LIMITES
*-----------------------------------------------------
ENC1=BLOQ LIG4 UZ ;ENC2=BLOQ LIG4 RX ;ENC3=BLOQ LIG4 RY ;
ENC4=BLOQ LIG2 UX ;ENC5=BLOQ LIG2 RY ;ENC6=BLOQ LIG2 RZ ;
ENC7=BLOQ LIG3 UY ;ENC8=BLOQ LIG3 RX ;ENC9=BLOQ LIG3 RZ ;
ENC10=BLOQ LIG1 DEPL ROTA ;
ENC11=ENC1 ET ENC2 ET ENC3 ET ENC4 ET ENC5 ET ENC6 ET
ENC7 ET ENC8 ET ENC9 ET ENC10 ;
*------------------------------------------------------
* FORCES
*------------------------------------------------------
F1=0 0 -2500 ;
EFOR=FORC F1 P3 ;
RIG2=RIG1 ET ENC11;
*------------------------------------------------------
* RESOLUTION ET RESULTATS
*------------------------------------------------------
DE1=RESOU RIG2 EFOR;
D1X = EXTR DE1 UX P1 ;
D3Z = EXTR DE1 UZ P3 ;
*------------------------------------------------------
* SORTIE DES RESULTATS
*------------------------------------------------------
SAUT PAGE ;
MESS ' DEPLACEMENT EN X DE LA BASE VALEUR THEORIQUE : 0.00' ;
MESS ' DEPLACEMENT EN X DE LA BASE VALEUR CALCULEE : ' D1X ;
SAUT 2 LIGNE ;
MESS ' DEPLACEMENT EN Z THEORIQUE : -1.140' ;
MESS ' DEPLACEMENT EN Z CALCULE : ' D3Z ;
TEMPS ;
* CODE FONCTIONNEMENT
DZREF=-1.14;
RESI=ABS((D3Z-DZREF)/DZREF);
SI(RESI <EG 1E-2);
ERRE 0;
SINO;
ERRE 5;
FINSI;
FIN;
Test elas2 Comments
DE1 = RESOU RIG2 EFOR;
The operator RESO(UDRE) constructs the solution of the linear system (Ku=F) with K equal to RIG2, EFOR equal to F and DE1 equal to u.
D1X = EXTR DE1 UX P1 ;
D3Z = EXTR DE1 UZ P3 ;
The operator EXTR(AIRE) allows to extract a value of one component of an object. Here D1X contains the value of the UX displacement at point P1 and D3Z contains the value of the UZ displacement at point P3.