Télécharger @PRCA2.procedur

Retour à la liste

Numérotation des lignes :

  1. * @PRCA2 PROCEDUR MB234859 17/09/26 21:15:04 9567
  2. ***********************************************************************
  3. *
  4. * CETTE PROCEDURE A ETE MISE GRACIEUSEMENT A DISPOSITION DES
  5. * UTILISATEURS PAR LE LTDS - Ecole Centrale Lyon (S. Fouvry et S.Garcin)
  6. *
  7. ***********************************************************************
  8. * PROCEDURE DE CALCUL @PRCA2
  9. *
  10. * Calcul du cycle de fretting en recuperant au point 'POINT_REF_DELTA'
  11. * le deplacement impose (LstDelta) et la force (LstFTang)
  12. * Ces donnees sont cumulees sur chaque cycle et mise a zero en debut
  13. * de chaque nouveau cycle.
  14. *
  15. * Entrees :
  16. * T1 : Table de PASAPAS
  17. * ID_BU : Entier donnant le numero de la BOITE D'USURE a considerer
  18. *
  19. * Sortie :
  20. * T1 : Table de PASAPAS avec les booleens mis a jour
  21. *
  22. * Appelee par @EVN_MNG
  23. *
  24. ***********************************************************************
  25. DEBP @PRCA2 T1*'TABLE' ID_BU*'ENTIER';
  26.  
  27. * Booleen pour trace ou non le cycle de freeting
  28. OPCycFre = FAUX ;
  29.  
  30. BOITE_US = T1.'BOITES_USURES'. ID_BU ;
  31. EntreeNC = BOITE_US.'EntreeNC' ;
  32. TermineC = BOITE_US.'TermineC' ;
  33. NCNECC = BOITE_US.'NCNECC' ;
  34.  
  35. * Indicateurs des Phases de Creation et Sauvegarde/Reset
  36. OuiCrea = ET EntreeNC (NON TermineC) ;
  37. OuiSauv = TermineC ;
  38.  
  39. * Ouicrea : VRAI (creation) / FAUX (recuperation)
  40. SI OuiCrea ;
  41. LstDelta = PROG ;
  42. LstFTang = PROG ;
  43. SINON ;
  44. LstDelta = BOITE_US.'LISTE_DELTAS' ;
  45. LstFTang = BOITE_US.'LISTE_FORCES_TANGENTIELLES' ;
  46. FINSI ;
  47.  
  48. * Indice de table courant
  49. TT = T1 . 'TEMPS' ;
  50. Inc = (DIME TT) - 1 ;
  51. TpsEst = T1.'ESTIMATION'.'TEMPS' ;
  52. SI (TpsEst <EG 1.e-10) ; Inc = 0 ; FINSI ;
  53. *
  54. EvCShear = BOITE_US.'EVO_CISAILLEMENT_CONTACT'. Inc ;
  55. PGetDlta = BOITE_US.'POINT_REF_DELTA';
  56. TU = T1.'ESTIMATION'.'DEPLACEMENTS' ;
  57.  
  58. * Evaluation des composantes souhaitees
  59. FTang_ii = INTG EvCShear ;
  60. Delta_ii = EXTR TU 'UX' PGetDlta ;
  61. *
  62. * Cumul des valeurs
  63. LstDelta = LstDelta ET Delta_ii ;
  64. LstFTang = LstFTang ET FTang_ii ;
  65.  
  66. * Doit-on sauvegarder les resutlats?
  67. SI OuiSauv ;
  68. * - Sauvegarde
  69. DeltaMin = MINI LstDelta ;
  70. DeltaMax = MAXI LstDelta ;
  71. DeltaMoy = (DeltaMin + DeltaMax) / 2. ;
  72. LstDelta = LstDelta - DeltaMoy ;
  73.  
  74. * Constitution du cycle de fretting par creation d'une evolution
  75. CyclFret = EVOL 'ROUG' 'MANU' 'Deplacement (mm)' LstDelta
  76. 'Force Tangentielle (N/mm)' LstFTang ;
  77. EnteteCF = CHAI 'Cycle de fretting n: ' NCNECC FORMAT '(I2)' ;
  78. CyclFret = CHAN CyclFret 'LEGE' EnteteCF ;
  79. BOITE_US.'CYCLE_DE_FRETTING'. NCNECC = CyclFret ;
  80.  
  81. * - Reinitialisation
  82. LstDelta = PROG ;
  83. LstFTang = PROG ;
  84. LstDelta = LstDelta ET Delta_ii ;
  85. LstFTang = LstFTang ET FTang_ii ;
  86.  
  87. * - Trace eventuel
  88. SI OPCycFre ;
  89. TabDess = TABL ;
  90. TabDess. 1 = 'TIRC MARQ CROI' ;
  91. DESS CyclFret TabDess 'GRIL' 'LEGE' ;
  92. FINSI ;
  93.  
  94. FINSI ;
  95.  
  96. * MAJ des donnees contenues dans les listes courantes.
  97. BOITE_US.'LISTE_DELTAS' = LstDelta ;
  98. BOITE_US.'LISTE_FORCES_TANGENTIELLES' = LstFTang ;
  99.  
  100. FINP T1 ;
  101.  
  102.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales