Procédures | Cast3M

* @MASSMOD  PROCEDUR  FD218221  26/06/11    21:15:06     12572          
*---------------------------------------------------------------------*
* NOM         :   @MASSMOD                                            *
*                                                                     *
* DESCRIPTION :   CALCUL DES MASSES MODALES EFFECTIVES MOBILISEES     *
*                 SELON LES DIRECTIONS DE MOUVEMENT (X, Y, Z) POUR    *
*                 CHAQUE MODE PROPRE, SUITE A UNE ANALYSE MODALE      *
*                 REALISEE PAR L'OPERATEUR VIBR.                      *
*                                                                     *
* SYNTAXE     :   TABRESU = @MASSMOD TAB_VIBR MASS1 ;                 *
*                                                                     *
*                                                                     *
* LANGAGE     :   GIBIANE-CAST3M                                      *
* AUTEUR      :   Abdelhafid NOUALI (SIMCO - SIAME - UPPA)            *
* COURRIEL    :   a.nouali@univ-pau.fr                                *
*---------------------------------------------------------------------*
*
DEBPROC @MASSMOD TAB1*'TABLE' MASS1*'RIGIDITE' ;
*
*----------------------------------------------------------------------
*  1. INITIALISATIONS 
*----------------------------------------------------------------------
*
NB_MODE = (DIME TAB1 . 'MODES') - 2 ;
STRU1   = EXTR MASS1 'MAIL' ;
*
* Masse totale = resultante des forces FX obtenues en multipliant
* la matrice de masse par un champ de translation rigide unitaire
* selon X.
TMAS = RESU (MASS1 * (MANU 'CHPO' STRU1 'UX' 1.)) ;
TMAS = EXTR (EXTR (EXCO TMAS 'FX') 'VALE' 'SCAL') 1 ;
*
* Listes destinees a recevoir les resultats mode par mode
L_MODE = LECT ;
L_FREQ = PROG ;
L_MX   = PROG ;
L_MY   = PROG ;
L_MZ   = PROG ;
*
*----------------------------------------------------------------------
*  2. DETECTION DES DIRECTIONS DE TRANSLATION ACTIVES
*----------------------------------------------------------------------
*
* On teste sur le premier mode la presence des composantes duales
* FX, FY, FZ apres produit deformee * matrice de masse.
TEST = ((TAB1 . 'MODES' . 1) . 'DEFORMEE_MODALE') * MASS1 ;
SI (EXIS TEST 'FX') ; DIR_X = VRAI ; SINON ; DIR_X = FAUX ; FINSI ;
SI (EXIS TEST 'FY') ; DIR_Y = VRAI ; SINON ; DIR_Y = FAUX ; FINSI ;
SI (EXIS TEST 'FZ') ; DIR_Z = VRAI ; SINON ; DIR_Z = FAUX ; FINSI ;
*
*----------------------------------------------------------------------
*  3. BOUCLE SUR LES MODES PROPRES
*----------------------------------------------------------------------
*
REPETER BOU1 NB_MODE ;
*
  BASE_M   = TAB1 . 'MODES' . &BOU1 ;
  F_MODALE = BASE_M . 'FREQUENCE' ;
  D_MODALE = BASE_M . 'DEFORMEE_MODALE' ;
  M_GENER  = BASE_M . 'MASSE_GENERALISEE' ;
*
  L_MODE = INSE L_MODE &BOU1 &BOU1 ;
  L_FREQ = INSE L_FREQ &BOU1 F_MODALE ;
*
* Masses modales effectives : m_eff_i,j = L_i,j^2 / M_gen,i
* avec L_i,j = facteur de participation = somme nodale du produit
* (matrice de masse * deformee), projete sur la direction j.
  MM = ((RESU (D_MODALE * MASS1)) ** 2) / M_GENER ;
*
  SI DIR_X ;
    MMX  = 100. * (EXTR (EXTR (EXCO MM 'FX') 'VALE' 'SCAL') 1) / TMAS ;
    L_MX = INSE L_MX &BOU1 MMX ;
  FINSI ;
*
  SI DIR_Y ;
    MMY  = 100. * (EXTR (EXTR (EXCO MM 'FY') 'VALE' 'SCAL') 1) / TMAS ;
    L_MY = INSE L_MY &BOU1 MMY ;
  FINSI ;
*
  SI DIR_Z ;
    MMZ  = 100. * (EXTR (EXTR (EXCO MM 'FZ') 'VALE' 'SCAL') 1) / TMAS ;
    L_MZ = INSE L_MZ &BOU1 MMZ ;
  FINSI ;
*
FIN BOU1 ;
*
*----------------------------------------------------------------------
*  4. CONSTRUCTION DE LA TABLE RESULTAT 
*----------------------------------------------------------------------
*
* On ajoute la somme cumulee en fin de chaque liste de masses.
TABRESU              = TABLE ;
TABRESU . ' MODE'  = L_MODE ;
TABRESU . ' FREQ_(Hz)'= L_FREQ ;
*
SI DIR_X ;
  L_MX = L_MX ET (SOMM L_MX) ;
  TABRESU . ' MASSE-X_(%)' = L_MX ;
FINSI ;
SI DIR_Y ;
  L_MY = L_MY ET (SOMM L_MY) ;
  TABRESU . ' MASSE-Y_(%)' = L_MY ;
FINSI ;
SI DIR_Z ;
  L_MZ = L_MZ ET (SOMM L_MZ) ;
  TABRESU . ' MASSE-Z_(%)' = L_MZ ;
FINSI ;
*
TABRESU . ' MASSE-T_(kg)' = PROG TMAS ;
*
*----------------------------------------------------------------------
*  5. AFFICHAGE DES RESULTATS DANS LE TERMINAL 
*----------------------------------------------------------------------
*
IND   = INDEX TABRESU ;
D_IND = DIME IND ;
*
MESS ;
MESS '-------------- MASSES MOBILISEES PAR MODE ET PAR DIRECTION ----------------------' ;
MESS ;
*
* Ligne d'en-tete : noms des colonnes de la table
TETE = CHAI IND.1 * 5 ;
REPETER BOU3 (D_IND - 2) ;
  TETE = CHAI TETE IND.(&BOU3 + 1) < 14 ;
FIN BOU3 ;
MESS TETE ;
*
* Lignes : une par mode
REPETER BOU2 NB_MODE ;
  INTER = CHAI &BOU2 * 5 ;
  REPETER BOU3 (D_IND - 2) ;
    VAL   = EXTR (TABRESU . (IND . (&BOU3 + 1))) &BOU2 ;
    INTER = CHAI INTER 'FORMAT' '(F10.5)' VAL < 14 ;
  FIN BOU3 ;
  MESS INTER ;
FIN BOU2 ;
*
MESS ;
*
* Ligne de cumul : somme par direction (derniere valeur de chaque liste)
TOT1 = CHAI 'MASSE TOTALE PAR DIRECTION (%):' ;
REPETER BOU3 (D_IND - 3) ;
  VAL  = EXTR (TABRESU . (IND . (&BOU3 + 2))) (NB_MODE + 1) ;
  TOT1 = CHAI TOT1 'FORMAT' '(F12.5)' VAL ' %' ;
FIN BOU3 ;
MESS TOT1 ;
*
MESS ;
MESS 'MASSE TOTALE DE LA STRUCTURE =' (EXTR (TABRESU.' MASSE-T_(kg)') 1) ' kg' ;
MESS ;
MESS '--------------------------------------------------------------------------------' ;
MESS ;
*
*----------------------------------------------------------------------
*
FINPROC TABRESU ;