Télécharger la plaquette Cast3M


fr en

Télécharger @rccmtrv.procedur

Retour à la liste

Numérotation des lignes : 

  1. * @RCCMTRV  PROCEDUR  CB215821  18/06/07    21:15:01     9836           
  2. * ----------------------------------------------------------------------
  3. ******                     PROCEDURE @RCCMTRV                     ******
  4. * ----------------------------------------------------------------------
  5. *
  6. *   CETTE PROCEDURE PERMET D'EFFECTUER LE CALCUL DU TRESCA ET DU
  7. *   VON MISES A PARTIR DES CONTRAINTES ELEMENTAIRES
  8. *    6 valeurs a rentre :
  9. *     -----> 4 valeurs pour un modele 2D + 2 valeurs nulles
  10. *     -----> 6 valeurs pour un modele 3D
  11. *
  12. * ----------------------------------------------------------------------
  13. *
  14. *   LES DONNEES SONT :
  15. *    ----> les 4 ou 6 contraintes elementaires
  16. *
  17. *   EN SORTIE :
  18. *    ----> le TRESCA
  19. *    ----> le VON MISES
  20. *
  21. * ----------------------------------------------------------------------
  22. *   PAR Jean-Marc PIETTE
  23. * ----------------------------------------------------------------------
  24. 'DEBPROC' @RCCMTRV  SX*FLOTTANT SY*FLOTTANT SZ*FLOTTANT SXY*FLOTTANT
  25.                     SYZ/FLOTTANT SZX/FLOTTANT   ;
  26. SI (NON (EXISTE SYZ)) ;
  27.   SYZ = 0. ;
  28. FINSI ;
  29. SI (NON (EXISTE SZX)) ;
  30.   SZX = 0. ;
  31. FINSI ;
  32. CC  =   SX + SY + SZ  / 3. ;
  33. SG1 =   SX - CC      ;
  34. SG2 =   SY  - CC    ;
  35. SG3 =  SZ  - CC     ;
  36.  
  37. C2 = SG1*SG1 +(SG2*SG2)+(SG3*SG3) * .5;
  38. C2= SXY*SXY+(SYZ*SYZ)+(SZX*SZX) + C2;
  39. C3A = SG2*SG3 - (SYZ*SYZ) *  SG1 ;
  40. C3B = SYZ*SZX  - (SXY*SG3) * SXY;
  41. C3C = SXY*SYZ - (SG2*SZX) * SZX;
  42. C3  = C3A + C3B + C3C ;
  43. T   =  C2 * 2. / 3.  ** .5 ;
  44. SI (T < 1.E-10) ;
  45.   XTRES = 0. ;
  46.   XVMIS = 0. ;
  47.   RESPRO XTRES ;
  48.   RESPRO XVMIS ;
  49.   QUITTER @RCCMTRV ;
  50. FINSI ;
  51. A   =  C3 * (2. ** 0.5)  / ( T ** 3 ) ;
  52. SI ( ( ABS A )  > 1. ) ;
  53.   A = SIGNE A ;
  54. FINSI ;
  55. TCS = ( 1. - ( A * A ) ) ** 0.5 ;
  56. A   = ATG TCS A; 
  57. A   = A / 3. ;
  58. T   = T * (2 ** 0.5) ;
  59. * ----------------------------------------------------------------------
  60. * calcul des contraintes principales
  61. * ----------------------------------------------------------------------
  62. AUX = 120. ;
  63. AA3 = A + AUX  ;
  64. AA4 = A - AUX  ;
  65. S1 = COS A * T + CC;
  66. S2 = COS AA3 * T + CC;
  67. S3 = COS AA4 * T + CC;
  68. SSS = PROG S1 S2 S3 ;
  69. * ----------------------------------------------------------------------
  70. * calcul du TRESCA et du VON MISES
  71. * ----------------------------------------------------------------------
  72. XTMAX = MAXI SSS ;
  73. XTMIN = MINI SSS ;
  74. XTRES = XTMAX - XTMIN ;
  75. XVMIS = ( ( S1 * S1 ) + ( S2 * S2 ) + ( S3 * S3 ) - ( S1 * S2 )
  76.         - ( S2 * S3 ) - ( S1 * S3 ) ) ** .5 ;
  77. RESPRO XTRES ;
  78. RESPRO XVMIS ;
  79. FINPROC  ;
  80.  
  81.  
  82.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales