Télécharger remplacer.dgibi

Retour à la liste

************************************************************************
*          Cas test de la directive / l'opérateur REMPlacer            *
************************************************************************
 
 
 
** Petite procédure de test d'égalité de 2 listes a et b
DEBP TEST a b ;
REPE bou (DIME a) ;
  a1 = EXTR a &bou ;
  b1 = EXTR b &bou ;
  SI (NEG a1 b1) ;
    LIST a ;
    LIST b ;
    ERRE 5 ;
  FINSI ;
FIN bou ;
FINP ;
 
 
************************************************************************
*                     D I R E C T I V E   R E M P                      *
*                        REMP obj1 ind1 obj2 ;                         *
************************************************************************
 
** Cas du LISTREEL
* remplacement d'un FLOTTANT dans un LISTREEL
obj0 = PROG 4. 8. 15. 100. 23. 42. ;
obj1 = PROG 4. 8. 15.  16. 23. 42. ;
ind1 = 4 ;
obj2 = 100. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs FLOTTANTs dans un LISTREEL
obj0 = PROG 4. 100. 15. 100. 23. 42. ;
obj1 = PROG 4.   8. 15.  16. 23. 42. ;
ind1 = LECT 2 4 ;
obj2 = 100. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs FLOTTANTs dans un LISTREEL
obj0 = PROG 4. 100. 15. 200. 300. 42. ;
obj1 = PROG 4.   8. 15.  16.  23. 42. ;
ind1 = LECT   2    4    5 ;
obj2 = PROG 100. 200. 300. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
** Cas du LISTENTI
* remplacement d'un ENTIER dans un LISTENTI
obj0 = LECT 4 8 15 100 23 42 ;
obj1 = LECT 4 8 15  16 23 42 ;
ind1 = 4 ;
obj2 = 100 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs ENTIERs dans un LISTENTI
obj0 = LECT 4 100 15 100 23 42 ;
obj1 = LECT 4   8 15  16 23 42 ;
ind1 = LECT 2 4 ;
obj2 = 100 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs ENTIERs dans un LISTENTI
obj0 = LECT 4 100 15 200 300 42 ;
obj1 = LECT 4   8 15  16  23 42 ;
ind1 = LECT   2   4   5 ;
obj2 = LECT 100 200 300 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
** Cas du LISTMOTS
* remplacement d'un MOT dans un LISTMOTS
obj0 = MOTS 'TATA' 'TETE' 'TITI' 'HOHO' 'TUTU' ;
obj1 = MOTS 'TATA' 'TETE' 'TITI' 'TOTO' 'TUTU' ;
ind1 = 4 ;
obj2 = 'HOHO' ;
REMP obj1 ind1 obj2 ;
TEST obj1 obj0 ;
* remplacement de plusieurs MOTs dans un LISTMOTS
obj0 = MOTS 'TATA' 'HOHO' 'TITI' 'HOHO' 'TUTU' ;
obj1 = MOTS 'TATA' 'TETE' 'TITI' 'TOTO' 'TUTU' ;
ind1 = LECT 2 4 ;
obj2 = 'HOHO' ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs MOTs dans un LISTMOTS
obj0 = MOTS 'TATA' 'HEHE' 'TITI' 'HOHO' 'HUHU' ;
obj1 = MOTS 'TATA' 'TETE' 'TITI' 'TOTO' 'TUTU' ;
ind1 = LECT   2   4   5 ;
obj2 = MOTS 'HEHE' 'HOHO' 'HUHU' ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
** Cas du LISTCHPO
OPTI 'DIME' 1 ;
mail = (POIN 0.) ET (POIN 1.) ET (POIN 2.) ;
chp1 = MANU 'CHPO' mail 'TATA' 1. ;
chp2 = MANU 'CHPO' mail 'TETE' 2. ;
chp3 = MANU 'CHPO' mail 'TITI' 3. ;
chp4 = MANU 'CHPO' mail 'TOTO' 4. ;
chp5 = MANU 'CHPO' mail 'TUTU' 5. ;
chp6 = MANU 'CHPO' mail 'TYTY' 6. ;
* remplacement d'un CHPOINT dans un LISTCHPO
obj0 = SUIT chp1 chp2 chp3 chp6 chp5 ;
obj1 = SUIT chp1 chp2 chp3 chp4 chp5 ;
ind1 = 4 ;
obj2 = chp6 ;
REMP obj1 ind1 obj2 ;
TEST obj1 obj0 ;
* remplacement de plusieurs CHPOINTs dans un LISTCHPO
obj0 = SUIT chp1 chp6 chp3 chp6 chp5 ;
obj1 = SUIT chp1 chp2 chp3 chp4 chp5 ;
ind1 = LECT 2 4 ;
obj2 = chp6 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs MOTs dans un LISTMOTS
obj0 = SUIT chp1 chp6 chp3 chp3 chp1 ;
obj1 = SUIT chp1 chp2 chp3 chp4 chp5 ;
ind1 = LECT 2 4 5 ;
obj2 = SUIT chp6 chp3 chp1 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
** Cas du LISTOBJE (contenant des LISTREEL)
lis1 = PROG 1. 2. 3. ;
lis2 = PROG 4. 5. 6. ;
lis3 = PROG 7. 8. 9. ;
lis4 = PROG 3. 2. 1. ;
lis5 = PROG 6. 5. 4. ;
lis6 = PROG 9. 8. 7. ;
* remplacement d'un OBJET LISTREEL dans un LISTOBJE
obj0 = ENUM lis1 lis2 lis3 lis6 lis5 ;
obj1 = ENUM lis1 lis2 lis3 lis4 lis5 ;
ind1 = 4 ;
obj2 = lis6 ;
REMP obj1 ind1 obj2 ;
TEST obj1 obj0 ;
* remplacement de plusieurs OBJETs LISTREEL dans un LISTOBJE
obj0 = ENUM lis1 lis6 lis3 lis6 lis5 ;
obj1 = ENUM lis1 lis2 lis3 lis4 lis5 ;
ind1 = LECT 2 4 ;
obj2 = lis6 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs OBJETs LISTREEL dans un LISTOBJE
obj0 = ENUM lis1 lis6 lis3 lis3 lis1 ;
obj1 = ENUM lis1 lis2 lis3 lis4 lis5 ;
ind1 = LECT 2 4 5 ;
obj2 = ENUM lis6 lis3 lis1 ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
** Cas du LISTOBJE (contenant des FLOTTANT)
* remplacement d'un FLOTTANT dans un LISTOBJE
obj0 = ENUM 4. 8. 15. 100. 23. 42. ;
obj1 = ENUM 4. 8. 15.  16. 23. 42. ;
ind1 = 4 ;
obj2 = 100. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs FLOTTANTs dans un LISTOBJE
obj0 = ENUM 4. 100. 15. 100. 23. 42. ;
obj1 = ENUM 4.   8. 15.  16. 23. 42. ;
ind1 = LECT 2 4 ;
obj2 = 100. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
* remplacement de plusieurs FLOTTANTs dans un LISTOBJE
obj0 = ENUM 4. 100. 15. 200. 300. 42. ;
obj1 = ENUM 4.   8. 15.  16.  23. 42. ;
ind1 = LECT   2    4    5 ;
obj2 = ENUM 100. 200. 300. ;
REMP obj1 ind1 obj2 ;
TEST obj0 obj1 ;
 
 
************************************************************************
*                     O P E R A T E U R   R E M P                      *
*                     mot3 = REMP mot1 ind1 mot2 ;                     *
************************************************************************
 
** Avec un mot seul
mot1 = 'J''aime la galette, savez-vous comment ?' ;
ind1 = 'galette' ;
mot2 = 'limonade' ;
mot3 = REMP mot1 ind1 mot2 ;
SI (NEG mot3 'J''aime la limonade, savez-vous comment ?')
  ERRE 5 ;
FINSI ;
 
 
** Avec un LISTMOTS
ind1 = MOTS 'galette' 'comment' ;
mot2 = MOTS 'limonade' 'pourquoi' ;
mot3 = REMP mot1 ind1 mot2 ;
SI (NEG mot3 'J''aime la limonade, savez-vous pourquoi ?')
  LIST mot3 ;
  ERRE 5 ;
FINSI ;
 
 
 
FIN ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales