Télécharger la plaquette Cast3M


fr en

Télécharger testICT3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  testICT3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * FICHIER GIBIANE POUR TESTER LES ELEMENTS
  6. * INCOMPRESSIBLES ICT3
  7. *
  8. * Maillage d'une plaque de forme carrée avec les éléments ICT3.
  9. * 
  10. * Cas déformation plane.
  11. *
  12. * On soumet la plaque à un champ de contrainte hydrostatique
  13. * (contribution: alpha=1) et à un champ de contrainte déviatorique
  14. * (contribution: beta=0.001).
  15. * 
  16. * Les résultats théoriques sont déterminés dans le cas incompressible
  17. * (coefficient de Poisson proche de 0.5).
  18. *
  19. *
  20. *
  21. *
  22. *-----MAILLAGE-----------
  23. *
  24. opti dime 2 mode plan defo elem tri3 ;
  25. *
  26. p1 = 0. 0. ;
  27. p2 = 100. 0. ;
  28. p3 = 100. 100. ;
  29. p4 = 0. 100. ;
  30. *
  31. li1 = d 10 p1 p2 ;
  32. li2 = d 10 p2 p3 ;
  33. li3 = d 10 p3 p4 ;
  34. li4 = d 10 p4 p1 ;
  35. *
  36. sur1 = dall li1 li2 li3 li4 'PLAN' ;
  37. *
  38. *
  39. *-----MODELE MECANIQUE------------
  40. *
  41. * Valeur du coefficient de Poisson
  42. *
  43. nu1 = 0.485 ;
  44. *
  45. mod1 = modele sur1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ict3 ;
  46. mat1 = mate mod1 'YOUNG' 2.e11 'NU' nu1 ;
  47. rigi1 = rigi mod1 mat1 ;
  48. *
  49. *
  50. *-----CONDITIONS AUX LIMITES------------
  51. *
  52. bl1 = bloq li1 'UY' ;
  53. bl2 = bloq li4 'UY' ;
  54. bl3 = bloq p1 'UX' ;
  55. *
  56. *
  57. *----------------CHARGEMENT-----------------
  58. *
  59. * Coefficients de contribution de chargement
  60. * (alpha-->hydrostatique)
  61. * (beta-->déviatorique)
  62. *
  63. alpha = 1. ;
  64. beta = 1.e-3 ;
  65. *
  66. *-----Chargement déviatorique------------
  67. *
  68. *-----sur li1-----
  69. *
  70. chpx1 = coor 1 li1 ;
  71. chpresy1 = pres 'MASS' mod1 (chpx1 * (-2.)*1.e5) ;
  72. chpres1 = beta * chpresy1 ;
  73. vecfor1 = vect chpres1 1.E-7 'FX' 'FY' rouge ;
  74. *
  75. *-----sur li2-----
  76. *
  77. chpy2 = coor 2 li2 ;
  78. chpresx2 = pres 'MASS' mod1 (200.*1.e5) li2 ;
  79. chpresy2 = pres 'MASS' mod1 (chpy2 * (-2.)*1.e5) ;
  80. chforx2 = chpresx2 ;
  81. chfory2 = exco 'FX' chpresy2 'FY';
  82. chpres2 = beta * ( chforx2 et chfory2 ) ;
  83. vecfor2 = vect chpres2 'FX' 'FY' 1.E-7 rouge ; 
  84. *
  85. *-----sur li3-----
  86. *
  87. chpx3 = coor 1 li3 ;
  88. chpresx3 = pres 'MASS' mod1 (-200.*1.e5) li3 ;
  89. chpresy3 = pres 'MASS' mod1 (chpx3 * (-2.)*1.e5) ;
  90. chforx3 = exco 'FY' chpresx3 'FX';
  91. chfory3 = chpresy3 ;
  92. chpres3 = beta * ( chforx3 et chfory3 ) ;
  93. vecfor3 = vect chpres3 'FX' 'FY' 1.E-7 rouge ; 
  94. *
  95. *-----sur li4-------
  96. *
  97. chpy4 = coor 2 li4 ;
  98. chpresy4 = pres 'MASS' mod1 (chpy4 * (-2.)*1.e5) ;
  99. chfory4 = exco 'FX' chpresy4 'FY';
  100. chpres4 =  beta * chfory4 ;
  101. vecfor4 = vect chpres4 1.E-7 'FX' 'FY' rouge ;
  102. *
  103. *
  104. *-----Chargement hydrostatique------------
  105. *
  106. *-----sur li1-----
  107. *
  108. presy1 = pres 'MASS' mod1 (1.e5) li1 ;
  109. pres1 = alpha * presy1 ;
  110. vfor1 = vect pres1 1.E-5 'FX' 'FY' vert ;
  111. *
  112. *-----sur li2-----
  113. *
  114. presx2 = pres 'MASS' mod1 (1.e5) li2 ;
  115. pres2 = alpha * presx2 ;
  116. vfor2 = vect pres2 'FX' 'FY' 1.E-5 vert ; 
  117. *
  118. *-----sur li3-----
  119. *
  120. presy3 = pres 'MASS' mod1 (1.e5) li3 ;
  121. pres3 = alpha * presy3 ;
  122. vfor3 = vect pres3 'FX' 'FY' 1.E-5 vert ; 
  123. *
  124. *-----sur li4-------
  125. *
  126. presx4 = pres 'MASS' mod1 (1.e5) li4 ;
  127. pres4 = alpha * presx4 ;
  128. vfor4 = vect pres4 1.E-5 'FX' 'FY' vert ;
  129. *
  130. *
  131. *---------CALCUL DES DEPLACEMENTS --------------------
  132. *
  133. *
  134. * Solution analytique au point P3: uyan.
  135. *
  136. x3 = coor 1 p3 ;
  137. y3 = coor 2 p3 ;
  138. mu = 1.e11 / ( 1 + nu1 ) ;
  139. uyan = ( 2 * x3 * y3 ) / ( 2 * mu ) * 1.e5 * beta ;
  140. *
  141. * Solution Castem au point P3: uycas.
  142. *
  143. deptot = reso (rigi1 et bl1 et bl2 et bl3)
  144. (chpres2 et chpres3 et chpres4 et chpres1 
  145. et pres2 et pres3 et pres4 et pres1) ;
  146. uycas = extr deptot 'UY' p3 ;
  147. *
  148. * Calcul de l'erreur sur le déplacement.
  149. *
  150. erry = abs (( uyan - uycas ) / ( uyan )) * 100 ;
  151. *
  152. * Test de précision sur le calcul du déplacement uy (<30%).
  153. *
  154. si ( erry >eg 30. ) ;
  155.      erreur 5 ;
  156. finsi ;
  157. *
  158. *
  159. *-----------CALCUL CONTRAINTES-------------------------
  160. *
  161. *
  162. * Solution analytique: pression = alpha*1.E5.
  163. *
  164. * Solution Castem : pression maximale = maxpres1.
  165. *
  166. sig1 = sigma mod1 deptot mat1 ;
  167. sxx = exco 'SMXX' sig1 'P' ;
  168. syy = exco 'SMYY' sig1 'P' ;
  169. szz = exco 'SMZZ' sig1 'P' ;
  170. sp = (sxx + syy + szz) / 3. ;
  171. maxpres1 = maxi sp ;
  172. *
  173. * Calcul de l'erreur sur la pression.
  174. *
  175. errpress = abs ((maxpres1 + (alpha * 1.E5)) / (alpha * 1.E5)) * 100. ;
  176. *
  177. * Test de précision sur le calcul de la pression (<20%).
  178. *
  179. si ( errpress >eg 20. ) ;
  180.      erreur 5 ;
  181. finsi ;
  182. *
  183. *
  184. fin;
  185.  
  186.  
  187.  
  188.  
  189.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales