Télécharger la plaquette Cast3M


fr en

Télécharger q4ri_bcn.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  q4ri_bcn.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. OPTI ECHO 1 ;
  5. ******************************************************************
  6. * TEST Q4RI     BCN
  7. * 
  8. * Verification of element Q4RI (QUA4 with 1x1 Gauss points)
  9. *
  10. * Elastic analysis of a square subjected to biaxial extension
  11. *
  12. ******************************************************************
  13. TITRE 'VERIFICATION OF ELEMENT Q4RI' ;
  14. OPTI DIME 2 ELEM QUA4 MODE PLAN DEFO ;
  15. GRAPH='N';
  16. *
  17. *------------ Geometry definition --------------------------------
  18. *
  19. pa = 0. 0. ; pb = 10. 0. ; pc = 10. 10. ; pd = 0. 10 ;
  20. lab = pa DROIT 10 pb ;lbc = pb DROIT 10 pc ;
  21. lcd = pc DROIT 10 pd ;lda = pd DROIT 10 pa ;
  22. mesh = DALLER lab lbc lcd lda ;
  23. *
  24. SI (NEG GRAPH 'N');
  25.   TRACE mesh ;
  26. FINSI ;
  27. *
  28. *------------ Model and material ---------------------------------
  29. *
  30. mod1 = MODE mesh MECANIQUE ELASTIQUE Q4RI ;
  31. mat1 = MATE mod1 YOUN 1.E7 NU 0 ;
  32. *
  33. *------------ Stiffness and boundary conditions ------------------
  34. *
  35. rig1 = RIGI mod1 mat1 ;
  36. bc_lab = BLOQ UY lab ; bc_lbc = BLOQ UX lbc ;
  37. bc_lcd = BLOQ UY lcd ; bc_lda = BLOQ UX lda ;
  38. bc_tot = bc_lab ET bc_lbc ET bc_lcd ET bc_lda ;
  39. rigtot = rig1 ET bc_tot ;
  40. *
  41. *------------ Prescribed displacements: dilatation ---------------
  42. *
  43. di_lbc = DEPI bc_lbc 0.01 ;
  44. di_lcd = DEPI bc_lcd 0.01 ;
  45. ftot = di_lbc ET di_lcd ;
  46. *
  47. *------------ Linear system --------------------------------------
  48. *
  49. desp = RESO rigtot ftot ;
  50. *=================================================================
  51. *                         Postprocess
  52. *=================================================================
  53. *
  54. * Deformed mesh
  55. *
  56. SI (NEG GRAPH 'N') ;
  57.   def0 = DEFO mesh desp 0.  BLAN ;
  58.   def1 = DEFO mesh desp 10. ROUG ;
  59.   TRACE (def0 ET def1) ;
  60. FINSI ;
  61. *
  62. * Stresses computed with SIGM 
  63. *
  64. stress1 = SIGM mod1 mat1 desp 'LINE' ;
  65. *
  66. * Stresses computed with EPSI and ELAS
  67. *
  68. strain  = EPSI mod1 desp 'LINE' ;
  69. stress2 = ELAS mod1 strain mat1 ;
  70. *
  71. * Gradient of displacements computed with GRAD
  72. *
  73. grad1 = GRAD mod1 desp ;
  74. *
  75. * Verifications
  76. ERRE 0 ;
  77. * 1) stress1 = stress2 
  78. *
  79. difstres = MAXI (stress1-stress2) ABS ;
  80. SI (difstres > 1.E-4) ; ERRE 5 ; FINSI  ;
  81. *
  82. * 2) smxx = smyy = 1.e4 , smzz = smxy = 0   
  83. *
  84. smxxmin = MINI (EXCO stress1 SMXX) ; dxxmin = ABS (smxxmin-1.E4) ;
  85. smxxmax = MAXI (EXCO stress1 SMXX) ; dxxmax = ABS (smxxmax-1.E4) ;
  86. smyymin = MINI (EXCO stress1 SMYY) ; dyymin = ABS (smyymin-1.E4) ;
  87. smyymax = MAXI (EXCO stress1 SMYY) ; dyymax = ABS (smyymax-1.E4) ;
  88. smzzmin = MINI (EXCO stress1 SMZZ) ; dzzmin = ABS smzzmin ;
  89. smzzmax = MAXI (EXCO stress1 SMZZ) ; dzzmax = ABS smzzmax ;
  90. smxymin = MINI (EXCO stress1 SMXY) ; dxymin = ABS smxymin ;
  91. smxymax = MAXI (EXCO stress1 SMXY) ; dxymax = ABS smxymax ;
  92. dif = PROG dxxmin dxxmax dyymin dyymax 
  93.            dzzmin dzzmax dxymin dxymax ;
  94. SI ( (MAXI dif ABS)> 1.E-4) ; 
  95.    ERRE 5 ; 
  96. FINSI ;
  97. FIN ;
  98.  
  99.  
  100.  
  101.  
  102.  
  103.  
  104.  
  105.  
  106.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales