Télécharger la plaquette Cast3M


fr en

Télécharger ther2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  ther2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************
  6. *    Test ther2.dgibi: jeux de données    *
  7. *    ---------------------------------    *
  8. *******************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI ECHO 1   ;
  19.   OPTI TRAC PSC   ;
  20. SINO ;
  21.   OPTI ECHO 0   ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *-----------------------------------------*
  26. *                  THER2                  *
  27. *                                         *
  28. *        TEST DES CL DE TEMPERATURE       *
  29. *          EN MODE AXISYMETRIQUE          *
  30. * ----------------------------------------*
  31. *                                         *
  32. *    TEMPERATURE IMPOSEE + CONVECTION     *
  33. *                        + FLUX           *
  34. *                        + SOURCE         *
  35. *                                         *
  36. *                                         *
  37. * Comme dans le test THER1, cet exemple   *
  38. * permet de tester les conditions aux     *
  39. * limites de température en calcul        *
  40. * axisymétrique.                          *
  41. *                                         *
  42. * Trois cas sont envisagés ici :          *
  43. *      - un tube épais soumis à une       *
  44. *        température imposée et à un      *
  45. *        flux imposé                      *
  46. *      - un tube épais soumis à une       *
  47. *        température imposée et à une     *
  48. *        source volumique de chaleur      *
  49. *      - un tube épais soumis à une       *
  50. *        température imposée et à une     *
  51. *        convection forcée                *
  52. *-----------------------------------------*
  53. *
  54. *--- 1er problème
  55. *    ------------
  56. *
  57. *---  Description :
  58. *
  59. *     établir le champ de température dans
  60. *     un tube épais soumis à une condition
  61. *     de température imposée et à un flux
  62. *     imposé
  63. *                     -----------
  64. *---  Description de la géométrie :
  65. *
  66. *  |  axe de symétrie
  67. *  .
  68. *  |    _________________________
  69. *  .   |                         |
  70. *  .   |                         |
  71. *  .   |                         |
  72. *  .   |                         |
  73. *  .   |                         |
  74. *  .   |                         |
  75. *  |   |         K=130.          |
  76. *  .   |_________________________|
  77. *  |   TI=0.57                   F=0.72
  78. *      RI=0.0515                 RE=0.2015
  79. *
  80. *---  Commentaires :
  81. *
  82. *  le problème est à symétrie de révolution
  83. *  température imposée sur la paroi interne
  84. *   (TI=0.57)
  85. *  flux imposé sur la paroi externe 
  86. *   (F=0.72)
  87. *  conductibilité isotrope 
  88. *   (K=130)
  89. *
  90. *---  Solution analytique :
  91. *
  92. *     T(R) = TI + LOG(R/RI) * (F * RE)/K
  93. *     Le test est réalisé en T(R=Re)
  94. *
  95. *------------------------------------------
  96.  
  97. TITR 'THER2 - C.L. TEMPERATURE -  CALCUL AXISYMETRIQUE';
  98. OPTI DIME 2 ELEM QUA4 MODE AXIS ;
  99. TEMPS ;
  100.  
  101. *---  CREATION DE LA GEOMETRIE:
  102. P1  = 0.0515 0.  ;P20 = 0.0665 0.  ;
  103. P19 = 0.0665 0.5 ;P2  = 0.0515 0.5 ;
  104. P18 = 0.0815 0.  ;P17 = 0.0815 0.5 ;
  105. P16 = 0.0965 0.  ;P15 = 0.0965 0.5 ;
  106. P14 = 0.1115 0.  ;P13 = 0.1115 0.5 ;
  107. P12 = 0.1265 0.  ;P11 = 0.1265 0.5 ;
  108. P10 = 0.1415 0.  ;P9  = 0.1415 0.5 ;
  109. P8  = 0.1565 0.  ;P7  = 0.1565 0.5 ;
  110. P6  = 0.1715 0.  ;P5  = 0.1715 0.5 ;
  111. P24 = 0.1865 0.  ;P23 = 0.1865 0.5 ;
  112. P4  = 0.2015 0.5 ;P3  = 0.2015 0.  ;
  113.  
  114. SURF1  = MANUEL QUA4 P1 P20 P19 P2 ;
  115. SURF2  = MANUEL QUA4 P20 P18 P17 P19 ;
  116. SURF3  = MANUEL QUA4 P18 P16 P15 P17 ;
  117. SURF4  = MANUEL QUA4 P16 P14 P13 P15 ;
  118. SURF5  = MANUEL QUA4 P14 P12 P11 P13 ;
  119. SURF6  = MANUEL QUA4 P12 P10 P9 P11 ;
  120. SURF7  = MANUEL QUA4 P10 P8 P7 P9 ;
  121. SURF8  = MANUEL QUA4 P8 P6 P5 P7 ;
  122. SURF9  = MANUEL QUA4 P6 P24 P23 P5 ;
  123. SURF10 = MANUEL QUA4 P24 P3 P4 P23 ;
  124. SURF11 = SURF1 ET SURF2 ET SURF3 ET SURF4 ET SURF5 ET SURF6 ET SURF7 ET SURF8 ET SURF9 ET SURF10;
  125.  
  126. D1 = DROITE 1 P1 P2 ;
  127. D3 = DROITE 1 P3 P4 ;
  128.  
  129. *---  DONNEES DU PROBLEME DE THERMIQUE:
  130.  
  131. *---  MODELISATION:
  132. MOD1 = MODE SURF11 THERMIQUE ISOTROPE ;
  133.  
  134. *---  CARACTERISTIQUES DU MATERIAU:
  135. KC = 130. ;
  136. MAT1 = MATE MOD1 K KC ;
  137.  
  138. *---  MATRICE DE CONDUCTIVITE:
  139. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  140.  
  141. *---  TEMPERATURES IMPOSEES: BLOQUE + DEPI
  142. B1 = BLOQUE T D1 ;
  143. TI = 0.57 ;
  144. E1 = DEPI B1 TI ;
  145.  
  146. *---  FLUX IMPOSE:
  147. F = 0.72;
  148. F1 = FLUX MOD1 F D3 ;
  149.  
  150. *---  ASSEMBLAGE: 
  151. RIG1 = CND1 ET B1 ;
  152. FF1  = E1   ET F1 ;
  153.  
  154. *---  RESOLUTION:
  155. CHTER1 = RESO RIG1 FF1 ;
  156. TETA1  = EXTR CHTER1 T P3  ;
  157.  
  158. SI(NEG GRAPH 'N');
  159.     TRAC 'QUAL' SURF11 ;
  160.     TRAC CHTER1 SURF11 ;
  161. FINSI;
  162.  
  163. *--- TEST DE NON REGRESSION:
  164. R  = COOR 1 P3;
  165. RI = COOR 1 P1;
  166. RE = COOR 1 P4;
  167.  
  168. TREF1 = TI +((LOG (R/RI)) * (F * RE) / KC);
  169.  
  170. RESI1=100. * (ABS((TETA1-TREF1)/TREF1));
  171.  
  172. MESS 'Temperature theorique :' TREF1' C';
  173. MESS 'Temperature calculee  :' TETA1' C';
  174. MESS '    Soit un ecart de : ' RESI1 '%';
  175. RESITOT = PROG RESI1 ;
  176.  
  177. SAUTER 1 LIGNES ;
  178.  
  179. *------------------------------------------
  180. *--- 2eme problème
  181. *
  182. * établir le champ de température dans un
  183. * tube épais soumis à une condition de
  184. * température imposée ainsi qu'à une source
  185. * volumique
  186.  
  187. *---  Description de la géométrie :
  188. *
  189. *  |  Y (axe de symétrie)
  190. *  .
  191. *  |    ______________________________
  192. *  .   |                              |
  193. *  |   |            Q=20.   K=1.      |
  194. *  .    ------------------------------
  195. *  |   TI=100.                       F=0.
  196. *      RI=6.                         RE=16.
  197. *
  198. *
  199. *---  Commentaires :
  200. *
  201. * Le problème est à symétrie de révolution.
  202. * Température sur la paroi interne (TI=100)
  203. * Flux imposé sur la paroi externe (F=0)
  204. *                           ( DT / DN = 0 )
  205. *     Source volumique imposée (Q=20)
  206. *     Conductibilité isotrope  (K=1)
  207. *
  208. *--- Solution analytique :
  209. *
  210. *     T(R) = TI - (Q/4K)*(R**2-RI**2) +
  211. *            (Q*RE/2)*RE*LOG(R/RI)
  212.  
  213. *     Le test est réalisé en T(R=Re)
  214. *
  215. *------------------------------------------
  216. *
  217. *---  CREATION DE LA GEOMETRIE:
  218. *
  219. P1 = 6 0 ;
  220. P2 = 16 0 ;
  221. P3 = 16 4 ;
  222. P4 = 6 4 ;
  223. D1 = DROITE 8 P1 P2 ;
  224. D2 = DROITE 6 P2 P3 ;
  225. D3 = DROITE 9 P3 P4 ;
  226. D4 = DROITE 4 P4 P1 ;
  227. LIG1 = D1 ET D2 ET D3 ET D4 ;
  228. SURF1 = SURFACE LIG1 PLANE ;
  229.  
  230. *---  DONNEES DU PROBLEME DE THERMIQUE:
  231.  
  232. *---  MODELISATION:
  233. MOD1 = MODE SURF1 THERMIQUE ISOTROPE ;
  234.  
  235. *---  CARACTERISTIQUES DU MATERIAU:
  236. KC = 1. ;
  237. MAT1 = MATE MOD1 K KC ;
  238.  
  239. *---  MATRICE DE CONDUCTIVITE:
  240. CND1 = COND MOD1 MAT1 ;
  241.  
  242. *---  TEMPERATURES IMPOSEES: BLOQUE + DEPI
  243. B1 = BLOQUE T D4 ;
  244. TI = 100. ;
  245. E1 = DEPI B1 TI ;
  246.  
  247. *---  FLUX IMPOSE:
  248. E2 = FLUX MOD1 0. D2 ;
  249.  
  250. *---  SOURCE VOLUMIQUE:
  251. Q = 20. ;
  252. E3 = SOURCE MOD1 Q SURF1 ;
  253.  
  254. *---  ASSEMBLAGE PREMIER ET SECOND MEMBRE:
  255. RIG1 = CND1 ET B1 ;
  256. FF1  = E1   ET E2 ET E3 ;
  257.  
  258. *---  RESOLUTION:
  259. CHTER2 = RESO RIG1 FF1 ;
  260. TETA2  = EXTR CHTER2 T P3 ;
  261.  
  262. SI(NEG GRAPH 'N');
  263.     TRAC 'QUAL' SURF1 ;
  264.     TRAC CHTER2 SURF1 ;
  265. FINSI;
  266.  
  267. *--- TEST DE NON REGRESSION:
  268. R  = COOR 1 P3;
  269. RI = COOR 1 P1;
  270. RE = COOR 1 P3;
  271.  
  272. C1 = Q * (RE**2)/(2*KC);
  273. TREF2=TI + ((Q /(2*KC)) * ((((RI**2) - (RE**2))/2) + ((RE**2) * (LOG (RE/RI))) )) ;
  274.  
  275.  
  276. RESI2=100. * (ABS((TETA2-TREF2)/TREF2));
  277.  
  278. MESS 'Temperature theorique :' TREF2' C';
  279. MESS 'Temperature calculee  :' TETA2' C';
  280. MESS '    Soit un ecart de : ' RESI2 '%';
  281. RESITOT = RESITOT ET (PROG RESI2) ;
  282.  
  283. SAUTER 1 LIGNES ;
  284.  
  285. *------------------------------------------
  286. *--- 3eme problème
  287. *
  288. *---  Description du problème :
  289. *
  290. *  établir le champ de température dans
  291. *  un tube épais soumis à une condition
  292. *  interne de température ainsi qu'à une
  293. *  convection sur sa paroi externe
  294. *
  295. *---  Données du problème :
  296. *
  297. *  Conductibilité isotrope du matériau 
  298. *   (K=8)
  299. *  Coefficient d'échange en convection 
  300. *   (HC=5)
  301. *  Température imposée sur la paroi 
  302. *    interne (TI=100)
  303. *  Température du milieu extérieur 
  304. *   (TE=125)
  305. *
  306. *---  Solution :
  307. *  Comparaison à la solution analytique
  308. *------------------------------------------
  309. *---  CREATION DE LA GEOMETRIE:
  310. *     - rayon intéreiur RI = 6.
  311. *     - rayon extérieur RE = 16.
  312. *     - hauteur         H  = 4.
  313. *     - surface interne : D4
  314. *     - surface externe : D2
  315.  
  316. P1 = 6 0 ;
  317. P2 = 16 0 ;
  318. P3 = 16 4 ;
  319. P4 = 6 4 ;
  320. D1 = DROITE 8 P1 P2 ;
  321. D2 = DROITE 5 P2 P3 ;
  322. D3 = DROITE 9 P3 P4 ;
  323. D4 = DROITE 6 P4 P1 ;
  324. LIG1 = D1 ET D2 ET D3 ET D4 ;
  325. SURF1 = SURF LIG1 PLANE ;
  326.  
  327. *---  DONNEES DU PROBLEME DE THERMIQUE:
  328.  
  329. *--- MODELISATION:
  330. MOD1 = MODE SURF1 THERMIQUE ISOTROPE   ;
  331. MOD2 = MODE D2    THERMIQUE CONVECTION ;
  332.  
  333. * DONNEE DES CARACTERISTIQUES DU MATERIAU:
  334. KC = 8. ;
  335. MAT1 = MATE MOD1 K KC ;
  336. HC = 5. ;
  337. MAT2 = MATE MOD2 H HC ;
  338.  
  339. *---  MATRICES DE CONDUCTIVITE:
  340. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  341. CNF1 = CONDUCTIVITE MOD2 MAT2 ;
  342.  
  343. *---  FLUX EQUIVALENTS A LA CONVECTION:
  344. TEX = 125. ;
  345. FF1 = CONVECTION MOD2 MAT2 T TEX ;
  346.  
  347. *---  TEMPERATURE IMPOSEE: BLOQUE + DEPI
  348. B1 = BLOQUE T D4 ;
  349.  
  350. TI = 100. ;
  351. E1 = DEPI B1 TI ;
  352.  
  353. *---  ASSEMBLAGE:
  354. RIG1 = CND1 ET CNF1 ET B1 ;
  355. Q1 = FF1 ET E1 ;
  356.  
  357. *---  RESOLUTION:
  358. CHTER3 = RESO RIG1 Q1 ;
  359. TETA3  = EXTR CHTER3 T P3 ;
  360.  
  361. SI(NEG GRAPH 'N');
  362.     TRAC 'QUAL' SURF1 ;
  363.     TRAC CHTER3 SURF1 ;
  364. FINSI;
  365.  
  366. *--- POST-TRAITEMENT
  367. RI = COOR 1 P1;
  368. RE = COOR 1 P3;
  369.  
  370. *Valeur Théorique de la température en RE
  371. TREF3=(TI + (HC*RE*TEX/KC*(LOG(RE/RI)))) / ( 1 + (HC*RE/KC*(LOG(RE/RI))));
  372.  
  373. RESI3=100. * (ABS((TETA3-TREF3)/TREF3));
  374.  
  375. MESS 'Temperature theorique :' TREF3' C';
  376. MESS 'Temperature calculee  :' TETA3' C';
  377. MESS '    Soit un ecart de : ' RESI3 '%';
  378. RESITOT = RESITOT ET (PROG RESI3) ;
  380.  
  381. TEMPS ;
  382. *         CODE DE FONCTIONNEMENT
  383. SI((MAXI RESITOT) <EG 0.4);
  384.    ERRE  0;
  385. SINO;
  386.    ERRE  5;
  387. FINSI;
  388. FIN;
  389.  
  390.  
  391.  
  392.  
  393.  
  394.  
  395.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales