Télécharger @PRCA3.procedur

Retour à la liste

Numérotation des lignes :

  1. * @PRCA3 PROCEDUR MB234859 18/11/21 21:15:02 10007
  2. ***********************************************************************
  3. *
  4. * CETTE PROCEDURE A ETE MISE GRACIEUSEMENT A DISPOSITION DES
  5. * UTILISATEURS PAR LE LTDS - Ecole Centrale Lyon (S. Fouvry et S.Garcin)
  6. *
  7. ***********************************************************************
  8. * PROCEDURE DE CALCUL @PRCA3
  9. *
  10. * Calcul du profil d usure : DeltaH = alpha * beta * phi
  11. *
  12. * Entrees :
  13. * T1 : Table de PASAPAS
  14. * ID_BU : Entier donnant le numero de la BOITE D'USURE a considerer
  15. *
  16. * Sortie :
  17. * T1 : Table de PASAPAS avec les booleens mis a jour
  18. *
  19. * Appelee par @EVN_MNG
  20. *
  21. ***********************************************************************
  22. DEBP @PRCA3 T1*'TABLE' ID_BU*'ENTIER';
  23.  
  24. * Booleen pour le trace
  25. OPEvUsCu = FAUX ;
  26.  
  27. BOITE_US = T1.'BOITES_USURES'. ID_BU ;
  28. ALPHA = BOITE_US.'COEFFICIENT_USURE' ;
  29. BETA = BOITE_US.'FACTEUR_ACCELERATION' ;
  30. SUR_APPL = BOITE_US.'SURFACE_APPLICATION' ;
  31. NCNECC = BOITE_US.'NCNECC' ;
  32.  
  33. * Usure obtenue par le produit : Energie Dissipee * Alpha * Beta
  34. * Avec Alpha le coefficient d'usure et Beta le facteur d'acceleration
  35. AmplFctr = MANU 'CHPO' SUR_APPL 1 'SCAL' (ALPHA*BETA) ;
  36.  
  37. * Cas Usure cyclique
  38. SI (BOITE_US.'USURE_CYCLIQUE') ;
  39. EnerDiss = BOITE_US.'ENERGIE_DISSIPEE_SUR_CYCLE'. NCNECC ;
  40. SI (NCNECC EGA 1) ;
  41. CumuUsU2 = MANU 'CHPO' SUR_APPL 1 'UU2' 0.0 ;
  42. SINON ;
  43. CumuUsU2 = BOITE_US.'USURE_CUMULEE'. (NCNECC - 1) ;
  44. FINSI ;
  45. * Cas Usure incrementale
  46. SINON ;
  47. Inc = BOITE_US.'INDICE-STOCKAGE' ;
  48. EnerDiss = BOITE_US.'ENERGIE_DISSIPEE_SUR_INCREMENT'. Inc ;
  49. FirstInc = (BOITE_US.'EntreeNC') ET (NON (BOITE_US.'TermineC')) ;
  50. SI FirstInc ;
  51. CumuUsU2 = MANU 'CHPO' SUR_APPL 1 'UU2' 0.0 ;
  52. SINON ;
  53. CumuUsU2 = BOITE_US.'USURE_CUMULEE'. (Inc - 1) ;
  54. FINSI ;
  55. FINSI ;
  56. NouvUsU2 = AmplFctr * EnerDiss ('MOTS' 'SCAL') ('MOTS' 'ED')
  57. ('MOTS' 'UU2') ;
  58.  
  59. CumuUsU2 = CumuUsU2 + NouvUsU2 ;
  60.  
  61. EvNouvUs = EVOL 'JAUN' 'CHPO' NouvUsU2 SUR_APPL ;
  62. EvNouvUs = EXTR EvNouvUs 'COUR' 1 ;
  63. EvNouvUs = CHAN EvNouvUs 'LEGE' 'Usure Nouvelle' ;
  64.  
  65. EvCumuUs = EVOL 'BLEU' 'CHPO' CumuUsU2 SUR_APPL ;
  66. EvCumuUs = EXTR EvCumuUs 'COUR' 1 ;
  67. EvCumuUs = CHAN EvCumuUs 'LEGE' 'Usure Cumulee' ;
  68.  
  69. SI OPEvUsCu ;
  70. DESS (EvNouvUs ET EvCumuUs) 'LEGE' ;
  71. FINSI ;
  72.  
  73. BOITE_US.'USURE_APPLIQUEE' . NCNECC = NouvUsU2 ;
  74. BOITE_US.'USURE_CUMULEE' . NCNECC = CumuUsU2 ;
  75. BOITE_US.'EVO_USURE_APPLIQUEE' . NCNECC = EvNouvUs ;
  76. BOITE_US.'EVO_USURE_CUMULEE' . NCNECC = EvCumuUs ;
  77.  
  78. FINP T1 ;
  79.  
  80.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales