Télécharger la plaquette Cast3M


fr en

Télécharger @cdg.procedur

Retour à la liste

Numérotation des lignes : 

  1. * @CDG      PROCEDUR  AM        93/11/02    21:15:17     956            
  2. *-----------------------------------------------------------            
  3. ******              PROCEDURE @CDG                    ******            
  4. *-----------------------------------------------------------            
  5. *                                                                       
  6. *      CETTE PROCEDURE A ETE MISE GRACIEUSEMENT
  7. *     A DISPOSITION DE LA COMMUNAUTE  CASTEM2000
  8. *  PAR  DELERUYELLE Fr.  (SOCOTEC-INDUSTRIE à L IPSN/DES)
  9. *                                                                       
  10. *-----------------------------------------------------------            
  11. *          CALCUL DU CENTRE DE GRAVITE D UNE GEOMETRIE                  
  12. *                CONTENUE DANS UN MODELE                                
  13. *-----------------------------------------------------------            
  14. 'DEBP' @CDG MO1*'MMODEL' CA1/'MCHAML' ;                                 
  15. GEO1 = 'EXTR' MO1 'MAIL' ;                                              
  16. CHP1 = 'COOR' 1 GEO1 ;                                                  
  17. CHE1 = 'CHAN' 'CHAM' CHP1 MO1 'NOEUD' 'SCALAIRE' ;
  18. CHP2 = 'COOR' 2 GEO1 ;                                                  
  19. CHE2 = 'CHAN' 'CHAM' CHP2 MO1 'NOEUD' 'SCALAIRE' ;
  20. UN = 'MANU' 'CHML' MO1 'SCAL' 1. 'TYPE' 'SCALAIRE' 'NOEUD' ;
  21. 'SI' ('EXISTE' CA1) ;                                                   
  22.  LCOM = 'EXTR' CA1 'COMP' ;
  23.  'SI' ('EXISTE' LCOM 'RHO') ;
  24.   RH = 'CHAN' 'NOEUD' MO1 ('EXCO' 'RHO' CA1 'SCAL') ;
  25.   XSECT = 'INTG' MO1 RH CA1 ;
  26.   XCHE1 = 'INTG' MO1 (MO1 RH * CHE1) CA1 ;
  27.   XCHE2 = 'INTG' MO1 (MO1 RH * CHE2) CA1 ;
  28.  'SINON' ;
  29.   XSECT = 'INTG' MO1 UN CA1 ;
  30.   XCHE1 = 'INTG' MO1 CHE1 CA1 ;
  31.   XCHE2 = 'INTG' MO1 CHE2 CA1 ;
  32.  'FINSI' ;
  33. 'SINON' ;                                                               
  34.  XSECT = 'INTG' MO1 UN ;                                                
  35.  XCHE1 = 'INTG' MO1 CHE1 ;                                              
  36.  XCHE2 = 'INTG' MO1 CHE2 ;                                              
  37. 'FINSI' ;                                                               
  38. XG1 = XCHE1 / XSECT ;                                                   
  39. XG2 = XCHE2 / XSECT ;                                                   
  40. 'RESP' XG1 XG2 ;                                                        
  41. 'SI' ('EGA' ('VALE' 'DIME') 3) ;                                        
  42.  CHP3 = 'COOR' 3 GEO1 ;
  43.  CHE3 = 'CHAN' 'CHAM' CHP3 MO1 'NOEUD' 'SCALAIRE' ;
  44.  'SI' ('EXISTE' CA1) ;                                                  
  45.   'SI' ('EXISTE' LCOM 'RHO') ;
  46.    XCHE3 = 'INTG' MO1 (MO1 RH * CHE3) CA1 ;
  47.   'SINON' ;
  48.    XCHE3 = 'INTG' MO1 CHE3 CA1 ;
  49.   'FINSI' ;
  50.  'SINON' ;                                                              
  51.   XCHE3 = 'INTG' MO1 CHE3 ;                                             
  52.  'FINSI' ;                                                              
  53.  XG3 = XCHE3 / XSECT ;                                                  
  54.  'RESP' XG3 ;                                                           
  55. 'FINSI' ;                                                               
  56. 'FINP' ;                                                                
  57.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales