Télécharger la plaquette Cast3M


fr en

Télécharger @pvsat.procedur

Retour à la liste

Numérotation des lignes : 

  1. * @PVSAT    PROCEDUR  FD218221  26/02/16    21:15:08     12474          
  2. *---------------------------------------------------------------------*
  3. * PROCEDURE @PVSAT                                                    *
  4. *---------------------------------------------------------------------*
  5. * NOM         : @PVSAT                                                *
  6. *                                                                     *
  7. * LANGAGE    : GIBIANE-CAST3M                                         *
  8. * AUTEUR     : G. Sciumè (I2M - University of Bordeaux)               *
  9. * COURRIEL   : giuseppe.sciume@u-bordeuax.fr                          *
  10. *---------------------------------------------------------------------*
  11. * VERSION    : v1, 13/02/2018, version initiale                       *
  12. * HISTORIQUE :                                                        *
  13. *---------------------------------------------------------------------*
  14. * COMMENTAIRE: calcul de la pression de la vapeur saturée             *
  15. *              de la pression de la vapeur Pgw                        *
  16. *              de la densité de la vapeur RHOgw                       *
  17. *---------------------------------------------------------------------*
  18. *                                                                     *
  19. * ENTREE                                                              *
  20. *  - Temperature (K)                                                  *
  21. *  - Pression capillaire (Pa)                                         *
  22. *  - Pression du gaz (Pa)                                             *
  23. *                                                                     *
  24. *-------------------- CARACTERISTIQUES CONSTANTES --------------------*
  25. *                                                                     *
  26. * RGP1     : Constante des gaz parfaits (J/mol/K)                     *
  27. * MMGA1    : Masse molaire de l'air (kg/m3)                           *
  28. * MMGW1    : Masse molaire de l'eau (kg/m3)                           *
  29. * RHOS1    : Masse volumique du solide (kg/m3)                        *
  30. * CPS0     : CAPACITE CALORIFIQUE DU SOLIDE                           *
  31. * CPW1     : Capacite calorifique a P constante de l'eau (J/kg/K)     *
  32. * CPGW1    : Capacite calorifique a P constante de la vapeur (J/kg/K) *
  33. * CPGA1    : Capacite calorifique a P constante de l'air (J/kg/K)     *
  34. * DHHD1    : Enthalpie de deshydratation (J/kg)                       *
  35. *---------------------------------------------------------------------*
  36. DEBPROC @PVSAT chpg*'CHPOINT' chpc*'CHPOINT' chtk*'CHPOINT';
  37.  
  38. RGP1     = 8.3145 ;                                                   
  39. MMGA1    = 28.9645E-3 ;                                               
  40. MMGW1    = 18.0153E-3 ;                                               
  41. RHOS1    = 2625.8 ;
  42. CPW1     = 4181.0 ;
  43. CPGW1    = 1805.0 ;
  44. CPGA1    = 1005.7 ;
  45. *---------------------------------------------------------------------*
  46.  
  47. CHTKSC0  = chtk 'NOMC' 'SCAL' ;
  48. CHPCSC0  = chpc 'NOMC' 'SCAL' ;
  49. CHPGSC0  = chpg 'NOMC' 'SCAL' ;
  50. CHTKSCM1 = CHTKSC0 ** -1 ;
  51. * Variabili di lavoro :
  52. FGPGA0   = (MMGA1 / RGP1 )* CHTKSCM1 ;
  53. FGPGW0   = (MMGW1 / RGP1 )* CHTKSCM1 ;
  54.  
  55.  
  56. *----------------- MASSE VOLUMIQUE DE L'EAU LIQUIDE ------------------*
  57. *                                                                     *
  58. * Constant water density
  59. RHOW0    = 1000.;
  60. DRHOW = 0.;
  61. *---------------------------------------------------------------------*    
  62.  
  63.  
  64. *------------------- Pression de vapeur saturante --------------------*
  65. * PARAMETRES
  66. * GCi      : facteurs polynomiaux
  67. GC1      = -5.8002206E+03 ;
  68. GC2      =  1.3914993E+00 ;
  69. GC3      = -4.8640239E-02 ;
  70. GC4      =  4.1764768E-05 ;
  71. GC5      = -1.4452093E-08 ;
  72. GC6      =  6.5459673E+00 ;
  73.  
  74. * CHPVSAT0: Pression de vapeur saturante :
  75. CHPVSAT0 = (GC1 * CHTKSCM1) + GC2 + (GC3 * CHTKSC0)
  76.          + (GC4 * (CHTKSC0 ** 2)) + (GC5 * (CHTKSC0 ** 3))
  77.          + (GC6 * ('LOG'CHTKSC0)) ;
  78. CHPVSAT0 = 'EXP' CHPVSAT0 ;
  79.  
  80. * Derivee -/- T :
  81. DPSATDT0 = (-1. * GC1 * (CHTKSCM1 ** 2)) + GC3 + (2. * GC4 * CHTKSC0)
  82.           + (3. * GC5 * (CHTKSC0 ** 2)) + (GC6 * CHTKSCM1) ;
  83. DPSATDT0 = DPSATDT0 * CHPVSAT0 ;
  84. *---------------------------------------------------------------------*
  85.  
  86. * CHPGWSC0 : Pression de vapeur d'eau (Pa, Clapeyron) :
  87. TEMP1    = FGPGW0 * (RHOW0 ** -1) ;
  88. TEMP2    = 'EXP' (TEMP1 * (CHPGSC0 - CHPCSC0 - CHPVSAT0)) ;
  89. CHPGWSC0 = CHPVSAT0 * TEMP2 ;
  90.  
  91. * RHOGW0 : densité de la vapeur  :
  92. RHOGW0   = FGPGW0 * CHPGWSC0 ;
  93.  
  94.  
  95. FINPROC CHPVSAT0 CHPGWSC0 RHOGW0 RHOW0 DPSATDT0 DRHOW;
  96. ***********************************************************************
  97. * FIN PROCEDURE @PVSAT
  98. **********************************************************************
  99.  
  100.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales