Procédures | Cast3M

* @PARAMEC  PROCEDUR  FD218221  26/02/16    21:15:08     12474          
*---------------------------------------------------------------------*
* PROCEDURE @PARAMEC                                                  *
*---------------------------------------------------------------------*
* NOM         : @PARAMEC                                              *
*                                                                     *
* LANGAGE     : GIBIANE-CAST3M                                        *
* AUTEUR      : G. Sciumè (I2M - University of Bordeaux)              *
* COURRIEL    : giuseppe.sciume@u-bordeuax.fr                         *
*---------------------------------------------------------------------*
* COMMENTAIRE: mise a jour parametres avec le degre d'hydratation     *
*---------------------------------------------------------------------*
* VERSION    : v1, 31/10/2024, version initiale                       *
* HISTORIQUE : v2, XX/XX/20XX,                                        *
*---------------------------------------------------------------------*
DEBP @PARAMEC TABGEN*'TABLE' ;
 
WTAB     = TABGEN. 'WTABLE' ;
*
*****BET_TOT  = TABGEN. 'BETON' ;
BET_TOT  = EXTR WTAB.'MOD_MEC' 'COMP' 'BETON_THM';
MAT_TOT  = REDU TABGEN. 'CARACTERISTIQUES' BET_TOT;
TAB_ZONE = EXTR BET_TOT 'ZONE';
NZONE    = ('DIME' TAB_ZONE)/2;
 
 
*----------------------------------------------------------------------
INDH1 = (DIME (TABGEN.DEPLACEMENTS)) - 1;
INDH2 = INDH1 + 1;
*
SI (WTAB.'COUPLAGE_BETON_THM');
  SI (WTAB . 'HT_SOL1' 'EGA' 0.);
    WTAB .'TET1' = TABGEN . 'CONTINUATION' . 'TEMPERATURES' ;
    WTAB .'TET2' = TABGEN . 'CONTINUATION' . 'TEMPERATURES' ;
  SINO;
    WTAB .'TET1' = WTAB . 'HT_SOL1' ;
    WTAB .'TET2' = WTAB . 'HT_SOL2' ;
  FINS;
  SI ('EXIS' WTAB 'VAR_THM1') ;
        WTAB .'HYD1'  = WTAB . 'VAR_THM1' ;
        WTAB .'HYD2'  = WTAB . 'VAR_THM2' ;
  SINO;
    WTAB .'HYD1'  = TABGEN . 'VARIABLES_THM' . 0;
          WTAB .'HYD2'  = TABGEN . 'VARIABLES_THM' . 0;
  FINS;
SINO;
  WTAB .'TET1' = TABGEN.'TEMPERATURES' . INDH1;
  WTAB .'TET2' = TABGEN.'TEMPERATURES' . INDH2;
  WTAB .'HYD1' = TABGEN.'VARIABLES_THM' . INDH1;
  WTAB .'HYD2' = TABGEN.'VARIABLES_THM' . INDH2;
FINS;
*
SI (INDH1 'EGA' 0);
  TEMPO0 =  'EXTR' TABGEN.'TEMPS_CALCULES' 1; 
  TEMPO1 =  'EXTR' TABGEN.'TEMPS_CALCULES' 2;    
  DELTAT0 = TEMPO1 - TEMPO0;
  DELTAT = DELTAT0;
SINO;
  DELTAT = WTAB.'DT';
FINS;
*----------------------------------------------------------------------
 
DT = DELTAT;
 
 
'SI' (DT 'EGA' 0.);
DT = 1.e-12 ;
'FINSI';
 
*LIST DT;
 
 
*** BOUCLE SUR LES DIFFERENTS ZONES DU MODELE TOTAL
INDZ = 1;
*
'REPETER' BOUCLE_Z NZONE;
*
MOD_i  =   TAB_ZONE.indz;
MAT_i  =  'REDU' MAT_TOT  MOD_i;
MAIL_i =  'EXTR' MOD_i   'MAIL';
*
SI (EXIS MAT_i 'TREF');
  TETA1  =  'REDU' MAIL_i (WTAB. 'TET1');
  TETA2  =  'REDU' MAIL_i (WTAB. 'TET2');
FINS;
*
*HYDR1  = 'REDU' WTAB.HYD1 MOD_i;
*HYDR2  = 'REDU' WTAB.HYD2 MOD_i;
HYDR1  = PROI MOD_i WTAB.HYD1;
HYDR2  = PROI MOD_i WTAB.HYD2;
 
*LIST 'RESUME' HYDR1;
 
*
*LIST 'RESUME' MAT_i;
*
**********************************************************************
* MISE A JOURS DU MATERIAU SI FORMULATION VISCOELSTIQUE              *
**********************************************************************
*
* Parametri posso convertire direttamente in CHPO
YOUN = CHAN CHPO MOD_i (('EXCO' 'YOUN'  MAT_i)  'NOMC' 'SCAL');
NU   = CHAN CHPO MOD_i (('EXCO' 'NU'    MAT_i)  'NOMC' 'SCAL');
KTR0 = CHAN CHPO MOD_i (('EXCO' 'KTR0'  MAT_i)  'NOMC' 'SCAL');
BTRA = CHAN CHPO MOD_i (('EXCO' 'BTRA'  MAT_i)  'NOMC' 'SCAL');
NUPO = CHAN CHPO MOD_i (('EXCO' 'NUPO'  MAT_i)  'NOMC' 'SCAL');
EKV1 = CHAN CHPO MOD_i (('EXCO' 'EKV1'  MAT_i)  'NOMC' 'SCAL');
AYOU = CHAN CHPO MOD_i (('EXCO' 'AYOU'  MAT_i) 'NOMC' 'SCAL');
AFTR = CHAN CHPO MOD_i (('EXCO' 'AFTR'  MAT_i) 'NOMC' 'SCAL');
AGFT = CHAN CHPO MOD_i (('EXCO' 'AGFT'  MAT_i) 'NOMC' 'SCAL');
AFLU = CHAN CHPO MOD_i (('EXCO' 'AFLU'  MAT_i) 'NOMC' 'SCAL');
GA0  = CHAN CHPO MOD_i (('EXCO' 'GAM0'  MAT_i) 'NOMC' 'SCAL');
BIOT1  = CHAN CHPO MOD_i (('EXCO' 'BIOT'  MAT_i) 'NOMC' 'SCAL');
*
* Parametri che NON vengono aggiornati nella procedura
* li tengo in CHAM e poi converto in CHPO quelli che uso
ALPHA_e = (('EXCO' 'ALPH'  MAT_i) 'NOMC' 'SCAL');
ATRA_e  = (('EXCO' 'ATRA'  MAT_i) 'NOMC' 'SCAL');
ACOM_e  = (('EXCO' 'ACOM'  MAT_i) 'NOMC' 'SCAL');
BCOM_e  = (('EXCO' 'BCOM'  MAT_i) 'NOMC' 'SCAL');
TKV1_e  = (('EXCO' 'TKV1'  MAT_i) 'NOMC' 'SCAL');
ETA2_e  = (('EXCO' 'ETA2'  MAT_i) 'NOMC' 'SCAL');
BETA_e  = (('EXCO' 'BETA'  MAT_i) 'NOMC' 'SCAL');
XFDE_e  = (('EXCO' 'XFDE'  MAT_i) 'NOMC' 'SCAL');
LCAR_e  = (('EXCO' 'LCAR'  MAT_i) 'NOMC' 'SCAL');
YOUN_e  = (('EXCO' 'YOUN'  MAT_i) 'NOMC' 'SCAL');
NU_e    = (('EXCO' 'NU'    MAT_i) 'NOMC' 'SCAL');
KTR0_e  = (('EXCO' 'KTR0'  MAT_i) 'NOMC' 'SCAL');
BTRA_e  = (('EXCO' 'BTRA'  MAT_i) 'NOMC' 'SCAL');
EKV1_e  = (('EXCO' 'EKV1'  MAT_i) 'NOMC' 'SCAL');
NUPO_e  = (('EXCO' 'NUPO'  MAT_i) 'NOMC' 'SCAL');
OMEG_e  = (('EXCO' 'OMEG'  MAT_i) 'NOMC' 'SCAL');
VGA_e   = (('EXCO' 'VGA'   MAT_i) 'NOMC' 'SCAL');
VGB_e   = (('EXCO' 'VGB'   MAT_i) 'NOMC' 'SCAL');
VGC_e   = (('EXCO' 'VGC'   MAT_i) 'NOMC' 'SCAL');
 
SI (EXIS MAT_i 'TREF');
   TREF_e  = (('EXCO' 'TREF'  MAT_i) 'NOMC' 'SCAL');
   TALP_e  = (('EXCO' 'TALP'  MAT_i) 'NOMC' 'SCAL');
FINS;
 
*-------------------------------
ATRA = CHAN CHPO MOD_i ATRA_e;
TKV1 = CHAN CHPO MOD_i TKV1_e;
LCA1 = CHAN CHPO MOD_i LCAR_e;
FTR  = YOUN * KTR0;
*--------------------------------------------------------------------
 
*LIST 'RESUME' HYDR1;
 
* GESTION DU DEGRE DE HYDRATATION 
*GA1  = (CHAN CHPO MOD_i (PROI MOD_i HYDR1)) 'NOMC' 'SCAL';
*GA2  = (CHAN CHPO MOD_i (PROI MOD_i HYDR2)) 'NOMC' 'SCAL';
GA1  = (CHAN CHPO MOD_i HYDR1) 'NOMC' 'SCAL';
GA2  = (CHAN CHPO MOD_i HYDR2) 'NOMC' 'SCAL';
GAm  = 0.5 * (GA1 + GA2);
Hmin = 0.05; 
MATUR1 = 'BORN' ((GA1 - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
MATUR2 = 'BORN' ((GA2 - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
MATUR  = 'BORN' ((GAm - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
 
* MISE A JOURS DU MATERIAU
* Estraggo scalare
AYOU_SC = MAXI AYOU;
AFTR_SC = MAXI AFTR;
AGFT_SC = MAXI AGFT;
AFLU_SC = MAXI AFLU;
GAM01_SC = MAXI GA0;
YOUN_mod = YOUN * (MATUR ** AYOU_SC);
FTR_mod  = FTR  * (MATUR ** AFTR_SC);
GFT_mod  = BTRA * (MATUR ** AGFT_SC);
KTR0_mod = FTR_mod * (YOUN_mod ** (-1.))  ;
BTRA_mod = GFT_mod;
 
*** Conversion en CHAM
YOUN_mod = 'CHAN' 'CHAM' YOUN_mod MOD_i ;
KTR0_mod = 'CHAN' 'CHAM' KTR0_mod MOD_i ;
BTRA_mod = 'CHAN' 'CHAM' BTRA_mod MOD_i ;
***
 
*** GESTION PARTIE FLUAGE
EKV1_1 = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR1))**(-1.)) *
          (MATUR1 ** AFLU_SC));
EKV1_2 = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR2))**(-1.)) *
          (MATUR2 ** AFLU_SC));
EKV1_moy = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR))**(-1.)) *
          (MATUR ** AFLU_SC));
*
DEKV1    = (EKV1_2 - EKV1_1) * (1./dt);
OMEGA    = 1. + (DEKV1 * TKV1 * (EKV1_moy ** (-1.)));
EKV1_mod = 'CHAN' 'CHAM' EKV1_moy MOD_i ;
OME_mod  = 'CHAN' 'CHAM' OMEGA MOD_i ;
 
BIOT1_SC = MAXI BIOT1;
 
* Partie necessaire pour le fluagede dessiccation
 
SI (EXIS MAT_i 'TREF');
  PC1    = (EXCO 'PC' TETA1) 'NOMC' 'SCAL';
  PC2    = (EXCO 'PC' TETA2) 'NOMC' 'SCAL';
  DPC    = (PC2 - PC1)  * (1./dt);
  DPC_e  = 'CHAN' 'CHAM' DPC MOD_i ;
FINS;
***********************************************
 
MAT_imod = MATE MOD_i 'YOUN' YOUN_mod 'NU' NU_e 'KTR0' KTR0_mod
'ALPH' alpha_e 'ATRA' atra_e 'BTRA' BTRA_mod 'ACOM' acom_e
'BCOM' bcom_e 'EKV1' EKV1_mod 'TKV1' TKV1_e 'ETA2' eta2_e
'NUPO' NUPO_e 'BETA' beta_e   'XFDE' XFDE_e 'LCAR' LCAR_e 
'OMEG' OME_MOD 'DPC' 0.  'GAM0' GAM01_SC 'AYOU' AYOU_SC 
'AFTR' AFTR_SC  'AFLU' AFLU_SC 'AGFT' AGFT_SC  'BIOT' BIOT1_SC
'VGA' VGA_e 'VGB' VGB_e 'VGC' VGC_e;
 
SI (EXIS MAT_i 'TREF');
  MAT_imod = MATE MOD_i 'YOUN' YOUN_mod 'NU' NU_e 'KTR0' KTR0_mod
  'ALPH' alpha_e 'ATRA' atra_e 'BTRA' BTRA_mod 'ACOM' acom_e
  'BCOM' bcom_e 'EKV1' EKV1_mod 'TKV1' TKV1_e 'ETA2' eta2_e
  'NUPO' NUPO_e 'BETA' beta_e   'XFDE' XFDE_e 'LCAR' LCAR_e 
  'OMEG' OME_MOD 'DPC' DPC_e    'GAM0' GAM01_SC 'AYOU' AYOU_SC 
  'AFTR' AFTR_SC  'AFLU' AFLU_SC 'AGFT' AGFT_SC  'BIOT' BIOT1_SC 
  'VGA' VGA_e 'VGB' VGB_e 'VGC' VGC_e
  'TREF' TREF_e 'TALP' TALP_e;
FINS;
 
'SI' (indz EGA 1);
    MAT_fin = MAT_imod;
'SINON';
    MAT_fin = MAT_fin  et  MAT_imod;
'FINSI';
 
indz = indz + 2;
'FIN' BOUCLE_Z;
 
SI (EXIS TABGEN 'MATE_AGGR');
    MAT_fin = MAT_fin  ET (TABGEN. 'MATE_AGGR' );
FINS;
 
FINPROC MAT_fin;
***********************************************************************
* FIN PROCEDURE @PARAMEC
***********************************************************************