Télécharger la plaquette Cast3M


fr en

Télécharger rayo_abs-3D-1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rayo_abs-3D-1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. complet = faux;
  6. *
  7. *************************************************
  8. *  pour calcul complet mettre complet à : vrai;
  9. *************************************************
  10. ***********************************************************************
  11. *                                                                     *
  12. *  Rayonnement thermique en milieu absorbant dans une cavité sphérique*
  13. *  (pas de couplage avec d'autres modes de transfert d'énergie)       *
  14. *                                                                     *
  15. *  Comparaison à un calcul analytique                                 *
  16. *  Ref: Siegel&Howell Ed.3 p609-615                                   *
  17. *                                                                     *
  18. *  On evalue la puissance perdue par un gaz absorbant de température  *
  19. *  uniforme 2273K et de coefficient d'absorption 100./m contenu dans  *
  20. *  cavité de rayon 0.01m à la température uniforme de 1273K.          *
  21. *                                                                     *
  22. *  Calcul 3D                                                          *
  23. *  Remarques: le calcul des facteurs de forme n'utilise pas l'option  *
  24. *             convexe 'CONV'                                          *
  25. *             avec la densité choisie, la sphère comprend 88 éléments *
  26. *             pour avoir un meilleur calcul mettre d = 0.003          *
  27. ***********************************************************************
  28. *
  29.  option echo 0 dime 3 elem tri3 ;
  30. *option dime 3 elem tri6 ;
  31.  graph = faux ;
  32. *
  33. *       P3
  34. *       |
  35. *       O   P2    sphère de centre O
  36. *       |
  37. *       P1
  38. *
  39. *-------------------------------
  40. *   Maillage 
  41. *------------------------------- 
  42. *  
  43. R1 = 1.E-2 ;
  44. O  =  0. 0. 0. ;
  45. O1 =  0.  1.E-6  0. ;
  46. O2 =  0. -1.E-6  0. ;
  47. p1 =  0.0  0. ( -1. * R1 )  ;  
  48. p2 =  R1  0.0 0. ;  
  49. p3 = 0. 0. R1 ;
  50.  
  51. * densite uniforme
  52. si complet;
  53. d = 0.002 ;
  54. sinon;
  55. d = 0.008;
  56. finsi;
  57.  
  58. p1p2 = cerc p1 O p2 DINI d DFIN d; 
  59. p2p3 = cerc p2 O p3 DINI d DFIN d;
  60. lign1    = p1p2 et p2p3 ;
  61. lign2 = inve(SYME lign1 'DROIT' p1 p3) ;
  62. lign_int=lign1 et lign2; 
  63. elim 0.000001 lign_int ;
  64. oeil = 10. 10. 10. ;
  65.  
  66. sphe1 = surf lign_int 'SPHERIQUE' O2;
  67. sphe2 = surf lign_int 'SPHERIQUE' O1;
  68. sphe_ext = sphe1 et (inve sphe2) ; 
  69. elim 0.000001 sphe_ext ;
  70. si graph ; 
  71. trac oeil sphe_ext cache ;
  72. finsi ; 
  73.  
  74. cavite =  sphe_ext ;
  75. tout = cavite;
  76.  
  77. *------------------------------- 
  78. *  Propriétés physiques 
  79. *------------------------------- 
  80.  
  81. e_wall = 0.5 ;
  82. abso0 = -100. ; 
  83. T_wall = 1273.  ; 
  84. T_gas = 2273. ; 
  85.  
  86. *------------------------------- 
  87. *  Modèle de rayonnement 
  88. *------------------------------- 
  89.  
  90. mrt = mode sphe_ext thermique rayonnement 'CAVITE' ;
  91. e   = mate mrt 'EMIS' e_wall CABS abso0 'TABS' T_gas; 
  92.  
  93. * opti 'IMPI' 1 ;
  94.  
  95. *------------------------------- 
  96. *  Facteurs de forme et matrice de rayonnement
  97. *------------------------------- 
  98.  
  99.  fft = ffor mrt e;
  100.  chamr = raye mrt  fft    e ;
  101.  
  102. *------------------------------- 
  103. * gaz absorbant : calcul du terme R*Tg4
  104. *------------------------------- 
  105.  
  106. tg = manu chpo tout 1 'T'  T_gas natu 'DIFFUS';
  107. tg_cavi   = redu tg cavite ;
  108. tge_cavi   =  chan 'CHAM' tg_cavi   mrt 'GRAVITE' ;
  109. crg= rayn mrt  chamr tge_cavi    ;
  110. fg =  crg*tg_cavi ;
  111.  
  112. *-------------------------------  
  113. * paroi : calcul du terme R*Tw4
  114. *------------------------------- 
  115.  
  116. tp = manu chpo tout 1 'T' T_wall natu 'DIFFUS';
  117. t_cavi   = redu tp cavite ;
  118. te_cavi   =  chan 'CHAM' t_cavi   mrt 'GRAVITE' ;
  119. cr = rayn mrt  chamr te_cavi    ;
  120. fw =  cr *t_cavi ;
  121.  
  122. *-------------------------------
  123. * puissance perdue par les frontieres:
  124. *------------------------------- 
  125.  
  126. puis_n =  fw - fg ;
  127. t1 = manu chpo tout 1 'T' 1.0    natu 'DIFFUS' ;
  128. lm1 = MOTS 'Q' ;  
  129. lm2 = MOTS 'T' ;
  130. puis_t = xty puis_n t1 lm1 lm2 ;
  131.  
  132. *-------------------------------
  133. * puissance théorique perdue par les frontieres:
  134. *------------------------------- 
  135.  
  136. abso0 = -1 * abso0 ;
  137. b0 = 5.670E-8 ;
  138. EMG1 = b0 * ( T_gas ** 4. ) ;
  139. EMS1 = b0 * ( T_wall ** 4. ) ;
  140. AIRE1 = 4. * 3.1416 * R1 * R1 ;
  141. tau1 = 2. / ( ( 2. * abso0 * R1 ) ** 2. ) ;
  142. tau0 = ( 2. * abso0 * R1 ) + 1. ;
  143. tau0 = tau0 * ( 'EXP' ( -2. * abso0 * R1 ) ) ;
  144. tau1 = ( 1. - tau0 ) * tau1 ;
  145. abso1 = 1. - tau1 ;
  146. denom0 = ( 1. / e_wall ) + ( 1. / abso1 ) - 1. ;
  147. res0 = -1. * AIRE1 * ( EMG1 - EMS1 ) / denom0 ; 
  148.  
  149. *-------------------------------
  150. * puissance obtenue numériquement à la creation du test (06/96)
  151. *-------------------------------
  152. si complet;
  153. res1 = -699.76 ;
  154. erma = 10.;
  155. sinon;
  156. res1 = -510.37 ;
  157. erma = 30.;
  158. finsi;
  159.  
  160. *------------------------------- 
  161. *  Erreurs
  162. *------------------------------- 
  163.  
  164. * par rapport a la solution analytique
  165. si ( ( 'ABS' res0 ) '>' 1.E-5 ) ; 
  166.   err0 = ( 'ABS' ( res0 - puis_t ) ) / ( 'ABS' res0 ) ;
  167.   err0 = err0 * 100. ; 
  168. sinon ; 
  169.   err0 = 0. ; 
  170. finsi ; 
  171.  
  172. * par rapport à la solution numérique de référence
  173. err1 = ( 'ABS' ( res1 - puis_t ) ) / ( 'ABS' res1 ) ;
  174. err1 = err1 * 100. ; 
  175. 'MESS' ' Puissance absorbée calculée  = ' puis_t ;
  176. 'MESS' ' Puissance absorbée théorique = ' res0 ;  
  177. 'MESS' ' Erreur en pourcentage        = ' err0 ' % ' ; 
  178.  
  179. *------------------------------- 
  180. * calcul du flux rayonné au moyen de l'évaluation de la
  181. * température de rayonnement (option 2 de RAYE)
  182. *------------------------------- 
  183.  
  184.        trad = raye mrt  fft e  te_cavi 1e-7  ;
  185. *      mess 'trad ' (mini trad) (maxi trad);
  186.  
  187. * calcul du coefficient d'echange
  188.  
  189.        hrad = HRCAV  mrt e te_cavi trad ;
  190. *      mess 'hrad ' (mini hrad) (maxi hrad);
  191.  
  192.        trad_n1= chan 'CHPO' mrt trad       ;
  193.        trad_n = nomc trad_n1 'T' 'NATU' 'DIFFUS';
  194.  
  195. * pour la condition de convection
  196.        cr = cond mrt hrad;
  197.        f = conv mrt hrad trad_n;
  198.  
  199. *      flux rayonne
  200.  
  201.        fray  =  (cr * tp)- f;
  202.        fray_tot = maxi (resu fray);
  203.  
  204. *      mess ' flux par methode 2 ' fray_tot ;
  205.  
  206. *------------------------------- 
  207. *  Erreur methode 2
  208. *------------------------------- 
  209.  
  210. si ( ( 'ABS' res0 ) '>' 1.E-5 ) ; 
  211.   err2 = ( 'ABS' ( res1 - fray_tot) ) / ( 'ABS' res1 ) ;
  212.   err2 = err2 * 100. ;
  213. sinon ; 
  214.   err2 = 0. ;
  215. finsi ; 
  216. 'MESS' ' Puissance absorbée calculée methode 2  = ' fray_tot ;
  217. 'MESS' ' Puissance absorbee théorique = ' res0 ;
  218. 'MESS' ' Erreur methode 2 en pourcentage = ' err2 ' % ' ;
  219.  
  220. si (err0 '>' erma) ;
  221.  'ERRE' 5 ;
  222. finsi ; 
  223. si (( err1 '<' 1. ) et ( err2 '<' 1. ));
  224.  'ERRE' 0 ;
  225. sinon ; 
  226.  'ERRE' 5 ;
  227. finsi ; 
  228.  
  229. fin ;
  230.  
  231.  
  232.  
  233.  
  234.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales