Procédures | Cast3M

* DEADMETR  PROCEDUR  GOUNAND   26/06/09    21:15:03     12566          
************************************************************************
* NOM         : DEADMETR
* DESCRIPTION : Calcule la métrique des éléments géométriques (moyenne
*               intégrée par élément).
*               L'élément de référence servant à définir la métrique
*               identité est un élément régulier de côté 1.
*
*               Comme dans DEDUADAP, le mode axisymétrique n'est pas
*               pris en compte.
*
*
*
*               Entrées : _mt   : Maillage de type QUAF
*                         gdisc : Discrétisation géométrique
*                                 typiquement 'LINE' (linéaire)
*                                 ou 'QUAI' (quadratique mécanique)
*                                 ou 'QUAF' (quadratique fluide).
*                         methgau : méthode d'intégration
*                                   typiquement 'GAU1' (intégration
*                                    réduite à 1 point de Gauss central)
*                                   ou 'GAR1' (éléments linéaires)
*                                   ou 'GAR2' (éléments quadratiques)
*                                   ou 'GAP7' (intégration précise à
*                                              l'ordre 7)
*                             (cf. aussi notice NLIN)
*                    Il n'est sans doute pas utile d'utiliser une
*                    intégration précise car la notion d'intégrale
*                    (ou de moyenne) d'un tenseur est sujette à
*                    caution...
*
*
*               Sorties : un CHPOINT défini sur le noeud central de
*                         chaque élément avec pour noms de composantes
*                         Gij avec i=1...dime
*                                  j=1...dime j>i (tenseur symétrique)
*
*                         Ce CHPOINT peut être transmis directement
*                         à l'opérateur 'DEDU' 'ADAP' pour conserver
*                         au mieux une métrique.
*
*                         Si l'on prescrit des déplacements nuls à la
*                         frontière et que l'on appelle 'DEDU' 'ADAP'
*                         avec l'inverse de la métrique calculée par
*                         DEADMETR, le déplacement des noeuds internes
*                         sera donc également nul ! (cas-test à faire et
*                         à évoluer...)
*
*                         Si l'on prescrit des déplacements non nuls à
*                         la frontière, on essaiera de conserver
*                         l'aspect des éléments de départ.
*
*
*               Exemple (ancienne syntaxe) : met = deadmetr _mt 'QUAF' 'GAU1' ;
*                                            imet = TENS INVE met ;
*                                            dxv = 'DEDU' 'ADAP' _mt 'METR' imet 'CSTE' ;
*
*               Exemple : met = deadmetr mt ;
*                         mod = MODE mt 'MECANIQUE' ;
*                         imet = TENS INVE met ;
*                         dxv = 'DEDU' 'ADAP' mt 'METR' imet mod ;
*
*
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
*               mél : gounand@semt2.smts.cea.fr
**********************************************************************
* VERSION    : v1, 2026/01/01
* HISTORIQUE : v1, 2026/01/01, creation, recopie de GINVMET mais
*                   syntaxe plus simple comme (uniqt le maillage)
* HISTORIQUE : v2, 2026/04/14, ajout metrique globale
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
*
'DEBPROC' DEADMETR ;
'ARGUMENT' _mt*'MAILLAGE' ;
'ARGUMENT' gdisc/'MOT' ;
lgdisc = 'EXIS' gdisc ;
'SI' lgdisc ;
   'ARGUMENT' methgau*'MOT' ;
'SINO' ;
   gdisc = DEADUTIL 'TYPM' _mt ;
   methgau = 'GAU1' ;
'FINS' ;
'ARGUMENT' met/'CHPOINT' ;
lmet = 'EXISTE' met ;
*
tmot = 'TABLE' ;
tnom = 'TABLE' ;
vdim = 'VALEUR' 'DIME' ;
mdim  = DEADUTIL 'DIMM' _mt ;
idx = 0 ;
'SI' lmet ;
   cim = 'CHAINE' 'METL' ;
'SINO' ;
   cim = 'CHAINE' 'METR' ;
'FINS' ;
cg  = 'CHAINE' 'G' ;
'REPETER' bidim vdim ;
   'REPETER' bjdim vdim ;
      'SI' ('>EG' &bjdim &bidim) ;
         idx = '+' idx 1 ;
         tmot . idx = 'CHAINE' cim &bidim &bjdim ;
* Convention Castem opposee à convention NLIN
         tnom . idx = 'CHAINE' cg &bjdim &bidim ;
      'FINSI' ;
   'FIN' bjdim ;
'FIN' bidim ;
*
dtm = 'DIME' tmot ;
'SI' ('NON' lmet) ;
   numop  = dtm ;
   numder = mdim ;
   numvar = dtm ;
   numdat = 0 ;
   numcof = dtm ;
   A = ININLIN numop numvar numdat numcof numder ;
   'REPE' itm dtm ;
      A . 'VAR' . &itm . 'NOMDDL' = tnom . &itm ;
      A . 'VAR' . &itm . 'DISC' = 'CSTE' ;
      A . 'COF' . &itm . 'COMPOR' = tmot . &itm ;
      A . &itm . &itm . 0 = &itm ;
   'FIN' itm ;
   numvar = 1 ;
   numdat = 0 ;
   numcof = 0 ;
   B = ININLIN numop numvar numdat numcof numder ;
   B . 'VAR' . 1 . 'VALEUR' = 1. ;
   'REPE' itm dtm ;
      B . &itm . 1 . 0 = 0 ;
   'FIN' itm ;
   'SI' lgdisc ;
      metr = NLIN gdisc _mt A B 'ERF1' methgau ;
   'SINO' ;
      metr = NLIN gdisc _mt A B 'ERF1' 'CHAM' methgau ;
   'FINS' ;
'SINO' ;
   ncmet  = '/' ('*' vdim ('+' vdim 1)) 2 ;
   numop  = dtm ;
   numder = mdim ;
   numvar = dtm ;
   numdat = ncmet ;
   numcof = dtm ;
   A = ININLIN numop numvar numdat numcof numder ;
*
   idat = 0 ;
   'REPETER' idi vdim ;
      nomdat = 'CHAINE' 'G' &idi &idi ;
*         'MESSAGE' ('CHAINE' 'nomdat=' nomdat) ;
      idat = '+' idat 1 ;
      A . 'DAT' . idat . 'NOMDDL' = nomdat ;
      A . 'DAT' . idat . 'DISC'   = gdisc ;
      'SI' lmet ;
*         A . 'DAT' . idat . 'VALEUR' = 'EXCO' nomdat met nomdat ;
         A . 'DAT' . idat . 'VALEUR' = met ;
      'SINON' ;
         A . 'DAT' . idat . 'VALEUR' = 1.D0 ;
      'FINSI' ;
   'FIN' idi ;
   'REPETER' idi vdim ;
      nj = '-' vdim &idi ;
*      'MESSAGE' ('CHAINE' 'nj=' nj) ;
      'SI' ('>EG' nj 1) ;
         'REPETER' jdi nj ;
* Mise en cohérence avec Castem
*            nomdat = 'CHAINE' 'G' &idi ('+' &idi &jdi) ;
            nomdat = 'CHAINE' 'G' ('+' &idi &jdi) &idi ;
*               'MESSAGE' ('CHAINE' 'nomdat=' nomdat) ;
            idat = '+' idat 1 ;
            A . 'DAT' . idat . 'NOMDDL' = nomdat ;
            A . 'DAT' . idat . 'DISC'   = gdisc ;
            'SI' lmet ;
*               A . 'DAT' . idat . 'VALEUR' = 'EXCO' nomdat met nomdat ;
               A . 'DAT' . idat . 'VALEUR' = met ;
            'SINON' ;
               A . 'DAT' . idat . 'VALEUR' = 0.D0 ;
            'FINSI' ;
         'FIN' jdi ;
      'FINSI' ;
   'FIN' idi ;
   lisdat = 'LECT' 1 'PAS' 1 'NPAS' ('-' numdat 1) ;
*
   'REPE' itm dtm ;
      A . 'VAR' . &itm . 'NOMDDL' = tnom . &itm ;
      A . 'VAR' . &itm . 'DISC' = 'CSTE' ;
      A . 'COF' . &itm . 'COMPOR' = tmot . &itm ;
      A . 'COF' . &itm . 'LDAT'   = lisdat ;
      A . &itm . &itm . 0 = &itm ;
   'FIN' itm ;
*
   numvar = 1 ;
   numdat = 0 ;
   numcof = 0 ;
   B = ININLIN numop numvar numdat numcof numder ;
   B . 'VAR' . 1 . 'VALEUR' = 1. ;
   'REPE' itm dtm ;
      B . &itm . 1 . 0 = 0 ;
   'FIN' itm ;
   'SI' lgdisc ;
      metr = NLIN gdisc _mt A B 'ERF1' methgau ;
   'SINO' ;
      metr = NLIN gdisc _mt A B 'ERF1' 'CHAM' methgau ;
   'FINS' ;
'FINS' ;
'RESPRO' metr ;
*
* End of procedure file DEADMETR
*
'FINPROC' ;