Télécharger la plaquette Cast3M


fr en

Télécharger vibr4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  vibr4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test vibr4.dgibi: jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI TRAC PSC ;
  19. FINSI ;
  20.  
  21. SAUT PAGE;
  22. ****************************************************************
  23. *                               VIBR4
  24. ****************************************************************
  25. *                                                              *
  26. *  Mots-clés : Vibrations, calcul modal, 3D                    *
  27. *                                                              *
  28. *  TEST VIBR4                                                  *
  29. *                                                              *
  30. *  CAS TEST DU 91/06/13     PROVENANCE : TEST                  *
  31. *                                                              *
  32. *  PLAQUE EPAISSE EN FORME DE LOSANGE                          *
  33. *                                                              *
  34. *  Test NAFEMS numero fv22                                     *
  35. *                                                              *
  36. *      On cherche les frequences et modes propres d'une plaque *
  37. *   en forme de losange d'un metre d'epaisseur.                *
  38. *                                                              *
  39. *      Les conditions aux limites imposees (voir dessin)sont   *
  40. *   les suivantes :                                            *
  41. *            - ux  = uy  = rz = 0 pour tout les noeuds,        *
  42. *            - uz' = rx' = ry = 0 pour les 4 cotes.            *
  43. *                                                              *
  44. *  dessin                                                      *
  45. *  ------                                                      *
  46. *                                                              *
  47. *                        axe y'                                *
  48. *                          |                                   *
  49. *                          |                                   *
  50. *                          |   axe x'                          *
  51. *                   P4      ----->                             *
  52. *                    ----------------- P3                      *
  53. *          axe y    /               /                          *
  54. *            |     /               /                           *
  55. *            |    /               /                            *
  56. *            |   /               /                             *
  57. *            |  /               /                              *
  58. *            | /               /                               *
  59. *             -----------------     ---> axe x                 *
  60. *            P1               P2                               *
  61. *                                                              *
  62. *             |_____10.m______|                                *
  63. *                                                              *
  64. *                                                              *
  65. *                                                              *
  66. ****************************************************************
  68. OPTI ELEM QUA8;
  69. *
  70. *--------------------------------------------------------------*
  71. *                  geometrie - maillage                        *
  72. *--------------------------------------------------------------*
  73. *
  74. ALPHA = 45.; COS = COS ALPHA; SIN = SIN ALPHA;
  75. *
  76. P1 =   0. 0. 0.;
  77. P2 =  10. 0. 0.;
  78. P3 = (10. * (1 + COS)) (10. * SIN) 0.;
  79. P4 = (10. * COS) (10. * SIN) 0.;
  80. *
  81. OEIL = 7. -100. 70.;
  82. *
  83. D12 = P1 DROI 6 P2;
  84. D23 = P2 DROI 6 P3;
  85. D34 = P3 DROI 6 P4;
  86. D41 = P4 DROI 6 P1;
  87. *
  88. SUR1 = DALL D12 D23 D34 D41 PLAN;
  89. *
  90. SI (NEG GRAPH 'N');
  91.   TRAC OEIL 'QUAL' SUR1;
  92. FINSI;
  93. PBARY = SUR1 POIN 'PROCH' (BARY SUR1);
  94.  
  95. *
  96. *--------------------------------------------------------------*
  97. *       MODE - materiau - caracteristique                      *
  98. *                   rigidite - masse                           *
  99. *--------------------------------------------------------------*
  100. *
  101. MOD1 = MODE SUR1 MECANIQUE COQ8;
  102. MAT1 = MATE  MOD1 YOUN 2.E11 NU 0.3 RHO 8.E3;
  103. CAR1 = CARA MOD1 EPAI 1.;
  104. MAT1 = MAT1 ET CAR1;
  105. RIG1 = RIGI MOD1 MAT1 ;
  106. MAS1 = MASS MOD1 MAT1;
  107. *
  108. *--------------------------------------------------------------*
  109. *               conditions aux limites                         *
  110. *--------------------------------------------------------------*
  111. *   - ux  = uy  = rz = 0 pour tout les noeuds,
  112. *   - uz' = rx' = ry' = 0 pour les 4 cotes.
  113.  
  114. si (faux);
  115.  
  116. CL1 = BLOQ UX SUR1;
  117. CL2 = BLOQ UY SUR1;
  118. CL3 = BLOQ RZ SUR1;
  119.  
  120. CL4 = BLOQ UZ (D12 ET D34);
  121. CL5 = BLOQ RX (D12 ET D34);
  122. CL6 = BLOQ RY (D12 ET D34);
  123.  
  124. DIR1 = COS SIN 0.; DIR2 = (-1 * SIN) COS 0.;
  125. CL7 = BLOQ UZ (D23 ET D41);
  126. CL8 = BLOQ ROTA DIRECTION DIR1 (D23 ET D41);
  127. CL9 = BLOQ ROTA DIRECTION DIR2 (D23 ET D41);
  128.  
  129. RIG1 = RIG1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5
  130.             ET CL6 ET CL7 ET CL8 ET CL9;
  131.  
  132. sinon;
  133. * CL1 = BLOQ 'UX' 'UY' 'RZ' SUR1;
  134. CL1 = BLOQ 'UX' 'UY' SUR1;
  135. CL2 = BLOQ 'UZ' 'RX' 'RY' (D12 ET D23 ET D34 ET D41);
  136.  
  137. RIG1 = RIG1 ET CL1 ET CL2 ;
  138.  
  139. finsi;
  140. *
  141. *--------------------------------------------------------------*
  142. *           calcul des frequences propres                      *
  143. *--------------------------------------------------------------*
  144. *
  145. * table des frequence propres theoriques
  146. FRE1 = TABLE;
  147. FRE1.1 = 133.95;
  148. FRE1.2 = 201.41;
  149. FRE1.3 = 265.81;
  150. FRE1.4 = 282.74;
  151. FRE1.5 = 334.45;
  152. FRE1.6 = 386.62;
  153.  
  154. * Utilisation de l'operateur VIBR avec l'option PROCH
  155. * + listreel de 6 valeurs :
  156. * 6 repetitions de la methode de la puissance inverse avec 6 decalage
  157. * spectral
  158. LIST1  = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 FRE1.5 FRE1.6;
  159. RESUL2 = VIBR PROC LIST1 RIG1 MAS1;
  160. * RESUL2 = VIBR PROC (prog 100.) (lect 6) RIG1 MAS1;
  161.  
  162. * Utilisation de l'operateur VIBR avec l'option IRAM :
  163. *  opti impi 5;
  164. RESUL3 = VIBR IRAM 100. 6 RIG1 MAS1;
  165. *  opti impi 0;
  166.  
  167. *
  168. *--------------------------------------------------------------*
  169. *               extraction des resultats ...                   *
  170. *--------------------------------------------------------------*
  171. *
  172. *... via la procedure explorer :
  173. *
  174.   toto = TABL;
  175.   toto . 'MAILLAGE' = SUR1;
  176.   toto . 'MAILLAGE_VECTEUR' = PBARY;
  177. * * +en interactif
  178. *   OPTI TRAC X ;
  179. * EXPLORER RESUL3 (mots 'TABL' 'DEF0' 'DEFO') toto;
  180. * +en ps
  181.   OPTI TRAC PSC ;
  182.   EXPLORER RESUL3 (mots 'TABL' 'DEF0' 'DEFO') toto;
  183. *
  184. *... a la main :
  185. *
  186. FRE3 = TABLE; ERG3 = TABLE;
  187. FRE2 = TABLE; ERG2 = TABLE;
  188. DEP  = TABLE; DEF = TABLE;
  189.  
  190. OPTI ECHO 0;
  191. MESS ' RESULTATS ';
  192. MESS ' ----------------------------------------------------------';
  193. MESS '      |    Frequence propre en Hz (erreur relative en %) ';
  194. MESS ' Mode |  Theorie |    VIBR PROCH     |    VIBR IRAM      ';
  195. MESS ' ----------------------------------------------------------';
  196. I = 0;
  197. REPETER BLOC1 6;
  198.    I = I + 1;
  199.    FRE2.I = RESUL2 . MODES . I . FREQUENCE;
  200.    ERG2.I = 100 * (ABS ((FRE2.I - FRE1.I) / FRE1.I));
  201.    FRE3.I = RESUL3 . MODES . I . FREQUENCE;
  202.    ERG3.I = 100 * (ABS ((FRE3.I - FRE1.I) / FRE1.I));
  203.    chacha = chai I *5 ' |' FORMAT '(F9.3)' FRE1.I
  204.           ' |' FORMAT '(F9.3)' FRE2.I ' (' FORMAT '(F5.3)' ERG2.I '%)'
  205.           ' |' FORMAT '(F9.3)' FRE3.I ' (' FORMAT '(F5.3)' ERG3.I '%)';
  206.    MESS chacha;
  207.   SI (NEG GRAPH 'N');
  208.     DEP.I  = RESUL2 . MODES . I . DEFORMEE_MODALE;
  209.     DEPZ   = EXCO DEP.I 'UZ';
  210.     DEF0   = DEFO SUR1 DEP.I 0. 'NOIR';
  211.     DEF.I  = DEFO SUR1 DEP.I 1. 'BLEU';
  212.     TRAC OEIL (DEF0 ET DEF.I);
  213.     TRAC OEIL DEPZ SUR1 (DEFO SUR1 DEP.I 0.5 NOIR);
  214.   FINSI;
  215. FIN BLOC1;
  216. MESS ' ----------------------------------------------------------';
  217. OPTI ECHO 1;
  218. *
  219. *
  220. *--------------------------------------------------------------*
  221. *                code fonctionnement                           *
  222. *--------------------------------------------------------------*
  223. *
  224. ERG2MAX = MAXI (PROG ERG2.1 ERG2.2 ERG2.3 ERG2.4 ERG2.5 ERG2.6);
  225. ERG3MAX = MAXI (PROG ERG3.1 ERG3.2 ERG3.3 ERG3.4 ERG3.5 ERG3.6);
  226.  
  227. SI (ERG2MAX > 4.5);
  228.   MESS 'ERREUR VIBR OPTION PROCHE';
  229.   ERRE 5;
  230. FINSI;
  231. SI (ERG3MAX > 4.5);
  232.   MESS 'ERREUR VIBR OPTION IRAM';
  233.   ERRE 5;
  234. FINSI;
  235.   ERRE 0;
  236.  
  238.  
  239. FIN;
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales