Télécharger la plaquette Cast3M


fr en

Télécharger topodvsa.procedur

Retour à la liste

Numérotation des lignes : 

  1. * TOPODVSA  PROCEDUR  FD218221  25/12/18    21:15:05     12429          
  2.  
  3. ************************************************************************
  4. ** Procedure called by TOPOCONT to evaluate "DVσA", with:
  5. **   - D : stiffness matrix
  6. **   - V : von Mises matrix
  7. **   - σ : input stress tensor
  8. **   - A : optional input scalar field
  9. **
  10. ** Author:
  11. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  12. **
  13. ** Version:
  14. ** 1.0 2025/11/21 Initial version
  15. ************************************************************************
  16.  
  17. DEBP TOPODVSA sig*'MCHAML' mod*'MMODEL' mat*'MCHAML' fld/'MCHAML' ;
  18.  
  19. * Value of the current mode
  20. val = VALE 'MODE' ;
  21.  
  22. * Plane stress or plane strain
  23. SI ((EGA val 'PLANCONT') OU (EGA val 'PLANDEFO')) ;
  24.     sig123 = EXCO (MOTS 'SMXX' 'SMYY' 'SMZZ')
  25.                   (MOTS 'EPXX' 'EPYY' 'EPYY') sig ;
  26.     sig231 = EXCO (MOTS 'EPXX' 'EPYY' 'EPZZ') sig123
  27.                   (MOTS 'EPZZ' 'EPXX' 'EPYY') ;
  28.     sig312 = EXCO (MOTS 'EPXX' 'EPYY' 'EPZZ') sig123
  29.                   (MOTS 'EPYY' 'EPZZ' 'EPXX') ;
  30.     Vsig   = (sig123 - (0.5 * (sig231 + sig312)))
  31.              ET (3.0 * (EXCO 'SMXY' sig 'GAXY')) ;
  32.     Vsig   = CHAN 'TYPE' Vsig 'DEFORMATIONS' ;
  33.     DVsig  = ELAS Vsig mod mat ;
  34. FINS ;
  35.  
  36. * Axisymmetric mode
  37. SI (EGA val 'AXIS') ;
  38.     sig123 = EXCO (MOTS 'SMRR' 'SMZZ' 'SMTT')
  39.                   (MOTS 'EPRR' 'EPZZ' 'EPTT') sig ;
  40.     sig231 = EXCO (MOTS 'EPRR' 'EPZZ' 'EPTT') sig123
  41.                   (MOTS 'EPTT' 'EPRR' 'EPZZ') ;
  42.     sig312 = EXCO (MOTS 'EPRR' 'EPZZ' 'EPTT') sig123
  43.                   (MOTS 'EPZZ' 'EPTT' 'EPRR') ;
  44.     Vsig   = (sig123 - (0.5 * (sig231 + sig312)))
  45.              ET (3.0 * (EXCO 'SMRZ' sig 'GARZ')) ;
  46.     Vsig   = CHAN 'TYPE' Vsig 'DEFORMATIONS' ;
  47.     DVsig  = ELAS Vsig mod mat ;
  48. FINS ;
  49.  
  50. * 3D
  51. SI (EGA val 'TRID') ;
  52.     sig123 = EXCO (MOTS 'SMXX' 'SMYY' 'SMZZ')
  53.                   (MOTS 'EPXX' 'EPYY' 'EPYY') sig ;
  54.     sig231 = EXCO (MOTS 'EPXX' 'EPYY' 'EPZZ') sig123
  55.                   (MOTS 'EPZZ' 'EPXX' 'EPYY') ;
  56.     sig312 = EXCO (MOTS 'EPXX' 'EPYY' 'EPZZ') sig123
  57.                   (MOTS 'EPYY' 'EPZZ' 'EPXX') ;
  58.     Vsig   = (sig123 - (0.5 * (sig231 + sig312)))
  59.              ET (3.0 * (EXCO 'SMXY' sig 'GAXY'))
  60.              ET (3.0 * (EXCO 'SMXZ' sig 'GAXZ'))
  61.              ET (3.0 * (EXCO 'SMYZ' sig 'GAYZ')) ;
  62.     Vsig   = CHAN 'TYPE' Vsig 'DEFORMATIONS' ;
  63.     DVsig  = ELAS Vsig mod mat ;
  64. FINS ;
  65.  
  66. * Interpolated at centroids
  67. DVsig = CHAN 'GRAVITE' DVsig mod ;
  68.  
  69. * Multiplied by the optional scalar input field
  70. SI (EXIS fld) ;
  71.     DVsig  = CHAN 'TYPE' DVsig 'SCALAIRE' ;
  72.     lstcpn = EXTR DVsig 'COMP' ;
  73.     REPE itr (DIME lstcpn) ;
  74.         cpn = EXTR lstcpn &itr ;
  75.         tmp = (EXCO cpn DVsig 'SCAL') * fld ;
  76.         tmp = CHAN 'COMP' cpn tmp ;
  77.         SI (EGA &itr 1) ;
  78.             DVsigA = tmp ;
  79.         SINO ;
  80.             DVsigA = DVsigA ET tmp ;
  81.         FINS ;
  82.     FIN itr ;
  83.     DVsigA  = CHAN 'TYPE' DVsigA 'CONTRAINTES' ;
  84. SINO ;
  85.     DVsigA = DVsig ;
  86. FINS ;
  87.  
  88. FINP DVsigA ;
  89.  
  90.  
  91.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales