Télécharger la plaquette Cast3M


fr en

Télécharger vibr14_fourier.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : vibr14_fourier.dgibi
  2. *
  3. ************************************************************************
  4. ************************************************************************
  5. *
  6. *                        VIBR14_FOURIER.dgibi
  7. *
  8. * Objectif  : Calcul des modes propres d'un tube mince orthotrope 
  9. *             axisymetrique encastre - encastre 
  10. * Elements  : coque mince COQ2, et massif QUA8
  11. * Creation  : BP, 2017-03-01
  12. * Reference : Intercomparaison avec modele 3D CAST3M (vibr14_3d)
  13. *
  14. ************************************************************************
  15. *
  16. * DIMENSION dans le plan (XOY)
  17. * 
  18. *              solide
  19. *      Y                                    
  20. *  Y=L | . . . D __ B                         
  21. *      |        |  |                        
  22. *      |        |  |                        
  23. *      |        |  |                        
  24. *      |        |  |                        
  25. *      |        |  |                        
  26. *      |        |  |                        
  27. *      |        |  |                        
  28. *      | . . .  |__|   -----> X       
  29. *      O       C    A                 
  30. *             R=Ri R=Re
  31. *
  32. *               |  |
  33. *               <-->
  34. *                 t
  35. *
  36. * la coque mince est definie sur Rmoy=(Re+Ri)/2
  37. *
  38. *
  39. * ORTHOTROPIE dans le plan (Y,Theta)
  40. *            
  41. *                    Y
  42. *                     |
  43. *            V2  beta |
  44. *               \     |
  45. *                \    |
  46. *                 \   |
  47. *                  \  |
  48. *                   \ |
  49. *                    \|
  50. *       Z-------------+X
  51. *
  52. ************************************************************************
  53.  
  54. GRAPH = FAUX ;
  55. * GRAPH = VRAI ; OPTI TRAC PSC POTR HELVETICA_16 EPTR 5;
  56.  
  57. ************************************************************************
  58. * OPTIONS ET DONNEES
  59. ************************************************************************
  60.  
  61. * options   
  62.   typEF = mot 'QUA8';
  63.   OPTI DIME 2 MODE FOUR NOHA ELEM typEF;
  64.  
  65.  
  66. * geometrie 
  67.   L = 0.3048;
  68.   t = 0.254E-3;
  69.   Re = 0.0762;
  70.   Ri = Re - t;
  71.   Rmoy = 0.5 * (Ri + Re);
  72.  
  73. * nz et nR = nombre d elements selon Z et R 
  74.    nz    = 20;  nR    = 1;
  75.  
  76. * materiau
  77.   Eyl  = 206.E9;
  78.   nult = 0.3;
  79.   rho1 = 7850.;
  80.   Eyt  = Eyl / 10.;
  81.   Glt  = Eyt / (2. * (1. + nult));
  82.   Gtt  = Glt;
  83.   nutt = 0.3;
  84.   nutl = nult * Eyt / Eyl;
  85.   mess Eyl Eyt Glt Gtt nutt;
  86.   beta=30.;
  87.  
  88. * nombre de modes calcules
  89.   nmod = 2;
  90.  
  91.  
  92. ************************************************************************
  93. * MAILLAGE
  94. ************************************************************************
  95.  
  96.   p0   = 0. 0. ;
  97.   vaxe = 0. 1. ;
  98.   vx = 1. 0. ;
  99.  
  100. * maillage solide  
  101.   p1i = Ri 0. ;
  102.   p1e = Re 0. ;
  103.   p2i = Ri L  ; 
  104.   p2e = Re L  ;
  105.   d1  = p1i droi nR p1e;
  106.   d2  = p2i droi nR p2e;
  107.  
  108.   mesh8 = REGL d1 nZ d2 ;
  109.  
  110. * maillage coq2
  111.   OPTI ELEM SEG2;
  112.   p1 = Rmoy 0.;
  113.   p2 = Rmoy L;
  114.   mesh2 = p1 droi nZ p2;
  115.  
  116.  
  117. ************************************************************************
  118. * MODELEs
  119. ************************************************************************
  120.  
  121.   mod2 = MODE mesh2 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'COQ2'
  122.                     'CONS' 'couche 1';
  123.   mod8 = MODE mesh8 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE';
  124.  
  125. *=======================================================================
  126. *===> BOUCLE SUR LES HARMONIQUES DE FOURIER
  127. *=======================================================================
  128. nHlect = lect 3 4 5 6 7 8 9 10;
  129. nnH = DIME nHlect;
  130.  
  131. w2vibr = prog;
  132. w8vibr = prog;
  133. * tables pour FOUR2TRI
  134. TFOU2 = TABL; 
  135. TFOU2 . 'MODELE' = mod2;
  136. TFOU8 = TABL; 
  137. TFOU8 . 'MODELE' = mod8;
  138.  
  139. REPE BnH nnH;
  140.  
  141.   nH = extr nHlect &BnH;
  142.   MESS ' ';
  143.   MESS '______________________________________________'; 
  144.   MESS ' ';
  145.   MESS '>>>>>>>>>>>>>>>>  nH=' nH '<<<<<<<<<<<<<<<<<<<';  
  146.   MESS '______________________________________________';  
  147.   MESS ' ';
  148.   OPTI MODE FOUR nH;
  149.  
  150.   MESS '==================== \b=' beta '====================';  
  151.   TITRE (chai '\b =' (enti beta) '° - n_{H}='nH);
  152.  
  153.  
  154.  
  155. ************************************************************************
  156. * MATERIAUx
  157. ************************************************************************
  158.  
  159.   mat2 = MATE mod2 'YG1' Eyl 'YG2' Eyt 'NU12' nult 'G12' Glt
  160.                    'RHO' rho1 'EPAI' t
  161.                    'DIRE' vaxe 'INCL' beta ;
  162.  
  163.   mat8 = MATE mod8 'YG1'  Eyt  'YG2'  Eyl  'YG3'  Eyt 
  164.                    'NU12' nutl 'NU13' nutt 'NU23' nult
  165.                    'G12'  Glt  'G13'  Gtt  'G23'  Glt
  166.                    'RHO'  rho1 'DIRE' vx 'INCL' 0. beta;
  167.  
  168. * verification graphique de l'orientation des fibres
  169.   v2 = chan (VLOC mod2 mat2) 'GRAVITE' mod2;  
  170.   v8 = chan (VLOC mod8 mat8) 'GRAVITE' mod8;  
  171.  
  172.   SI GRAPH;
  173.     xv2 = 0.1 / nZ;
  174.     vv2 = vect v2 xv2 mod2 (mots V1R V1Z V2R V2Z V3R V3Z)
  175.                       (mots 'BLEU' 'BRON' 'ROUG');
  176.     TRAC vv2 mesh2  ;
  177.     vv8 = vect v8 xv2 mod8 (mots V1R V1Z V2R V2Z V3R V3Z)
  178.                       (mots 'BLEU' 'BRON' 'ROUG');
  179.     TRAC vv8 mesh8  ;
  180.   FINSI;
  181.  
  182.  
  183. ************************************************************************
  184. * MATRICES
  185. ************************************************************************
  186.  
  187. * solide :
  188.   cl1  = BLOQ 'DEPL'  d1;
  189.   cl2y = BLOQ 'UZ' d2;
  190.   cl2  = BLOQ 'UR' 'UT' d2;
  191.   cl_8 = cl1 et cl2 et cl2y;
  192.   K8 = RIGI mod8 mat8;
  193.   M8 = MASS mod8 mat8;
  194.   Ktot8 = K8 et cl_8;
  195.  
  196. * coque :
  197.   cl1  = BLOQ 'DEPL'  p1;
  198.   cl2y = BLOQ 'UZ'    p2;
  199.   cl2  = BLOQ 'UR' 'UT' p2;
  200.   cl_2 = cl1 et cl2 et cl2y;
  201.   K2 = RIGI mod2 mat2;
  202.   M2 = MASS mod2 mat2;
  203.   Ktot2 = K2 et cl_2;
  204.  
  205.  
  206. ************************************************************************
  207. * ANALYSE MODALE
  208. ************************************************************************
  209.   NMOD = 2;
  210.   TMOD_2 = VIBR 'IRAM' 100. NMOD  Ktot2 M2 ;
  211.   TMOD_8 = VIBR 'IRAM' 100. NMOD  Ktot8 M8 ;
  212.  
  213. * stockage  
  214.   w2vibr = w2vibr et (TMOD_2 . 'MODES' . 1 . 'FREQUENCE');
  215.   w8vibr = w8vibr et (TMOD_8 . 'MODES' . 1 . 'FREQUENCE'); 
  216.  
  217. * en prevision de FOUR2TRI
  218.   INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  219.   TFOU2 . INDICE_NH = TABL;
  220.   TFOU8 . INDICE_NH = TABL;
  221.   REPE BB NMOD;
  222.     TFOU2 . INDICE_NH . &BB = TMOD_2 . 'MODES' . &BB . 'DEFORMEE_MODALE';
  223.     TFOU8 . INDICE_NH . &BB = TMOD_8 . 'MODES' . &BB . 'DEFORMEE_MODALE';
  224.   FIN BB;
  225.  
  226. FIN BnH;
  227. *=======================================================================
  228.  
  229.  
  230. ************************************************************************
  231. * post-traitement FOUR2TRI 
  232. ************************************************************************
  233.  
  234. * on monte jusqu'a l'harmonique 10 -> besoin de finesse circonferentielle
  235.   prteta = prog 0. PAS 3. 360.;
  236.   TFOU2 . 'ANGLES' = prteta;
  237.   TFOU8 . 'ANGLES' = prteta;
  238.  
  239. * --- coque ---  
  240.  
  241. * creation du maillage 3D
  242.   OPTI 'MODE' 'FOUR' 'NOHA';
  243.   FOUR2TRI TFOU2 ;
  244.   mesh2_3d = TFOU2 . 'MAILLAGE_3D';
  245.   list TFOU2 2;
  246.   SI GRAPH; TRAC mesh2_3d TITRE 'maillage 3D coque issu de FOUR2TRI'; FINSI;
  247.  
  248. * creation des deformees modales 3D  
  249.   REPE BnH nnH;
  250.  
  251.     nH = extr nHlect &BnH;
  252.     TITRE (chai 'Modes - n_{H}='nH);
  253.     INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  254.     TFOU2 . 'DEPLACEMENTS' = TFOU2 . INDICE_NH;
  255.     FOUR2TRI TFOU2 nH ;
  256.  
  257.     SI GRAPH;
  258.       TMOD_2 . 'MODES' . 'MAILLAGE' = mesh2_3d;
  259.       REPE BB NMOD;
  260.         TMOD_2 . 'MODES' . &BB . 'DEFORMEE_MODALE' 
  261.         = TFOU2 . 'DEPLACEMENTS_3D' . &BB;
  262.       FIN BB;   
  263.       POSTVIBR TMOD_2;
  264.     FINSI;
  265.   FIN BnH;
  266.  
  267. * --- massif ---  
  268.  
  269. * creation du maillage 3D
  270.   OPTI 'MODE' 'FOUR' 'NOHA';
  271.   FOUR2TRI TFOU8 ;
  272.   mesh8_3d = TFOU8 . 'MAILLAGE_3D';
  273.   list TFOU8 2;
  274.   SI GRAPH; TRAC mesh8_3d TITRE 'maillage 3D massif issu de FOUR2TRI'; FINSI;
  275.  
  276. * creation des deformees modales 3D  
  277.   REPE BnH nnH;
  278.  
  279.     nH = extr nHlect &BnH;
  280.     TITRE (chai 'Modes - n_{H}='nH);
  281.     INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  282.     TFOU8 . 'DEPLACEMENTS' = TFOU8 . INDICE_NH;
  283.     FOUR2TRI  TFOU8 nH ;
  284.  
  285.     SI GRAPH;
  286.       TMOD_8 . 'MODES' . 'MAILLAGE' = mesh8_3d;
  287.       REPE BB NMOD;
  288.         TMOD_8 . 'MODES' . &BB . 'DEFORMEE_MODALE' 
  289.         = TFOU8 . 'DEPLACEMENTS_3D' . &BB;
  290.       FIN BB;   
  291.       POSTVIBR TMOD_8;
  292.     FINSI;
  293.  
  294.   FIN BnH;
  295.  
  296.  
  297. ************************************************************************
  298. * TEST DE BON FONCTIONNEMENT
  299. ************************************************************************
  300. * REM :  On teste que les harmoniques de Fourier sont 6, 7, 5 et 8.
  301. nHref = lect 6 7 5 8;
  302.  
  303. w_2 nHjj_2 = ORDO w2vibr nHlect;
  304. list nHjj_2;
  305. list w_2;
  306.  
  307. w_8 nHjj_8 = ORDO w8vibr nHlect;
  308. list nHjj_8;
  309. list w_8;
  310.  
  311. * on ne teste que les 4 premiers modes
  312. nHdiff_2 = (extr nHjj_2 (lect 1 2 3 4)) - nHref;
  313. nHdiff_8 = (extr nHjj_8 (lect 1 2 3 4)) - nHref;
  314.  
  315. SI ( ((MAXI nHdiff_2 'ABS') >EG 1) 
  316.   OU ((MAXI nHdiff_8 'ABS') >EG 1) );
  317.   ERRE 5;
  318. SINON; 
  319.   ERRE 0;
  320. FINSI;
  321.  
  322. TEMP 'IMPR' 'MAXI' 'HORL' ;
  323.  
  324. FIN ;
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales