Télécharger la plaquette Cast3M


fr en

Télécharger rayo_abs-2D-2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rayo_abs-2D-2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. complet = faux;
  6. *
  7. *************************************************
  8. *  pour calcul complet mettre complet à : vrai;
  9. *************************************************
  10. ************************************************************************
  11. *                                                                      *
  12. * Rayonnement thermique en milieu absorbant dans une cavité cylindrique*
  13. * (pas de couplage avec d'autres modes de transfet d'énergie)          *
  14. *                                                                      *
  15. * Comparaison à un calcul analytique                                   *
  16. *                                                                      *
  17. *                                                                      *
  18. * On evalue la puissance perdue par un gaz absorbant de température    *
  19. * uniforme 2273K et de coefficient d'absorption 100./m contenu dans    *
  20. * cavité de rayon 0.01m à la température uniforme de 1273K.            *
  21. *                                                                      *
  22. * Calcul 2D plan                                                       *
  23. * Remarque: le calcul des facteurs de forme n'utilise pas l'option     *
  24. *            convexe 'CONV'                                            *
  25. ************************************************************************
  26.  option echo 1 dime 2 elem qua4;
  27.  graph = faux ;
  28.  
  29. *-----------------------------------------------------
  30. * fonction de Bickley-Naylor à l'ordre 3 (normalisée)
  31. * intervenant dans le calcul du facteur de forme
  32. 'DEBPROC' BICK3   tau*'FLOTTANT';
  33.  
  34. * intervalle et nombre de points d'intégration
  35. tetat = pi/2.;
  36. nbou = 50 ;
  37. dteta = tetat / nbou;
  38.  
  39. xki1 = 0. ;
  40. repe bcl nbou ;
  41. teta = dteta * (0.5 + (&bcl-1));
  42. sinteta =   'SIN' (teta*90.*2./pi) ;
  43. zz = tau / sinteta ;
  44. zz = -1 * zz ;
  45. dki1 = ('EXP' zz)*dteta;
  46. dki1 = dki1 * sinteta *sinteta ;
  47. xki1 = xki1 + dki1;
  48. fin bcl ;
  49. * normalisation
  50. xki1 = xki1 * 4./pi   ;
  51. *  mess 'bickley xki1: ' xki1 ;
  52. 'FINPROC' xki1;
  53. *-----------------------------------------------------
  54. *
  55. *-------------------------------
  56. *   Maillage 
  57. *------------------------------- 
  58. *  
  59. R1 = 1.E-2 ; 
  60. O  =  0. 0. ;
  61. p1 =  0. ( -1. * R1 )  ;  
  62. p2 =  R1  0. ;  
  63. p3 =  0. R1 ;
  64.  
  65. si complet ;
  66.  d = 2.E-4 ;
  67. sinon;
  68.  d = 1.E-3 ;
  69. finsi;
  70.  
  71. p1p2 = cerc p1 O p2 DINI d DFIN d; 
  72. p2p3 = cerc p2 O p3 DINI d DFIN d;
  73. sphe_dro = p1p2 et p2p3 ;
  74. sphe_gau = inve (syme 'DROIT' sphe_dro p1 p3) ;
  75. cavite = sphe_dro et sphe_gau ;
  76. elim (d*1e-5) cavite ;
  77.  
  78. si graph ; 
  79. trac cavite ;
  80. finsi ; 
  81.  
  82. tout = cavite;
  83.  
  84. *------------------------------- 
  85. *  Propriétés physiques 
  86. *------------------------------- 
  87.  
  88. e_wall = 0.5 ;
  89.  abso0 = 100. ;
  90. T_wall = 1273.  ; 
  91. T_gas = 2273. ; 
  92.  
  93. tau1 = 2.*R1*abso0;
  94.  
  95. *-------------------------------
  96. * puissance théorique perdue par les frontieres:
  97. *
  98. * calcul de la solution analytique
  99. *------------------------------- 
  100.  
  101. * calcul du facteur de forme F11 du cylindre sur lui-même
  102. * intervalle et nombre de points d'intégration
  103.  
  104. betat= pi/2. ;
  105. nbeta = 50 ;
  106. dbeta = betat/nbeta;
  107.  
  108. F11 = 0. ;
  109. repe bcl1 nbeta ;
  110. beta = dbeta * (0.5 + (&bcl1-1));
  111. cosbeta = 'COS' (beta*90.*2./pi) ;
  112. tau2 = tau1 * cosbeta;
  113. Ki1 = BICK3   tau2 ;
  114. *mess ' Ki3 : ' Ki1;
  115. DF = Ki1 *cosbeta*dbeta;
  116. F11 = F11 + DF ;
  117. fin bcl1;
  118.  
  119. * facteur de forme
  120.  
  121. mess 'F11: ' F11 ;
  122. mess '1-F11: ' (1-F11) ;
  123.  
  124. * puissance échangée cylindre-milieu absorbant
  125.  
  126. b0 = 5.67e-8;
  127. EMG1 = b0 * ( T_gas ** 4. ) ;
  128. EMS1 = b0 * ( T_wall ** 4. ) ;
  129. AIRE1 = 2. *pi * R1 ;
  130. abso1 = 1. - tau1 ;
  131. *denom0 = ( 1. / e_wall ) + ( 1. / abso1 ) - 1. ;
  132. res0 = -1. * AIRE1 * ( EMG1 - EMS1 ) ;
  133. coef1 = 1. - F11 ;
  134. coef2 = 1. - ((1. - e_wall)*F11) ;
  135. coef = e_wall * coef1 /coef2 ;
  136. res0 = coef * res0 ;
  137. mess 'res0: ' res0 ;
  138.  
  139. *------------------------------- 
  140. *  Modèle de rayonnement 
  141. *------------------------------- 
  142.  
  143. mrt = mode cavite thermique   rayonnement 'CAVITE' ;
  144. e   = mate mrt 'EMIS' e_wall  CABS (-1 *abso0) 'TABS' T_gas ; 
  145.  
  146. *------------------------------- 
  147. *  Facteurs de forme et matrice de rayonnement
  148. *------------------------------- 
  149. opti impi 1; comm pour récupérer le bilan ;
  150.  fft = ffor mrt e    ;
  151. opti impi 0;
  152.  
  153.  chamr = raye mrt  fft    e ;
  154.  
  155. *------------------------------- 
  156. * gaz absorbant : calcul du terme R*Tg4
  157. *------------------------------- 
  158.  
  159. tg = manu chpo tout 1 'T'  T_gas natu 'DIFFUS';
  160. tg_cavi   = redu tg cavite ;
  161. tge_cavi   =  chan 'CHAM' tg_cavi   mrt 'GRAVITE' ;
  162. crg= rayn mrt  chamr tge_cavi    ;
  163. fg =  crg*tg_cavi ;
  164.  
  165. *-------------------------------  
  166. * paroi : calcul du terme R*Tw4
  167. *------------------------------- 
  168.  
  169. tp = manu chpo tout 1 'T' T_wall natu 'DIFFUS';
  170. t_cavi   = redu tp cavite ;
  171. te_cavi   =  chan 'CHAM' t_cavi   mrt 'GRAVITE' ;
  172. cr = rayn mrt  chamr te_cavi    ;
  173. fw =  cr *t_cavi ;
  174.  
  175. *-------------------------------
  176. * puissance perdue par les frontieres:
  177. *------------------------------- 
  178.  
  179. puis_n =  fw - fg ;
  180. t1 = manu chpo tout 1 'T' 1.0    natu 'DIFFUS' ;
  181. lm1 = MOTS 'Q' ;  
  182. lm2 = MOTS 'T' ;
  183. puis_t = xty puis_n t1 lm1 lm2 ;
  184.  
  185.  
  186. *------------------------------- 
  187. *  Erreur methode 1
  188. *------------------------------- 
  189.  
  190. si ( ( 'ABS' res0 ) '>' 1.E-5 ) ; 
  191.   err1 = ( 'ABS' ( res0 - puis_t ) ) / ( 'ABS' res0 ) ;
  192.   err1 = err1 * 100. ;
  193. sinon ; 
  194.   err1 = 0. ;
  195. finsi ; 
  196. 'MESS' ' Puissance absorbée calculée methode 1  = ' puis_t ;
  197. 'MESS' ' Puissance absorbee théorique = ' res0 ;
  198. 'MESS' ' Erreur methode 1 en pourcentage = ' err1 ' % ' ;
  199.  
  200.  
  201. *------------------------------- 
  202. * calcul du flux rayonné au moyen de l'évaluation de la
  203. * température de rayonnement (option 2 de RAYE)
  204. *------------------------------- 
  205.  
  206.        trad = raye mrt  fft e  te_cavi 1e-7  ;
  207. *      mess 'trad ' (mini trad) (maxi trad);
  208.  
  209. * calcul du coefficient d'echange
  210.  
  211.        hrad = HRCAV  mrt e te_cavi trad ;
  212. *      mess 'hrad ' (mini hrad) (maxi hrad);
  213.  
  214.        trad_n1= chan 'CHPO' mrt trad       ;
  215.        trad_n = nomc trad_n1 'T' 'NATU' 'DIFFUS';
  216.  
  217. * pour la condition de convection
  218.        cr = cond mrt hrad;
  219.        f  = conv mrt hrad trad_n;
  220.  
  221. *      flux rayonne
  222.  
  223.        fray  =  (cr * tp)- f;
  224.        fray_tot = maxi (resu fray);
  225.  
  226.        mess ' flux par methode 2 ' fray_tot ;
  227.  
  228. *------------------------------- 
  229. *  Erreur methode 2
  230. *------------------------------- 
  231.  
  232. si ( ( 'ABS' res0 ) '>' 1.E-5 ) ; 
  233.   err2 = ( 'ABS' ( res0 - fray_tot) ) / ( 'ABS' res0 ) ;
  234.   err2 = err2 * 100. ;
  235. sinon ; 
  236.   err2 = 0. ;
  237. finsi ; 
  238. 'MESS' ' Puissance absorbée calculée methode 2  = ' fray_tot ;
  239. 'MESS' ' Puissance absorbee théorique = ' res0 ;
  240. 'MESS' ' Erreur methode 2 en pourcentage = ' err2 ' % ' ;
  241.  
  242.  
  243. si (( err1 '<' .2 ) et ( err2 '<' .2 ));
  244.  'ERRE' 0 ;
  245. sinon ; 
  246.  'ERRE' 5 ;
  247. finsi ; 
  248.  
  249. fin ;
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales