Procédures | Cast3M

* PAS_HELM  PROCEDUR  FD218221  24/02/07    21:15:22     11834          
DEBPROC PAS_HELM PRECED*'TABLE' WMAT1*'MCHAML' ;
*
* objet de la procedure :
* preparation des calculs en NON_LOCAL, modele HELM
* 
 WTAB = PRECED . 'WTABLE' ; 
 TAHELM = WTAB . 'HELMHOLTZ' ;   
 NHELM  =  TAHELM . 'N_VARI_NL' ; 
 MODHELM = WTAB.'NLOC_MODL'  ;
 MATHELM = 'REDU' MODHELM  WMAT1;
 DDVA = TAHELM . 'NLOC_COVA' ; 
 LOGVAR=FAUX;
 
 'REPE' BH NHELM ;
*    nom de la variable a moyenner  
     LEMO = TAHELM . &BH. 'NOM' ;
*    numero de la formulation associe a cette variable
     NUMFH1= &BH ;
*    capacite
     MOTHC0  = 'CHAI' 'CAP' NUMFH1;
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHC0));
*    diffusions
     MOTHD0  = 'CHAI' 'DH'  NUMFH1;
     MOTHD1  = 'CHAI' MOTHD0 '1';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHD1));
     MOTHD2  = 'CHAI' MOTHD0 '2';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHD2));
     MOTHD3  = 'CHAI' MOTHD0 '3';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHD3));
*    vecteurs unitaires des directions de diffusion
     MOTHV0  = 'CHAI' 'V'   NUMFH1;
*    1er vecteur associe a DH1
     MOTHV11  = 'CHAI' MOTHV0 '11';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV11));
     MOTHV12  = 'CHAI' MOTHV0 '12';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV12));
     MOTHV13  = 'CHAI' MOTHV0 '13';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV13));
*    2eme vecteur associe a DH2
     MOTHV21  = 'CHAI' MOTHV0 '21';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV21));
     MOTHV22  = 'CHAI' MOTHV0 '22';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV22));
     MOTHV23  = 'CHAI' MOTHV0 '23';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV23));
*    3eme vecteur associe a DH3
     MOTHV31  = 'CHAI' MOTHV0 '31';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV31));
     MOTHV32  = 'CHAI' MOTHV0 '32';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV32));
     MOTHV33  = 'CHAI' MOTHV0 '33';
     LOGVAR = (LOGVAR 'OU' ('EXIS' DDVA MOTHV33));
*    existance des operateurs de Helmholtz
     LOGHOPER='EXIS' TAHELM . &BH  'H_OPER';
     LOGHCAPA='EXIS' TAHELM . &BH  'INV_CAPA';
     'SI' (LOGVAR 'OU'
         (('NON' LOGVAR) 'ET' ('NON' LOGHOPER)) 'OU' 
         (('NON' LOGVAR) 'ET' ('NON' LOGHCAPA)));
*        recuperation du modele de Helmholtz (toujours thermique orthotrope)
         MOH1= TAHELM . &BH . 'H_MODELE' ;
*        il faut (re) construire le materiau pour cette formulation
*        CAPACITES
         test0 = 'XTX' ('EXCO' MATHELM  MOTHC0 'SCAL');
         'SI' ( test0 '&lt;EG' 0.) ;
*            par defaut on prend une capacite unitaire
             CAP0=MATE MOH1 MOTHC0 1. ;
             chai1=CHAI 'La capacite d Helmholtz est mise a 1 pour' LEMO;
             'MESS' Chai1;
         'SINON';
*            on prend la capacite donnee par l utilisateur
             CAP0 = 'EXCO' MATHELM  MOTHC0 'SCAL';
             CAP0a = 'CHAN' 'NOEUD' CAP0 MODHELM ;
             CAP0 = 'PROI' MOH1 CAP0a 'MINI';
             CAP1 = 'CHAN' 'CHPO' CAP0 MOH1;
         'FINSI';
         INV_CAP1 =  CAP1**-1;        
*        stockage l inverse de la capacite aux noeuds du maillage 
*        de Helmholtz pour la normalisation de l erreur de convergence
         TAHELM . &BH . 'INV_CAPA'  = INV_CAP1  ;
*         trac cap0  moh1   titr 'capa';
*         trac INV_CAP1 (extr moh1 'MAIL') titr 'inv capa';
*        DIFFUSIONS
         dif1='EXCO' MATHELM  MOTHD1 'SCAL';
         dif2='EXCO' MATHELM  MOTHD2 'SCAL';
         dif3='EXCO' MATHELM  MOTHD3 'SCAL';
         ver11='EXCO' MATHELM  MOTHV11 'SCAL';
         ver12='EXCO' MATHELM  MOTHV12 'SCAL';
         ver13='EXCO' MATHELM  MOTHV13 'SCAL';
         ver21='EXCO' MATHELM  MOTHV21 'SCAL';
         ver22='EXCO' MATHELM  MOTHV22 'SCAL';
         ver23='EXCO' MATHELM  MOTHV23 'SCAL';
         ver31='EXCO' MATHELM  MOTHV31 'SCAL';
         ver32='EXCO' MATHELM  MOTHV32 'SCAL';
         ver33='EXCO' MATHELM  MOTHV33 'SCAL';
*        calcul de la matrice de diffusion de Helmholtz sur le modele mecanique
*        list dif1;
*        trac ver11 modhelm titr 'ver11';
         kr11=((dif1*(ver11*ver11))+(dif2*(ver21*ver21)))+(dif3*(ver31*ver31));
*        trac kr11 modhelm titr 'kr11 avant ';
         kr22=((dif1*(ver12*ver12))+(dif2*(ver22*ver22)))+(dif3*(ver32*ver32));
         kr33=((dif1*(ver13*ver13))+(dif2*(ver23*ver23)))+(dif3*(ver33*ver33));
         kr21=((dif1*(ver12*ver11))+(dif2*(ver22*ver21)))+(dif3*(ver32*ver31));
         kr31=((dif1*(ver13*ver11))+(dif2*(ver23*ver21)))+(dif3*(ver33*ver31));
         kr32=((dif1*(ver13*ver12))+(dif2*(ver23*ver22)))+(dif3*(ver33*ver32));
*        projection des composantes sur le modele thermique orthotrope
         kr11a = 'CHAN' 'NOEUD' kr11 MODHELM ;
         kr11 = 'PROI' MOH1 kr11a 'MINI';
*         kr11  = 'CHAN' 'CHPO' kr11b MOH1;
         kr22a = 'CHAN' 'NOEUD' kr22 MODHELM ;
         kr22 = 'PROI' MOH1 kr22a 'MINI';
*         kr22  = 'CHAN' 'CHPO' kr22b MOH1;
         kr33a = 'CHAN' 'NOEUD' kr33 MODHELM ;
         kr33 = 'PROI' MOH1 kr33a 'MINI';
*         kr33  = 'CHAN' 'CHPO' kr33b MOH1;
         kr21a = 'CHAN' 'NOEUD' kr21 MODHELM ;
         kr21 = 'PROI' MOH1 kr21a 'MINI';
*         kr21  = 'CHAN' 'CHPO' kr21b MOH1;
         kr31a = 'CHAN' 'NOEUD' kr31 MODHELM ;
         kr31 = 'PROI' MOH1 kr31a 'MINI';
*         kr31  = 'CHAN' 'CHPO' kr31b MOH1;
         kr32a = 'CHAN' 'NOEUD' kr32 MODHELM ;
         kr32 = 'PROI' MOH1 kr32a 'MINI';
*         kr32  = 'CHAN' 'CHPO' kr32b MOH1;
*        (re) construction du MATERIAU DE HELMHOLTZ
*        il faut connaitre la dimension
         NDIM1='VALE' 'DIME';
         'SI' ( 'EGA' NDIM1 3 );
            MAH1='MATE' MOH1 'DIRECTION' (1. 0. 0.) (0. 1. 0.)  
            'K11' KR11 'K22' KR22 'K33' KR33 'K21' KR21 'K31' KR31 'K32' KR32       
            'RHO' 1. 'C' CAP0;
         'SINON';
            'SI' ( 'EGA' NDIM1 2);
                MAH1='MATE' MOH1 'DIRECTION' (1. 0. )  
                'K11' KR11 'K22' KR22 'K21' KR21  'RHO' 1. 'C' CAP0;
            'SINON';
                MESS1='HELMHOLTZ NE FONCTIONNE QU EN MASSIF 2D OU 3D';
                'MESS' MESS1;
            'FINS';
         'FINS';
*        list mah1;
*        trac mah1 moh1 titre 'kr11 apres';
*        MATRICE DE RIGIDITE 
         COH1 = 'COND' MOH1 MAH1 ;
*        MATRICE DE CAPACITE
         CAH1 = 'CAPA' MOH1 MAH1 ;
*        BLOCAGES EVENTUELS
         LOGBLOH1= FAUX ;
*        DEPLACEMENTS DU BLOCAGE 
         LOGDEPH1= FAUX ;
*        Noms des blocages et des deplacements imposees contenus dans materiau Helmholtz (cf idmatr)
         MOTBLOH1='CHAI' 'BLO' NUMFH1;
         MOTDEPH1='CHAI' 'DEP' NUMFH1;
         LOGBLOH1=(LOGBLOH1 'OU' ('EXIS' DDVA MOTBLOH1));
*        traitement si des blocages sont presents
         'SI' (LOGBLOH1) ;
            CHPOBLOH1 = 'EXCO' MATHELM  MOTBLOH1 'SCAL';
            CHPOBLOH2 = 'CHAN' 'NOEUD' CHPOBLOH1 MODHELM ;
            CHPOBLOH3 = 'PROI' MOH1 CHPOBLOH2 'MINI';
*           maillage pour le blocage
            ZONEBLOH1='REDU' CHPOBLOH3 CHPOBLOH3;
            MAILBLOH1='EXTR' ZONEBLOH1 'MAIL';
*           affectation du blocage
            BLOCH1='BLOQ' MAILBLOH1 'T';
*           affectation du deplacement impose au blocage
            'SI' ('EXIS' DDVA MOTDEPH1);
                DEPIH1='EXCO' MATHELM MOTDEPH1 'T';
                DEPIH2 = 'CHAN' 'NOEUD' DEPIH1 MODHELM ;
                DEPIH3 = 'PROI' MOH1 DEPIH2 'MINI';
                CLH1='DEPI' BLOCH1 DEPIH3;
            'SINON';
                CLH1='DEPI' BLOCH1 0.;
            'FINSI';
*           ASSEMBLAGE CAPA et RIGI et BLOQ dans H_OPER
            TAHELM . &BH . 'H_OPER'  = COH1 'ET' CAH1 'ET' CLH1;
         'SINON';
*           ASSEMBLAGE CAPA et RIGI sans blocage
            TAHELM . &BH . 'H_OPER'  = COH1 'ET' CAH1;
         'FINSI';
*         information sur la linearite du pb donnee par l utilisteur
          MOTHL0  = 'CHAI' 'LIN' NUMFH1; 
*         existance des operateurs de Helmholtz
          LOGH_LINE = 'EXIS' TAHELM . &BH . 'LINEAIRE' ;
          'SI' ( ('NON' LOGH_LINE) 'OU'  ('EXIS' DDVA MOTHL0) );
             LIN0 = 'EXCO' MATHELM  MOTHL0 'SCAL';
             MIN0 = 'MINI' LIN0;
             'SI' ('EGA' MIN0 1.);
                 LOGVARL = VRAI;
             'SINON';
                 LOGVARL = FAUX;
             'FINSI';
             TAHELM . &BH . 'LINEAIRE' = LOGVARL ;
          'FINS';   
*        list TAHELM . &BH . 'H_OPER';
*        trac mah1 moh1;
     'FINS' ;
 'FIN' BH ;
'FINPROC' ;