Télécharger toposauv.procedur

Retour à la liste

* TOPOSAUV  PROCEDUR  FD218221  25/12/18    21:15:14     12429          
 
************************************************************************
** Procedure called by TOPOPTIM for saving some data for restart and
** user-requested outputs.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** 4.0 2025/11/17 Made compatible with TOPOPTIM V4.0
** 3.0 2021/04/15 Made compatible with TOPOPTIM V3.0
** 2.0 2018/02/09 Always save the last cycle data in case of early
**                stop of the optimization process for safe restart
**                and delete the previous cycle data if it did not need
**                to be saved
** 1.0 2017/04/18 Initial version
************************************************************************
 
* TODO sauver X et TOPO dans les tables utilisateur et dans RTABLE
 
DEBP TOPOSAUV tab*'TABLE' ;
 
* Input data
* **********
 
Wtab = tab.'WTABLE' ;
Ltab = Wtab.'LOGIQUE' ;
 
* Initialize restart table if it does not exists
SI (NON (EXIS tab 'RTABLE')) ;
    tab.'RTABLE' = TABL ;
FINS ;
Rtab = tab.'RTABLE' ;
 
* Base model
modB = Wtab.'MODELE_B' ;
 
* Current cycle number
cyc = Wtab.'CYCLE' ;
 
* Number of cycles since the last call to TOPOPTIM
nbritr = Wtab.'ITERATION' ;
 
* Fixed zone
LF = Ltab.'ZONE_FIGEE' ;
SI LF ;
    uniF = Wtab.'UNIT_F' ;
FINS ;
 
* Update output evolutions
* ************************
 
* Table of evolutions
lstevo = tab.'EVOLUTIONS' ;
 
REPE itr (DIME tab.'EVOLUTIONS_SAUVEES') ;
 
*   Value name
    varnam = EXTR tab.'EVOLUTIONS_SAUVEES' &itr ;
*   Get its value
    var = FAUX ;
    SI (EXIS Wtab varnam) ;
        var = Wtab.varnam ;
    SINO ;
        SI (EXIS tab varnam) ;
            var = tab.varnam ;
        FINS ;
    FINS ;
*   Update its value if it is 'FRACTION_VOLUME' or 'TEMPS_CYCLE'
    SI (EGA varnam 'FRACTION_VOLUME') ;
        modD = Wtab.'MODELE_D' ;
        matD = Wtab.'CARACTERISTIQUES_D' ;
        SI (TOPOMODI tab (CHAI 'FRACTION_VOLUME') Wtab.'Y_D_PRECED' modD matD) ;
            Wtab.'FRACTION_VOLUME' = (INTG Wtab.'Y_D_PRECED' modD matD) /
                                     Wtab.'VOLUME_TOTAL_D' ;
        FINS ;
        var = Wtab.'FRACTION_VOLUME' ;
    FINS ;
    SI (EGA varnam 'TEMPS_CYCLE') ;
        var = (TEMP 'HORL') - Wtab.'HORLOGE' ;
        Wtab.'TEMPS_CYCLE' = var ;
    FINS ;
 
*   If value exists
    SI (NEG (TYPE var) 'LOGIQUE') ;
 
*       Initialize the corresponding evolutions if they do not already exist
        SI ((nbritr EGA 1) ET (NON (EXIS lstevo varnam))) ;
            lstevo.varnam = EVOL 'MANU' (PROG) (PROG) ;
        FINS ;
 
*       Update evolution
        evo = lstevo.varnam ;
        tmp1 = (EXTR evo 'ABSC') ET cyc ;
        tmp2 = (EXTR evo 'ORDO') ET var ;
        tmp3 = MOT 'BLAN' ;
        SI (EXIS Wtab.'EVOLUTIONS_COULEUR'.varnam) ;
            tmp3 = Wtab.'EVOLUTIONS_COULEUR'.varnam ;
        FINS ;
        lstevo.varnam = EVOL 'MANU' 'CYCLE' tmp1 varnam tmp2 'COUL' tmp3 ;
 
    SINO ;
        MESS (CHAI 'Variable' ' ' varnam
                   ' inconnue. Son evolution n''a pas ete sauvegardee.') ;
    FINS ;
 
FIN itr ;
 
* Save restart data
* *****************
 
* Save in a "restart table", any data that would be needed to
* restart the optimization exactly where it was previously stopped.
* Using this table, the final result should be exactly the same as
* if the user didn't change any input data between the two calls.
* Output fields are defined on B, not on D, as F may evolve between
* tow successive calls to TOPOPTIM.
* Remark: the user is not supposed to change anything in this table.
 
* Reset restart table
tab.'RTABLE' = TABL ;
Rtab = tab.'RTABLE' ;
 
* Restart save
SI tab.'SAUVEGARDE_DE_REPRISE' ;
 
*   Save next cycle design variables
    Rtab.'X_B' = Wtab.'X_D' ;
    SI LF ;
*       Combine the X field on D with the unitary field on F
*       This creates a 2-zone field merged into a single zone
*       field, preserving the original element order using REDU
        Rtab.'X_B' = REDU (Wtab.'X_D' ET uniF) modB ;
    FINS ;
 
*   Save next cycle intermediate densities
    Rtab.'S_B' = Wtab.'S_D' ;
    SI LF ;
*       Combine the X field on D with the unitary field on F
*       This creates a 2-zone field merged into a single zone
*       field, preserving the original element order using REDU
        Rtab.'S_B' = REDU (Wtab.'S_D' ET uniF) modB ;
    FINS ;
 
*   Save next cycle physical densities
    Rtab.'Y_B' = Wtab.'Y_D' ;
    SI LF ;
*       Combine the Y field on D with the unitary field on F
*       This creates a 2-zone field merged into a single zone
*       field, preserving the original element order using REDU
        Rtab.'Y_B' = REDU (Wtab.'Y_D' ET uniF) modB ;
    FINS ;
 
*   As any call to MFIL to get the hat filter matrix can be time
*   consuming, we always save any existing hat filter matrix to allow
*   reusing it without recalculating it.
    SI (EXIS Wtab 'FILTRE_CHAPEAU_NORMALISE') ;
        Rtab.'FILTRE_CHAPEAU_NORMALISE' = Wtab.'FILTRE_CHAPEAU_NORMALISE' ;
*       If FILTRE_CHAPEAU_NORMALISE exists, then FILTRE_CHAPEAU_MODIFIE might also
*       exist and should be saved too.
        SI (EXIS Wtab 'FILTRE_CHAPEAU_MODIFIE') ;
            Rtab.'FILTRE_CHAPEAU_MODIFIE' = Wtab.'FILTRE_CHAPEAU_MODIFIE' ;
        FINS ;
*       Save their corresponding identification extra data that will
*       later be used to know if the hat filter matrices need to be
*       updated (i.e., if one of those corresponding parameters has
*       changed)
        Rtab.'FILTRE_CHAPEAU_ID' = Wtab.'FILTRE_CHAPEAU_ID' ;
    FINS ;
 
*   Copy loading and mechanism for modification detection
    res = Wtab.'RESOLUTION_B' ;
    ldg = res.'CHARGEMENT' ;
    SI (EGA (TYPE ldg) 'TABLE') ;
        Rtab.'CHARGEMENT' = COPI ldg ;
    SINO ;
        Rtab.'CHARGEMENT' = ldg ;
    FINS ;
    SI Ltab.'MECANISME' ;
        ldg1 = tab.'MECANISME' ;
        SI (EGA (TYPE ldg1) 'TABLE') ;
            Rtab.'MECANISME' = COPI ldg1 ;
        SINO ;
            Rtab.'MECANISME' = ldg1 ;
        FINS ;
    FINS ;
 
*   MMA data
    SI (EXIS Wtab 'MMA') ;
        Rtab.'MMA' = Wtab.'MMA' ;
    FINS ;
 
*   Projection data
    SI Ltab.'PROJECTION_VOLUME_CONSTANT' ;
        Rtab.'PROJECTION_SEUIL' = Wtab.'PROJECTION_SEUIL' ;
    FINS ;
 
SINO ;
 
*   Delete RTABLE from tab ;
    OTER tab 'RTABLE' ;
 
FINS ;
 
* Save user requested data
* ************************
 
* If this cycle has to be saved or if it is the final cycle
SI ((EXIS tab.'CYCLES_SAUVES' cyc) OU Ltab.'STOP') ;
 
*   Save the design variables (X)
    SI tab.'MES_SAUVEGARDES'.'X' ;
*       Copy X from Rtab except if it is the first cycle as X in Rtab may
*       differe from the actual initial design variables
        SI ((EXIS Rtab 'X_B') ET (nbritr > 1)) ;
            tab.'X'.cyc = Rtab.'X_B' ;
        SINO ;
            tab.'X'.cyc = Wtab.'X_D_PRECED' ;
            SI LF ;
*               Combine the X field on D with the unitary field on F
*               This creates a 2-zone field merged into a single zone
*               field, preserving the original element order using REDU
                tab.'X'.cyc = REDU (Wtab.'X_D_PRECED' ET uniF) modB ;
            FINS ;
        FINS ;
    FINS ;
 
*   Save the intermediate densities (S)
    SI tab.'MES_SAUVEGARDES'.'X_FILTRE' ;
*       Copy S from Rtab except if it is the first cycle as X in Rtab may
*       differe from the actual initial design variables
        SI ((EXIS Rtab 'S_B') ET (nbritr > 1)) ;
            tab.'X_FILTRE'.cyc = Rtab.'S_B' ;
        SINO ;
            tab.'X_FILTRE'.cyc = Wtab.'S_D_PRECED' ;
            SI LF ;
*               Combine the X field on D with the unitary field on F
*               This creates a 2-zone field merged into a single zone
*               field, preserving the original element order using REDU
                tab.'X_FILTRE'.cyc = REDU (Wtab.'S_D_PRECED' ET uniF) modB ;
            FINS ;
        FINS ;
    FINS ;
 
*   Save the physical densities (Y)
    SI tab.'MES_SAUVEGARDES'.'TOPOLOGIE' ;
*       Copy Y from Rtab except if it is the first cycle as Y in Rtab may
*       differe from the actual initial design variables
        SI ((EXIS Rtab 'Y_B') ET (nbritr > 1)) ;
            tab.'TOPOLOGIE'.cyc = Rtab.'Y_B' ;
        SINO ;
            tab.'TOPOLOGIE'.cyc = Wtab.'Y_D_PRECED' ;
            SI LF ;
*               Combine the Y field on D with the unitary field on F
*               This creates a 2-zone field merged into a single zone
*               field, preserving the original element order using REDU
                tab.'TOPOLOGIE'.cyc = REDU (Wtab.'Y_D_PRECED' ET uniF) modB ;
            FINS ;
        FINS ;
    FINS ;
 
*   Save the mesh
    SI tab.'MES_SAUVEGARDES'.'MAILLAGE' ;
        tab.'MAILLAGE'.cyc = Wtab.'MAILLAGE_A' ;
    FINS ;
 
*   Save the resolution data
    SI tab.'MES_SAUVEGARDES'.'RESOLUTION' ;
        tab.'RESOLUTION'.cyc = Wtab.'RESOLUTION_A' ;
    FINS ;
 
FINS ;
 
* Save next cycle design variables, intermediate densities and physical densities
* *******************************************************************************
 
* Save X and Y of the next cycle if the current cycle is the final one,
* as the user may want to access them.
 
SI (tab.'MES_SAUVEGARDES'.'X' ET Ltab.'STOP') ;
    SI tab.'SAUVEGARDE_DE_REPRISE' ;
        tab.'X'.(cyc + 1) = Rtab.'X_B' ;
    SINO ;
        tab.'X'.(cyc + 1) = Wtab.'X_D' ;
        SI LF ;
*           Combine the X field on D with the unitary field on F
*           This creates a 2-zone field merged into a single zone
*           field, preserving the original element order using REDU
            tab.'X'.(cyc + 1) = REDU (Wtab.'X_D' ET uniF) modB ;
        FINS ;
    FINS ;
FINS ;
 
SI (tab.'MES_SAUVEGARDES'.'X_FILTRE' ET Ltab.'STOP') ;
    SI tab.'SAUVEGARDE_DE_REPRISE' ;
        tab.'X_FILTRE'.(cyc + 1) = Rtab.'S_B' ;
    SINO ;
        tab.'X_FILTRE'.(cyc + 1) = Wtab.'S_D' ;
        SI LF ;
*           Combine the X field on D with the unitary field on F
*           This creates a 2-zone field merged into a single zone
*           field, preserving the original element order using REDU
            tab.'X_FILTRE'.(cyc + 1) = REDU (Wtab.'S_D' ET uniF) modB ;
        FINS ;
    FINS ;
FINS ;
 
SI (tab.'MES_SAUVEGARDES'.'TOPOLOGIE' ET Ltab.'STOP') ;
    SI tab.'SAUVEGARDE_DE_REPRISE' ;
        tab.'TOPOLOGIE'.(cyc + 1) = Rtab.'Y_B' ;
    SINO ;
        tab.'TOPOLOGIE'.(cyc + 1) = Wtab.'Y_D' ;
        SI LF ;
*           Combine the Y field on D with the unitary field on F
*           This creates a 2-zone field merged into a single zone
*           field, preserving the original element order using REDU
            tab.'TOPOLOGIE'.(cyc + 1) = REDU (Wtab.'Y_D' ET uniF) modB ;
        FINS ;
    FINS ;
FINS ;
 
* And delete them from the previous cycle
*   - if it is not 0 as this cycle can't exists and
*   - if it is not in CYCLES_SAUVES
oldcyc = cyc - 1 ;
SI ((NEG oldcyc 0) ET (NON (EXIS tab.'CYCLES_SAUVES' oldcyc))) ;
    SI (EXIS (tab.'X') oldcyc) ;
        OTER (tab.'X') oldcyc ;
    FINS ;
    SI (EXIS (tab.'X_FILTRE') oldcyc) ;
        OTER (tab.'X_FILTRE') oldcyc ;
    FINS ;
    SI (EXIS (tab.'TOPOLOGIE') oldcyc) ;
        OTER (tab.'TOPOLOGIE') oldcyc ;
    FINS ;
    SI (EXIS (tab.'MAILLAGE') oldcyc) ;
        OTER (tab.'MAILLAGE') oldcyc ;
    FINS ;
    SI (EXIS (tab.'RESOLUTION') oldcyc) ;
        OTER (tab.'RESOLUTION') oldcyc ;
    FINS ;
FINS ;
 
* Save data in a file
* *******************
 
SI tab.'SAUV' ;
*   Save the current cycle data if requested
    SI ((EXIS tab.'CYCLES_SAUVES' cyc) OU Ltab.'STOP') ;
*       Save design variables
        SI tab.'MES_SAUVEGARDES'.'X' ;
            SAUV tab.'X'.cyc ;
            OUBL tab.'X' cyc ;
        FINS ;
*       Save intermediate densities
        SI tab.'MES_SAUVEGARDES'.'X_FILTRE' ;
            SAUV tab.'X_FILTRE'.cyc ;
            OUBL tab.'X_FILTRE' cyc ;
        FINS ;
*       Save physical densities
        SI tab.'MES_SAUVEGARDES'.'TOPOLOGIE' ;
            SAUV tab.'TOPOLOGIE'.cyc ;
            OUBL tab.'TOPOLOGIE' cyc ;
        FINS ;
*       Save active mesh
        SI tab.'MES_SAUVEGARDES'.'MAILLAGE' ;
            SAUV tab.'MAILLAGE'.cyc ;
            OUBL tab.'MAILLAGE' cyc ;
        FINS ;
*       Save resolution
        SI tab.'MES_SAUVEGARDES'.'RESOLUTION' ;
            SAUV tab.'RESOLUTION'.cyc ;
            OUBL tab.'RESOLUTION' cyc ;
        FINS ;
    FINS ;
FINS ;
 
FINP ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales