Télécharger la plaquette Cast3M


fr en

Télécharger pas_rayo.procedur

Retour à la liste

Numérotation des lignes : 

  1. * PAS_RAYO  PROCEDUR  MB234859  26/11/04    21:15:09     12691          
  2. *----------------------------------------------------------------------*
  3. * Procedure pour le calcul des termes dus au rayonnement
  4. * (facteurs de forme, matrices, seconds membres)
  5. *
  6. * PRECED   table de calcul envoyee a PASAPAS
  7. * TEMM     instant courant du calcul
  8. * IAPPEL   vaut - 1 si l'appel vient de DUPONT2
  9. *               - 2 si premier appel de TRANSNON
  10. *               - 3 si deuxieme appel de TRANSNON
  11. *----------------------------------------------------------------------*
  12. 'DEBP' PAS_RAYO PRECED*'TABLE' TEMM*'FLOTTANT' IAPPEL*'ENTIER' ;
  13. *
  14.   TAA  = 'TABLE' ;
  15. *
  16.   etab     = PRECED.'WTABLE' ;
  17.   rayo_val = etab.'RAYONNEMENT' ;  
  18.   NDIM3    = 'DIME' rayo_val ;
  19.   LM_PRIM  = 'EXTR' ETAB.'MOD_RAY' 'DEPL';
  20. *----------------------------------------------------------------------*
  21. * Mise a jour des facteurs de forme (si necessaire)
  22. *----------------------------------------------------------------------*
  23.   'SI' ('<' IAPPEL 3) ;
  24.     'SI' etab.'REA_GEOM' ;
  25.       'REPETER' bou_ray NDIM3 ;
  26.         'SI' ('EGA' rayo_val. &bou_ray .'MODELE' 'CAVITE') ;
  27.           mo_ray = rayo_val. &bou_ray .'MODELE' ;
  28.           ma_ray = 'REDU' ETAB.'MAT_RAY' mo_ray ;
  29.           etab.'FAC_FORM'. &bou_ray = 'FFOR' mo_ray ma_ray ;
  30.         'FINSI' ;
  31.       'FIN' bou_ray ;
  32.     'FINSI' ;
  33.   'FINSI' ;
  34. *----------------------------------------------------------------------*
  35. * Deuxieme partie du rayonnement calcul matrices et chpoint
  36. *----------------------------------------------------------------------*
  37.   'SI' ( ('EGA' IAPPEL 1) 'OU' ('EGA' IAPPEL 3) ) ;
  38.     CTE_SB = etab.'CTE_STEFAN_BOLTZMANN' ;
  39.  
  40.     TREF = ETAB.'TREF' ;
  41.     U0   = ('EXCO' ETAB.'THER_COURANT' LM_PRIM LM_PRIM) + TREF ;
  42. *
  43.     MAT_CHPO = 0. ;
  44.     bb       = 'VIDE' 'RIGIDITE' ;
  45. *
  46.     'REPETER' bou_ray NDIM3 ;
  47.  
  48.       RTYPE  = 'MOT' RAYO_VAL. &BOU_RAY .'TYPE' ;
  49.       MO_RAY = RAYO_VAL. &BOU_RAY .'MODELE';
  50.       MA_RAY = 'REDU' etab.'CHMAT' mo_ray ;
  51.       CHTEMP = U0 ;
  52. *
  53.       'SI'  ('NEG' RTYPE 'CAVITE') ;
  54. *
  55.         'SI' ('EGA' RTYPE 'INFINI') ;
  56.           'SI' ('EXIS' (etab.'CHARGEMENT') 'TERA') ;
  57.             CH_TER = 'TIRE' (etab.'CHARGEMENT') 'TERA' TEMM ;
  58.           'SINON' ;
  59.             CH_TER = 'EXCO' MA_RAY 'T_IN' 'T' ;
  60.             CH_TER = 'CHAN' 'CHPO' CH_TER MODRAY ;
  61.           'FINSI' ;
  62.           CH_TER = CH_TER '+' TREF ;
  63.           CH_TER = 'CHAN' 'ATTRIBUT' CH_TER 'NATURE' 'DIFFUS' ;
  64.           CHTEMP = CHTEMP 'ET' ('NOMC' CH_TER 'TERA') ;
  65.         'FINSI' ;
  66. *
  67.         MAT_RAD = HRAYO RTYPE MO_RAY MA_RAY CHTEMP CTE_SB ;
  68. *
  69.         'SI' ('EGA' RTYPE 'INFINI') ;
  70.           CHAL_TES = 'CONVECTION' MO_RAY MAT_RAD CH_TER ;
  71.           MAT_CHPO = MAT_CHPO '+' CHAL_TES ;
  72.         'FINSI' ;
  73.         RIG_RAD = 'CONDUCTIVITE' MO_RAY MAT_RAD ;
  74. *
  75. *------------- Cas du rayonnement dans une cavite--------------------
  76.       'SINON' ;
  77.         U_CAK2 = 'CHAN' 'CHAM' mo_ray CHTEMP 'GRAVITE' ;
  78.         MCH_FF = etab.'FAC_FORM'. &bou_ray ;
  79. *
  80. *       Methode avec calcul de la matrice de rayonnement
  81.         'SI' ('NON' ('EXIS' mo_ray 'MATE' 'TRAYO')) ;
  82. * methode avec le calcul de la temperature de rayonnement a l'infini
  83. * equivalente a l'ensemble de la cavite pour la face consideree
  84.           TCAV     = 'RAYE' mo_ray 1.E-7 MCH_FF MA_RAY U_CAK2 ;
  85.           HRAD     = HRCAV  mo_ray MA_RAY U_CAK2 TCAV ;
  86.           RIG_RAD  = 'COND' mo_ray HRAD ;
  87.  
  88.           TCAV_N1  = 'CHAN' 'CHPO' mo_ray TCAV ;
  89.           TCAV_N   = 'NOMC' TCAV_N1 'T' 'NATU' 'DIFFUS';
  90.           CHAL_TES = 'CONV' mo_ray HRAD TCAV_N ;
  91.           MAT_CHPO = MAT_CHPO '+' CHAL_TES ;
  92.         'SINON';
  93.           MAT_RAYE = 'RAYE' mo_ray MCH_FF MA_RAY ;
  94.           RIG_RAD  = 'RAYN' mo_ray MAT_RAYE U_CAK2 CTE_SB ;
  95.         'FINSI';
  96.  
  97.       'FINSI';
  98.  
  99.       bb = rig_rad 'ET' bb;
  100.     'FIN' bou_ray ;
  101. *   -------------------------------------------------------------------
  102.     'SI' ('NEG' MAT_CHPO 0.) ;
  103.       TAA.'ADDI_SECOND'  = MAT_CHPO ;
  104.     'FINSI' ;
  105.     TAA.'ADDI_MATRICE' = bb ;
  106.   'FINSI';
  107.   'RESPRO' TAA ;
  108. 'FINPROC' ;
  109.  
  110.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales