Télécharger la plaquette Cast3M


fr en

Télécharger relaunil.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  relaunil.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * test de trois poutres parralleles encastrées a une extremite
  5. * ayant des relations de contact unilaterales avec jeux
  6. *
  7. *                      P |                     
  8. *      |________________\|/_________________________
  9. *      |        |                 |                 |
  10. *      |     jeu 1               jeu 2            jeu 3
  11. *      |________|________________ |_________________|
  12. *      |        |                 |
  13. *      |     jeu 4               jeu 5 
  14. *      |________|_________________|__________________
  15. *      |                /|\
  16. *      |               P |
  17. *
  18. *
  19. *      |   10   |        20       |       20        |
  20. *
  21. *
  22. * On pince les poutres exterieures a l'aide des forces P
  23. *
  24. *   Le jeu 3 se ferme en premier puis le jeu 5 
  25. * en continuant a charger le jeu 2 se ferme  puis le 3 se rouvre
  26. * Le probleme redevient symetrique et les jeux 1 et 4 se ferment 
  27. * simultanenement
  28. *
  29.  
  30.  
  31.  
  32. opti dime 3 elem seg2 mode trid echo 0;
  33. rayon = 0.45 ;
  34. d = 2*rayon ;
  35. epais = 0.1 ;
  36. *lcontact = 
  37. *
  38. * Points...
  39. *
  40. p0 = 0. 6. 0. ;
  41. p1 = 0. 3. 0. ;
  42. p2 = 0. 0. 0. ;
  43. *
  44. p10= 10. 6. 0. ;
  45. p11= 10. 3. 0. ;
  46. p12= 10. 0. 0. ;
  47. *
  48. p30= 30. 6. 0. ;
  49. p31= 30. 3. 0. ;
  50. p32= 30. 0. 0. ;
  51. *
  52. p50= 50. 6. 0.;
  53. p51= 50. 3. 0.;
  54. p52= 50. 0. 0.;
  55. *
  56. * no of elements...
  57. *
  58. n1 = 1 ;
  59. n2 = 2 ;
  60. *
  61. li01     = p0       droite n1 p10  ;
  62. li02     = p10      droite n2 p30 ;
  63. li03     = p30      droite n2 p50 ;
  64. litot0   = li01 et li02 et li03 ;
  65. *  
  66. li11     = p1       droite n1 p11 ;
  67. li12     = p11      droite n2 p31 ;
  68. li13     = p31      droite n2 p51 ;
  69. litot1   = li11 et li12 et li13 ;
  70. *
  71. li21     = p2       droite n1 p12 ;
  72. li22     = p12      droite n2 p32 ;
  73. li23     = p32      droite n2 p52 ;
  74. litot2   = li21 et li22 et li23 ;
  75. *
  76. pf1 = litot0 poin 'PROC' (20. 6. 0.) ;
  77. pf2 = litot2 poin 'PROC' (20. 0. 0.) ; 
  78. *
  79. litot = litot0 et litot1 et litot2 ;
  80. elim 1e-05 litot ;
  81. *trac litot;
  82. *opti donn 5;
  83. *
  84. * Finite Element Model & Material...
  85. *
  86. valyoun = 1e+8 ;
  87. valnu = 0.1 ;
  88. racin3 = 3.0 ** 0.5 ;
  89. s1 = epais * 6 * rayon;
  90. iy = rayon * rayon * rayon * epais * 2.5;
  91. iz = iy; 
  92. ts = iy + iz;
  93. mess  ' section des poutres  ' s1;
  94. mess ' mmoment d inertie des poutres ' iy;
  95. *
  96. mo1 = modele litot MECANIQUE ELASTIQUE pout ; 
  97. ma1 = mate mo1 YOUN valyoun NU valnu  ;
  98. ca1 = CARA mo1 sect s1 inry iy inrz iz tors ts ;
  99. *
  100. *  Rigidite et CL ...
  101. * 
  102. ri1 = RIGI mo1 (ma1 et ca1) ;
  103. *
  104. cl1 = bloq rota depl p0 ;
  105. cl2 = bloq rota depl p1 ;
  106. cl3 = bloq rota depl p2 ;
  107. cl4 = bloq uz ry rx litot ;
  108. *
  109. rig2 = ri1 et cl1 et cl2 et cl3 et cl4 ;
  110. *
  111. * Contact Relation....
  112. *
  113. map10 = manu POI1 p10 ;
  114. map11 = manu POI1 p11 ;
  115. map12 = manu POI1 p12 ;
  116. map30 = manu POI1 p30 ;
  117. map31 = manu POI1 p31 ;
  118. map32 = manu POI1 p32 ;
  119. map50 = manu POI1 p50 ;
  120. map51 = manu POI1 p51 ;
  121. *
  122. rela1   = rela 'MINI' 1.0  UY map10 - 1.0 UY map11 ;
  123. fodepi1 = depi rela1 -0.01 ;
  124. *
  125. rela2   = rela 'MINI' 1.0 UY map30 - 1.0 UY map31 ; 
  126. fodepi2 = depi rela2 -0.01 ;
  127. *  
  128. rela3   = rela 'MINI' 1.0 UY map50 - 1.0 UY map51 ; 
  129. fodepi3 = depi rela3 -0.01 ;
  130. *
  131. rela4   = rela 'MINI' 1.0 UY map11 - 1.0 UY map12 ; 
  132. fodepi4 = depi rela4 -0.01 ;  
  133. *
  134. rela5   = rela 'MINI' 1.0 UY map31 - 1.0 UY map32 ; 
  135. fodepi5 = depi rela5 -0.01 ;
  136. *
  137. reltot = rela1 et rela2 et rela3 et rela4 et rela5;
  138. ritot = rig2 et rela1 et rela2 et rela3 et rela4 et rela5 ;
  139. *trac ritot ;
  140. *
  141. * Loading....
  142. *
  143. fo1 = force FY -20. pf1 ;
  144. fo2 = force FY  20. pf2 ;
  145. fo3 = fo2 et fo1 ;
  146. fincre = fo3 ;
  147. fodepi = fodepi1 et fodepi2 et fodepi3 et fodepi4 et fodepi5 ;
  148. *
  149. *   test
  150. *
  151. * detest = reso rig2 fo3 ;
  152. * opti donn 5 ;
  153. *
  154. tabdepl = table ;
  155. tabre1 = table ;
  156. tabre2 = table ;
  157. tabre3 = table ;
  158. tabre4 = table ;
  159. tabre5 = table ;
  160. listr1 = prog ;
  161. listr2 = prog;
  162. listr3 = prog;
  163. listr4 = prog ;
  164. listr5 = prog ;
  165. i = 1 ;
  166. *opti donn 5;
  167. na=10;
  168. repeter surligne   na ;      
  169.       fotot = (i * fo3) et fodepi  ;
  170.       dep1 = reso ( rig2 et reltot) fotot ;
  171.       tabdepl . i = dep1 ;
  172.       mess'=================================' ;
  173.       mess 'increment ' i ;
  174. *      list dep1;
  175.       valfo1 = extr fotot FY pf1 ;
  176. *      list valfo1 ;
  177.       valfo2 = extr fotot FY pf2 ;
  178. *     list valfo2 ;
  179. *
  180.       reac1 = reac rela1 dep1 ;
  181.       tabre1 . i = reac1 ;
  182.       listr1 = listr1 et (prog (extr reac1 FY p10)) ;
  183.       reac2 = reac rela2 dep1 ;
  184.       tabre2 . i = reac2 ;
  185.       listr2 = listr2 et (prog (extr reac2 FY p30)) ;
  186.       reac3 = reac rela3 dep1 ;
  187.       tabre3 . i = reac3 ;
  188.       listr3 = listr3 et (prog (extr reac3 FY p50)) ;
  189.       reac4 = reac rela4 dep1 ;
  190.       tabre4 . i = reac4 ;
  191.       listr4 = listr4 et (prog (extr reac4 FY p11)) ;
  192.       reac5 = reac rela5 dep1 ;
  193.       tabre5 . i = reac5 ;
  194.       listr5 = listr5 et (prog (extr reac5 FY p31)) ;
  195. *
  196.       i = i + 1 ;
  197. fin surligne ;
  198. *
  199. listiter = prog 1.  pas 1. na ;
  200.  
  201. evolr1 = evol BLAN manu 'Numiter' listiter 'Reac1' listr1 ;
  202. evolr2 = evol ROUG manu 'Numiter' listiter 'Reac2' listr2 ;
  203. evolr3 = evol BLEU manu 'Numiter' listiter 'Reac3' listr3 ;
  204. evolr4 = evol JAUN manu 'Numiter' listiter 'Reac4' listr4 ;
  205. evolr5 = evol TURQ manu 'Numiter' listiter 'Reac5' listr5 ;
  206. *
  207. * les listri sont les reactions des appuis aux niveaux des 
  208. * relations unilaterales par pas de temps
  209. *list listr1;list listr2;list listr3;list listr4;list listr5;
  210. *  dess (evolr1 et evolr2 et evolr3 et evolr4 et evolr5) ;
  211. ltest = prog   6.1718       18.209       28.580  
  212. 38.950 49.321   59.691      69.548       76.821       84.094    
  213.   91.366 ;
  214. dif = ltest - listr2;
  215. poce= abs (dif / ltest);
  216. maxerr = maxi poce;
  217. *
  218. optio echo 0;
  219. mess ' **********************************************************';
  220. mess ' *                                                        *';
  221. mess ' *                                                        *';
  222. mess ' *        erreur max sur reaction au contact 2 (en %)     *';  
  223. mess ' *                                                        *';
  224. mess ' *                       ' maxerr    '                 *';
  225. mess ' *                                                        *';
  226. mess ' *                                                        *';
  227. mess ' **********************************************************';
  228. si ( maxerr > 0.01) ; erreur 5; finsi;
  229.  
  230. fin;
  231.  
  232.  
  233.  
  234.  
  235.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales