Télécharger rayoh-3D.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rayoh-3D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * *
  7. * Rayonnement thermique en milieu transparent: *
  8. * *
  9. * Test de bon fonctionnement de la procédure HRAYO permettant de *
  10. * traiter le rayonnement face à face par comparaison à une solution *
  11. * analytique en régime permanent. *
  12. * *
  13. * Calcul 3D. *
  14. * *
  15. * on considère 3 plaques parallèles rayonnantes : *
  16. * *
  17. * -------- T3,e3 milieu infini *
  18. * *
  19. * e2sup *
  20. * -------- T2 *
  21. * e2inf face à face *
  22. * *
  23. * -------- T1,e1 *
  24. * *
  25. * La température des plaques supérieure et inférieure est imposée et *
  26. * uniforme (respectivement 1000K et 2000K) et on détermine la tempéra- *
  27. * ture d'équilibre de la plaque intermédiaire. *
  28. * Le rayonnement entre les plaques 1 et 2 est modélisé par un rayonne- *
  29. * ment face à face, celui entre les plaques 2 et 3 par un rayonnement *
  30. * avec un milieu infini, le milieu infini étant representé par la *
  31. * plaque 3 non maillée. *
  32. * *
  33. * paramètre xquad vrai : éléments quadratiques *
  34. * faux : éléments linéaires *
  35. * Remarque: dans le cas quadratique, et pour le face à face chaque *
  36. * frontière doit etre un maillage simple (TRI6 uniquement *
  37. * ou QUA8 uniquement) *
  38. ************************************************************************
  39.  
  40. graph = faux ;
  41.  
  42. xquad = faux ;
  43.  
  44. si (xquad) ;
  45. option echo 0 dime 3 elem pr15 ;
  46. sinon ;
  47. option echo 0 dime 3 elem cub8 ;
  48. finsi ;
  49.  
  50. *-------------------------------
  51. * Données physiques du problème
  52. *-------------------------------
  53.  
  54. T1 = 1000. ; T3 = 2000. ;
  55. e1 = 0.1 ; e2inf = 0.6 ; e2sup = 0.3 ; e3 = 0.9 ;
  56. lamb = 2.e3 ;
  57.  
  58. *-------------------------------
  59. * Solution analytique
  60. *-------------------------------
  61.  
  62. r1 = 1. - e1 ; r2i = 1. - e2inf ;
  63. r3 = 1. - e3 ; r2s = 1. - e2sup ;
  64. alpha1= (e1*e2inf) / (1.-(r1*r2i)) ;
  65. alpha3= (e3*e2sup) / (1.-(r3*r2s)) ;
  66. M1 = T1**4. ; M3 = T3**4. ;
  67. M2 = ((alpha1*M1) + (alpha3*M3)) / (alpha1+alpha3) ;
  68. T2_ana = M2**(0.25) ;
  69.  
  70. *-------------------------------
  71. * Maillage
  72. *-------------------------------
  73.  
  74. oeil=10 10 10;
  75. p1=0 0 0 ; p2=1 0 0 ; p3=1 1 0 ; p4=0 1 0;
  76. l1=p1 d 1 p2;
  77. l2=p2 d 1 p3;
  78. l3=p3 d 1 p4;
  79. l4=p4 d 2 p1;
  80. si xquad ;
  81. * on recherche un objet simple
  82. opti elem tri6 ;
  83. s1= (l1 et l2 et l3 et l4) surf plan ;
  84. option echo 1 dime 3 elem pr15 ;
  85. sinon ;
  86. s1= (l1 et l2 et l3 et l4) surf plan ;
  87. finsi ;
  88.  
  89. n=1 ;
  90. v = 0 0 0.1 ; v1 = (-1)*v ;
  91. w = 0 0 0.001 ; w1 = (-1)*w ;
  92.  
  93.  
  94. s2inf = s1 ;
  95. s2sup = s2inf plus w ;
  96. plaq2 = s2inf volu n s2sup ;
  97.  
  98. s1sup = s2inf plus v1;
  99. s1inf = s1sup plus w1;
  100. plaq1 = s1inf volu n s1sup ;
  101.  
  102. rac12 = liai 0.1 s1sup s2inf ;
  103.  
  104. tout = plaq1 et plaq2 ;
  105.  
  106. si graph ; trac oeil tout ; finsi ;
  107.  
  108. *-------------------------------
  109. * Conduction
  110. *-------------------------------
  111.  
  112. mcd = mode tout thermique ;
  113. k = mate mcd 'K' lamb ;
  114. cnd = cond mcd k ;
  115.  
  116. *-------------------------------
  117. * Modeles de rayonnement et emissivites
  118. *-------------------------------
  119.  
  120. * face a face
  121. mr1 = mode rac12 thermique rayonnement 'FACE_A_FACE' ;
  122. emi1 = mate mr1 'EMI1' e1 'EMI2' e2inf ;
  123.  
  124. tmr = 'EXTR' mr1 'ZONE' ;
  125. mr1a = tmr. 1 ;
  126. mr1b = tmr. 3 ;
  127.  
  128. * milieu infini
  129. mr2s = mode s2sup thermique rayonnement 'INFINI' CONS 'INF1' ;
  130. emi2s= mate mr2s 'EMIS' e2sup 'E_IN' e3 ;
  131.  
  132. t3inf = manu chpo s2sup 1 'T' T3 'NATURE' 'DIFFUS' ;
  133.  
  134. *-------------------------------
  135. * Conditions aux limites
  136. *-------------------------------
  137.  
  138. c1 = bloq plaq1 'T' ;
  139. tim1 = depi c1 T1 ;
  140.  
  141. *-------------------------------
  142. * Algorithme de résolution
  143. *-------------------------------
  144.  
  145. *** Initialisation de la température ...
  146.  
  147. tp = manu chpo tout 1 'T' T3 natu 'DIFFUS';
  148. nbpsup = nbno tout ;
  149.  
  150. *** Résolution (par itérations) ...
  151.  
  152. * Coeff. de relaxation ...
  153. alfa = 0.3 ;
  154.  
  155. listemp = prog ;
  156. listres = prog ;
  157.  
  158. maxiter = 100 ;
  159. critconv = 1.e-2 ;
  160. * opti echo 1 ;
  161. REPE bloc1 ;
  162.  
  163. nbiter = &bloc1 ;
  164.  
  165. * traitement du rayonnement
  166.  
  167. * face à face (1,2)
  168.  
  169. h12a = HRAYO 'FACE_A_FACE' mr1a emi1 tp ;
  170. h12b = HRAYO 'FACE_A_FACE' mr1b emi1 tp ;
  171. h12 = h12a 'ET' h12b ;
  172. CR12 = COND MR1 H12 ;
  173.  
  174. * milieu infini (2,3)
  175.  
  176. tpt = tp 'ET' ('NOMC' t3inf 'TERA') ;
  177. h23 = HRAYO 'INFINI' mr2s emi2s tpt ;
  178. cr23 = cond mr2s h23 ;
  179. f3 = conv mr2s h23 t3inf ;
  180.  
  181. crtot= cr12 et cr23 ;
  182.  
  183. cndtot = crtot et cnd et c1 ;
  184. residu = (cndtot * tp) - f3 ;
  185. normres= ((xtx (exco 'Q' residu)) / nbpsup) ** 0.5 ;
  186. * mess ' La norme du flux résiduel = ' normres ;
  187. si((nbiter > 1) et (normres < critconv)) ;
  188. mess 'Convergence à l itération ' (nbiter-1) ;
  189. quitter bloc1 ;
  190. finsi ;
  191. si(nbiter > maxiter) ;
  192. mess 'Erreur ! Pas de convergence après ' (nbiter-1)
  193. ' itérations !' ;
  194. erre 2 ;
  195. quitter bloc1 ;
  196. finsi ;
  197. listres = listres et (prog normres) ;
  198.  
  199. * mess '---------------------------------------' ;
  200. * mess 'Itération N° ' &bloc1 ;
  201.  
  202. tt = resou cndtot (tim1 et f3) ;
  203. dt = exco 'T' (tt - tp) 'T' ;
  204. normdt = ((xtx dt) / nbpsup) ** 0.5 ;
  205. * mess ' La norme de delta t = ' normdt ;
  206.  
  207. tn = (alfa * tt) + ((1.-alfa) * tp) ;
  208. tp = tn ;
  209.  
  210.  
  211. FIN bloc1 ;
  212. * opti echo 1 ;
  213.  
  214. *-------------------------------
  215. * Post-traitement ...
  216. *-------------------------------
  217.  
  218. titre 'Champ de température final' ;
  219. si(graph) ; trac plaq2 (exco 'T' tn) ; finsi ;
  220.  
  221. Temp = exco 'T' tt 'T' ;
  222. T2 = redu plaq2 Temp ;
  223. * list T2 ;
  224.  
  225. RESI=maxi( ABS((T2 - T2_ana)/T2_ana));
  226. mess 'Solution analytique ' T2_ana ;
  227. mess 'Erreur relative ' (100*RESI) '%' ;
  228. SI (RESI &lt;EG 1E-4);
  229. ERRE 0;
  230. SINO;
  231. ERRE 5;
  232. FINSI;
  233.  
  234. fin;
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales