Procédures | Cast3M

* @DEPS_HH  PROCEDUR  FD218221  26/02/16    21:15:06     12474          
*---------------------------------------------------------------------*
* @DEPS_HH  PROCEDUR                                                  *
* PROCEDURE @DEPS_HH                                                  *
* APPELLE PAR : UNPAS                                                 *
*---------------------------------------------------------------------*
* NOM         : @DEPS_HH                                              *
*                                                                     *
* LANGAGE     : GIBIANE-CAST3M                                        *
* AUTEUR      : G. Sciumè (I2M - University of Bordeaux)              *
* COURRIEL    : giuseppe.sciume@u-bordeuax.fr                         *
*---------------------------------------------------------------------*
* COMMENTAIRE: calcul de la deformation liee à pc e pg                *
*---------------------------------------------------------------------*
* VERSION    : v1, 31/10/2024, version initiale                       *
* HISTORIQUE : v2, XX/XX/20XX,                                        *
*---------------------------------------------------------------------*
DEBP @DEPS_HH  TABGEN*'TABLE' MCR1_TOT*'MCHAML' DT*'FLOTTANT';
 
BIOT_FIX = VRAI;
*
*
WTAB     = TABGEN. 'WTABLE' ;
*****BET_TOT  = TABGEN. 'BETON' ;
BET_TOT  = EXTR WTAB.'MOD_MEC' 'COMP' 'BETON_THM';
MAT_TOT  = REDU TABGEN. 'CARACTERISTIQUES' BET_TOT;
DT       = WTAB. 'DT';
*
TAB_ZONE = EXTR BET_TOT 'ZONE';
NZONE    = ('DIME' TAB_ZONE)/2;
*
'SI' (DT 'EGA' 0.);
DT = 1.e-12 ;
'FINSI';
 
*
*** BOUCLE SUR LES DIFFERENTS ZONES DU MODELE BETON
INDZ = 1;
*
'REPETER' BOUCLE_Z NZONE;
*
MOD_i  =  TAB_ZONE.indz;
MAT_i  = 'REDU' MAT_TOT  MOD_i;
MAIL_i = 'EXTR' MOD_i   'MAIL';
TETA1  = 'REDU' MAIL_i (WTAB. 'TET1');
TETA2  = 'REDU' MAIL_i (WTAB. 'TET2');
*HYDR1  = 'REDU' WTAB.HYD1 MOD_i;
*HYDR2  = 'REDU' WTAB.HYD2 MOD_i;
HYDR1  = PROI MOD_i WTAB.HYD1;
HYDR2  = PROI MOD_i WTAB.HYD2;
 
MCR1   = CHAN CHPO MOD_i ('REDU' MCR1_TOT  MOD_i);
*
* RECUPERATION DES PARAMETRES ELASTICITE
YOUN    = CHAN CHPO MOD_i (('EXCO' 'YOUN'  MAT_i) 'NOMC' 'SCAL');
NU      = CHAN CHPO MOD_i (('EXCO' 'NU'    MAT_i) 'NOMC' 'SCAL');
ALPHA_e =                 (('EXCO' 'ALPH'  MAT_i) 'NOMC' 'SCAL');
AYOU    = CHAN CHPO MOD_i (('EXCO' 'AYOU'  MAT_i) 'NOMC' 'SCAL');
GA0     = CHAN CHPO MOD_i (('EXCO' 'GAM0'  MAT_i) 'NOMC' 'SCAL');
BIOT1   = CHAN CHPO MOD_i (('EXCO' 'BIOT'  MAT_i) 'NOMC' 'SCAL');
VGA     = CHAN CHPO MOD_i (('EXCO' 'VGA'   MAT_i) 'NOMC' 'SCAL');
VGB     = CHAN CHPO MOD_i (('EXCO' 'VGB'   MAT_i) 'NOMC' 'SCAL');
VGC     = CHAN CHPO MOD_i (('EXCO' 'VGC'   MAT_i) 'NOMC' 'SCAL');
 
 
*
* GESTION DU DEGRE DE HYDRATATION 
GA1  = (CHAN CHPO MOD_i HYDR1) 'NOMC' 'SCAL';
GA2  = (CHAN CHPO MOD_i HYDR2) 'NOMC' 'SCAL';
GAm  =  0.5 * (GA1 + GA2);
Hmin = 0.05; 
MATUR1 = 'BORN' ((GA1 - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
MATUR2 = 'BORN' ((GA2 - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
MATUR  = 'BORN' ((GAm - GA0)*((1. - GA0)**-1.)) 'SCAL' 'MINIMUM' Hmin;
*
*** SKELETON AND GRAIN BULK MODULI (final values)
BULK_SKE = YOUN * ((3. * (1. - (2.* NU)))**(-1.));
BULK_SOL = BULK_SKE * ((1. - BIOT1)**-1.);
*
*
*** PASSO N **********************************************************
*EXP(ESPONENTE*(LOG(ARGOMENTO))
YOUN_1  =  YOUN * (EXP(AYOU*(LOG(MATUR1))));
NU_1    = NU ;
BULK_1  = (YOUN_1 * ((3. * (1. - (2. *  NU_1)))**(-1.)));
BULK_1  = 'BORNER'  BULK_1 'SCAL' 'MINIMUM' 2.2E9;
BIOT_1  = 1. - (BULK_1 * (BULK_SOL**( -1.)));
*BIOT_1  =   BIOT1 * (EXP(AYOU*(LOG(MATUR1))));
*
SI (BIOT_FIX 'EGA' VRAI);
  BIOT_1  = BIOT1;
FINS;
*
 
PC_1  = ((EXCO 'PC' TETA1) 'NOMC' 'SCAL');
PG_1  = ((EXCO 'PG' TETA1) 'NOMC' 'SCAL');
TK_1  = ((EXCO 'T'  TETA1) 'NOMC' 'SCAL');
SATU_1  = @SATURA PC_1 TK_1 GA1 VGA VGB VGC GA0;
PS1     = PG_1 - (SATU_1 * PC_1);
*PS1     = 0. - (SATU_1 * PC_1);
*
*** PASSO N + 1 ******************************************************
YOUN_2  =  YOUN * (EXP(AYOU*(LOG(MATUR2))));
NU_2    = NU ;
BULK_2  = (YOUN_2 * ((3. * (1. - (2. *  NU_2)))**(-1.)));
BULK_2  = 'BORNER'  BULK_2 'SCAL' 'MINIMUM' 2.2E9;
BIOT_2  = 1. - (BULK_2 * (BULK_SOL**(-1.)));
*BIOT_2  =   BIOT1 * (EXP(AYOU*(LOG(MATUR2))));
*
SI (BIOT_FIX 'EGA' VRAI);
  BIOT_2  = BIOT1;
FINS;
*
PC_2  = ((EXCO 'PC' TETA2) 'NOMC' 'SCAL');
PG_2  = ((EXCO 'PG' TETA2) 'NOMC' 'SCAL');
TK_2  = ((EXCO 'T'  TETA2) 'NOMC' 'SCAL');
SATU_2  = @SATURA PC_2 TK_2 GA2 VGA VGB VGC GA0;
PS2     = PG_2 - (SATU_2 * PC_2);
*PS2     = 0. - (SATU_2 * PC_2);
*
*** BULK MODULUS MEAN VALUE
BULK_MOY = 0.5 * (BULK_1 + BULK_2);
COEF_RET = (3. *  BULK_MOY)**(-1.);
*
*** BIOT COEFFICIENT MEAN VALUE
ALFA_MOY = 0.5 * (BIOT_1 + BIOT_2);
*
*** INCREMENT DE ALFA.PS et VALEUR MOYEN (attenzione ai 2 modelli costitutivi)
D_APS    =  ALFA_MOY * (PS2 - PS1);
*D_APS    =  (BIOT_2*PS2) - (BIOT_1*PS1);
APS_MOY  =  0.5 * ALFA_MOY * (PS2 + PS1);
*
*** ELASTIC SHRINKAGE
RET_ELA = (COEF_RET) * D_APS;
DHH_ELA =  CHAN CHAM RET_ELA MOD_i;
DHH_MC  =  0. * DHH_ELA;
DEPS2i  =  0. * DHH_ELA; 
 
* CALCOLO LA PARTE LEGATA AL CREEP
*
* Estraggo i parametri aggiuntivi
EKV1 = CHAN CHPO MOD_i (('EXCO' 'EKV1'  MAT_i ) 'NOMC' 'SCAL');
TKV1 = CHAN CHPO MOD_i (('EXCO' 'TKV1'  MAT_i ) 'NOMC' 'SCAL');
ETA2 = CHAN CHPO MOD_i (('EXCO' 'ETA2'  MAT_i ) 'NOMC' 'SCAL');
NUPO = CHAN CHPO MOD_i (('EXCO' 'NUPO'  MAT_i ) 'NOMC' 'SCAL');
AFLU = CHAN CHPO MOD_i (('EXCO' 'AFLU'  MAT_i ) 'NOMC' 'SCAL');
XFDE = CHAN CHPO MOD_i (('EXCO' 'XFDE'  MAT_i ) 'NOMC' 'SCAL');
***************************************
*
*** CREEP CELL NUMBER 1
*EXP(ESPONENTE*(LOG(ARGOMENTO))
EKV1_1  = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR1))**(-1.)) *
          (EXP(AFLU*(LOG(MATUR1)))));
EKV1_2  = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR2))**(-1.)) *
          (EXP(AFLU*(LOG(MATUR2)))));
EKV1_moy  = (EKV1 * 0.473 * ((2.081 - (1.608 * MATUR))**(-1.)) *
          (EXP(AFLU*(LOG(MATUR)))));
*
NUPO_mod = NUPO ;
*
DEKV1 = (EKV1_2 - EKV1_1) * (1./dt);
DEKV1 = 'BORNER'  DEKV1 'SCAL' 'MINIMUM' 0.;
OMEGA = 1. + (DEKV1 * TKV1 * (EKV1_moy ** (-1.)));
TEMP1 = (EKV1_moy * TKV1) - (0.5 * EKV1_moy * OMEGA * DT);
TEMP2 = (EKV1_moy * TKV1) + (0.5 * EKV1_moy * OMEGA * DT);
DENOM = TEMP2 ** (-1.);
DEPS1 = MCR1 ;
3D_CO = (1. - (2. * NUPO_mod));
DEPS2 = ((TEMP1 * DEPS1) + (D_APS * 3D_CO)) * DENOM;
CELL1 = (0.5 * (DEPS1 + DEPS2)) * DT;
*
*** CREEP CELL NUMBER 2 (Ajouter coeff 3D)
NUMER = APS_MOY * DT;
DENOM = ETA2 ** (-1.);
CELL2 = NUMER * 3D_CO * DENOM;
*
*** CREEP CELL NUMBER 3 (DRYING CREEP) (Ajouter coeff 3D)
PC1  = (EXCO 'PC' TETA1) 'NOMC' 'SCAL';
PC2  = (EXCO 'PC' TETA2) 'NOMC' 'SCAL';
DPC  = (PC2 - PC1)  * (1./dt);
CELL3 = XFDE * DPC * 3D_CO * APS_MOY * DT;
******************************** tot
*
RET_VISC = (CELL1 + CELL2 + CELL3);
DHH_MC  = CHAN  CHAM  RET_VISC MOD_i;
DEPS2i  = CHAN  CHAM  DEPS2 MOD_i;
*
* ASSEMBLAGGIO
DHH_scai = DHH_ELA + DHH_MC;
*
* FROM 0D to 3D
MA_BID   = 'MATE' MOD_i 'YOUN' 1. 'NU' 0.3 'ALPH' 1.
                                    'TREF' 0. 'TALP' 0.;
TE_AUX   = 'MANU' CHPO MAIL_i 'T' 1.;
DHH_UNO  = 'EPTH' MOD_i MA_BID TE_AUX;
DHH_scai = PROI MOD_i DHH_scai;
DHH_scai = CHAN 'STRESSES' MOD_i DHH_scai;
DHH_RETi = DHH_scai * DHH_UNO;
*
'SI' (indz EGA 1);
    DHH_TOT = DHH_RETi;
    DE2_TOT = DEPS2i;
'SINON';
    DHH_TOT = DHH_TOT  et  DHH_RETi;
    DE2_TOT = DE2_TOT  et  DEPS2i;
'FINSI';
*
indz = indz + 2;
*
'FIN' BOUCLE_Z;
 
 
'FINP' DHH_TOT  DE2_TOT;
***********************************************************************
* FIN PROCEDURE @DEPS_HH
***********************************************************************