Procédures | Cast3M

* MADEF3D   PROCEDUR  JK148537  26/06/26    21:15:11     12583          
*** TRAC3D    PROCEDUR  CHAT      96/03/05    21:15:02     2071           
*---------------------------------------------------------------------- 
*                                                                       
*                       PROCEDURE MADEF3D  < TRAC3D                                
*                                                                       
*  PROCEDURE EN DIMENSION3 
*  CONSTRUCTION D UN MAILLAGE SURFACIQUE 3D et du CHPO DEFORME A PARTIR 
* DU MAILLAGE 3D DU PROFIL MERIDIEN D AXE Z (coor 3)
* ET DU CHAMP DE DEPLACEMENT DEFORME ASSOCIE EN DECOMPOSITION DE FOURIER
*  SORT DANS OPTION MODE INITIAL
*---------------------------------------------------------------------- 
*                                                                       
*                      ENTREE  DANS L'ORDRE                             
*                                                                       
*  +   ZMAIL    OBJET MAILLAGE 2d (profil meridien d axe Z (coor 3))  
*  +   ZCHPU    CHPOINT DE DEPLACEMENTS ISSU DU CALCUL FOURIER COQ2 (OU AXI)   
*  +   ZAM      AMPLIFICATION DES DEPLACEMENTS                          
*  +   ZANGL    ANGLE DE ROTATION EN DEGRES POUR LA CONSTRUCTION        
*                  DU MAILLAGE 3D                                       
*  +   ZM       NOMBRE DE DECOUPAGES SUR CET ANGLE                      
*  +   ZN       NUMERO DE L HARMONIQUE  ( 0 SI CALCUL AXI)              
*  +   ZXVISU   ABSCISSE DE L'OEIL                                      
*  +   ZYVISU   ORDONNEE DE L'OEIL                                      
*  +   ZZVISU   COTE DE L'OEIL                                          
*  +   ZINTER   UTILISATION DE LA ROUTINE EN INTERACTIF OU NON          
*                                                                       
*---------------------------------------------------------------------- 
*              DEBPROC TRAC3D                                            
*ZMAIL*MAILLAGE ZCHPU*CHPOINT ZAM*FLOTTANT ZANGL*FLOTTANT ZM*ENTIER      
*ZN*ENTIER ZXVISU*FLOTTANT ZYVISU*FLOTTANT ZZVISU*FLOTTANT               
*ZINTER*LOGIQUE;                                                         
              DEBPROC MADEF3D                                            
ZMAIN*MAILLAGE ZCHPI*CHPOINT ZN*ENTIER ZMOT*MOT ZANGL/FLOTTANT ZM/ENTIER
ZAM/FLOTTANT ;
*-----------------------------------------------------------------------
mess '§§§§§§§ procedure madef3d /  ' zmot ' §§§§§§§§§§' ;
'SI' ('NEG' ('TYPE' ZAM) 'FLOTTANT') ; ZAM = 1.d0 ; 'FINSI' ;
'SI' ('NEG' ('TYPE' ZANGL) 'FLOTTANT') ; ZANGL = 360.d0 ; 'FINSI' ;
'SI' ('NEG' ('TYPE' ZM) 'ENTIER') ; ZM = 10 ; 'FINSI' ; 
VZERO = 0. 0. 0. ;
ZMAIL = ZMAIN PLUS VZERO ;
ZCHPU = ZCHPI PLUS VZERO ;                                                              
*  
inimode = 'MOT' 'MODE' ;
'SI' ('EGA' ('VALE' 'MODE') 'FOUR') ;
   inimode = 'MOT' 'FOUR' ; l_four = 'VALE' 'MODE' 'FOUR' ; 'FINSI' ;
'SI' ('EGA' ('VALE' 'MODE') 'AXIS') ; inimode = 'MOT' 'AXIS' ; 'FINSI';
 
'SI'  (EGA ZMOT 'FORCES') ;
  ZCHPU = 'CHANGER' ZCHPU 'COMP' ('MOTS' 'FR' 'FZ' 'FT' 'MT')
                                 ('MOTS' 'UR' 'UZ' 'UT' 'RT') ;
'FINSI' ;
 
OPTI ELEM QUA4 MODE TRID ;     
CHPUR0=EXCO 'UR' ZCHPU;               
CHPUZ0=EXCO 'UZ' ZCHPU;                                                 
CHPUT0=EXCO 'UT' ZCHPU;  
CHPRT0=EXCO 'RT' ZCHPU;
 ELIM 1.E-4 (ZMAIL ET (EXTR CHPUR0 MAIL)) ;                                      
*                          
ZA0=0. 0. 0.; ZAX=1. 0. 0.; ZAZ=0. 0. 1.;                                 
 
CHPUR0=NOMC SCAL (CHPUR0 * ZAM)  NATURE 'DISCRET';                              
CHPUZ0=NOMC SCAL (CHPUZ0 * ZAM)  NATURE 'DISCRET';                              
CHPUT0=NOMC SCAL (CHPUT0 * ZAM)  NATURE 'DISCRET'; 
CHPRT0=NOMC SCAL (CHPRT0 * ZAM)  NATURE 'DISCRET';  
 
K=0;    
 
  CHPUXKK= NOMC 'UX' CHPUR0  NATURE 'DISCRET';                               
  CHPUYKK= NOMC 'UY' CHPUT0  NATURE 'DISCRET';                                
  CHPUZKK= NOMC 'UZ' CHPUZ0 NATURE 'DISCRET';                                  
  CHPRXKK= NOMC 'RX' (CHPRT0 * 0.d0) NATURE 'DISCRET';                                  
  CHPRYKK= NOMC 'RY' CHPRT0 NATURE 'DISCRET';                                  
  CHPRZKK= NOMC 'RZ' (CHPRT0 * 0.d0) NATURE 'DISCRET'; 
 
  CHPUK  = CHPUXKK ET CHPUYKK ET CHPUZKK ET CHPRXKK ET CHPRYKK ET CHPRZKK;                               
  DETR CHPUXKK;DETR CHPUYKK;DETR CHPUZKK;DETR CHPRXKK ; DETR CHPRYKK  ; DETR CHPRZKK ; 
  CHPU_T = CHPUK PLUS VZERO ;
  ZMAI0 = EXTR CHPU_T MAIL ;
 
TDF3D=TABLE;
  TDF3D.0 = ZMAIL PLUS VZERO ;
 
DTHETA=ZANGL / ZM ; 
REPETER  DEP3D (ZM - 1) ; 
  K= K + 1;                                                           
  THETA= K * (DTHETA);                                                  
  COSNT= COS ( ZN *THETA );                                             
  SINNT= SIN ( ZN *THETA );                                             
  COST = COS THETA ;                                                    
  SINT = SIN THETA ;  
*  CHPUXK = COLI CHPUR0 (COSNT*COST) CHPUT0 (SINNT*SINT*(-1));   
  CHPUXK = COLI CHPUR0 (COSNT*COST) CHPUT0 (COSNT*SINT*(-1));             
*  CHPUYK = COLI CHPUR0 (COSNT*SINT) CHPUT0 (SINNT*COST);                
  CHPUYK = COLI CHPUR0 (COSNT*SINT) CHPUT0 (COSNT*COST);                
  CHPUZK = CHPUZ0 ; 
*jk
  CHPRXK = CHPRT0 * COSNT * SINT*(-1) ;
  CHPRYK = CHPRT0 * COSNT * COST ;
  CHPRZK = CHPRT0 * 0.D0 ;
 
  CHPUXKK= NOMC 'UX' CHPUXK  NATURE 'DISCRET';                               
  CHPUYKK= NOMC 'UY' CHPUYK  NATURE 'DISCRET';                                
  CHPUZKK= NOMC 'UZ' CHPUZK  NATURE 'DISCRET';                                  
  CHPRXKK= NOMC 'RX' CHPRXK  NATURE 'DISCRET';                               
  CHPRYKK= NOMC 'RY' CHPRYK  NATURE 'DISCRET';                                
  CHPRZKK= NOMC 'RZ' CHPRZK  NATURE 'DISCRET';                                  
  CHPUK  = CHPUXKK ET CHPUYKK ET CHPUZKK ET CHPRXKK ET CHPRYKK ET CHPRZKK  ;                               
  DETR CHPUXKK;DETR CHPUYKK;DETR CHPUZKK;DETR CHPRXKK ; DETR CHPRYKK  ; DETR CHPRZKK ;  
  DEPLA ZMAIL TOUR DTHETA ZA0 ZAZ; 
  CHPUL = CHPUK PLUS VZERO ;
  ZMAIU = EXTR CHPUL MAIL ;
  TDF3D.K=ZMAIL PLUS VZERO ;  
     Z_U = (TDF3D.(K - 1)) REGL 1 (TDF3D.K) ;
   CHPU_T = CHPU_T ET CHPUL ;
  SI (K > 1);     
     ZDF3D = ZDF3D ET Z_U ;
  SINON ;
     ZDF3D = Z_U ;  
  FINSI;  
 
  SI (K EGA (ZM - 1)) ;
     Z_U = (TDF3D.K ) REGL 1 (TDF3D.0) ;
     ZDF3D = ZDF3D ET Z_U ;
  FINSI ;    
 
FIN DEP3D;   
 
 
*
'SI' ('EGA' ZMOT 'MAILLAGE') ;
   ELIM 1.E-4 ZDF3D ;
   Z_U = ZDF3D ;
   ZDF3D = REGE Z_U 'VERI' ;                                                           
  DETR CHPU_T ; RESP ZDF3D ; 'FINSI' ;
 
'SI' ('EGA' ZMOT 'DEFORMEE') ;
   DETR ZDF3D ;   ELIM 1.e-4 (EXTR CHPU_T MAIL) ;
   RESP CHPU_T ; 'FINSI' ;
 
'SI'  (EGA ZMOT 'FORCES') ;
  DETR ZDF3D ;   ELIM 1.e-4 (EXTR CHPU_T MAIL) ;
  CHPU_T = 'CHANGER' CHPU_T 'COMP' ('MOTS' 'UX' 'UY' 'UZ' 'RX' 'RY' 'RZ')
                                   ('MOTS' 'FX' 'FY' 'FZ' 'MX' 'MY' 'MZ') ;
   RESP CHPU_T ;
'FINSI' ;
 
'SI' ('EGA' inimode 'FOUR') ;
   'OPTI' 'MODE' 'FOUR' l_four ; 'FINSI' ;
 
*------------------------------------------------------------           
               FINPROC ;