Télécharger mato-3d3.dgibi

Retour à la liste

* fichier : mato-3d3.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-3D3
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un cube
*               avec une métrique isotrope constante en espace
*               dans le but d'obtenir 1x1x1 mailles.
*               Au départ, le cube est 5x5x5. Concernant la frontière,
*               on contraint le mailleur, soit à ne pas la modifier,
*               soit à en modifier une partie, soit la totalité.
*
*               On teste la qualité des éléments obtenus.
*
*               Issu de mato-2d5.dgibi
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 08/06/2026, version initiale
* HISTORIQUE : v1, 08/06/2026, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
* Mini, mediane et maxi d'un LISTREEL
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 3 'ELEM' 'CUB8' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0. 'PAS' 0.05 1. ;
ldens1 = 'PROG' 0.5 'PAS' 0.05  1. ;
ldens2 = 'PROG' 0.9 'PAS' -0.05  0.5 ;
ldens  = ldens1 'ET' (ldens2 '**' -1.) ;
*
for = '(E11.3)' ;
*
* Création du contour
*
* On met nv plus petit que 1 pour bien forcer le deraffinement
nx = 5 ; nv = 0.5 ;
pA = 0. 0. 0. ; pB = 1. 0. 0. ;
lAB  = 'DROI' nx pA pB ;
fbas = 'TRAN' lAB nx (0. 1. 0.) ;
vol  = 'VOLU' 'TRAN' fbas nx (0. 0. 1.) ;
env  = 'ENVE' vol ;
env = 'CHAN' env 'TRI3' ;
* faces x=0, y=0, z=0
x y z = 'COOR' env ;
px0  = 'POIN' x 'EGINFE' ('VALE' prec) ;
facx0 = 'ELEM' env appuye strictement px0 ;
py0  = 'POIN' y 'EGINFE' ('VALE' prec) ;
facy0 = 'ELEM' env appuye strictement py0 ;
pz0  = 'POIN' z 'EGINFE' ('VALE' prec) ;
facz0 = 'ELEM' env appuye strictement pz0 ;
fac0 = facx0 'ET' facy0 'ET' facz0 ;
fac1 = 'DIFF' env fac0 ;
*
'SI' graph ;
   tit = 'CHAI'  'Enveloppe ' ;
      envq = 'CHAN' env 'QUAF' ;
      fac0q = 'CHAN' fac0 'QUAF' ;
      fac1q = 'CHAN' fac1 'QUAF' ;
      'TRACER' 'CACH' envq  'TITR' tit ;
      'TRACER' 'CACH' ('COUL' fac0q roug) 'TITR' tit ;
      'TRACER' 'CACH' ('COUL' fac1q vert) 'TITR' tit ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage initial
*
   mail1 = 'TRIA' 'TOPO' env ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage initial genere par TRIA TOPO' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que les qualités mini, moyenne et maxi des éléments sont bonnes
qmail1 = 'INDI' 'TOPO' 'EQLT' mail1 ;
miqo meqo maqo = MIMEMA qmail1 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 1 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail1 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 1 : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail1 = 'MODE' mail1 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'EQLT' qmail1) momail1 lqual 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5
*miqar = 0.64 ; meqar = 0.82 ; maqar = 0.99 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqar = 0.62 ; meqar = 0.83 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 1 : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 1 failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Remaillage de mail1 avec une taille voulue de 0.2 sans
*         toucher le bord
*
   tparam = 'TABL' ; tparam . 'impr' = 1 ;
   mail2 = 'REMA' mail1 ('ENVE' mail1) ('/' 1. nv) tparam ;
   critqs = tparam . 'critquals_eff' ;
   critq2 = 'EXTR' critqs ('DIME' critqs) ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher le bord' ;
      'TRAC' mail2 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' 'COHE' 'DENS' mail2 ('/' 1. nv) critq2 ;
miqo meqo maqo = MIMEMA qmail2 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail2 'COHE' ;
'MESS'  'FORMAT' for 'TEST 2 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5 linux32
*miqar = 0.36 ; meqar = 0.48 ;
maqar = 0.66 ;
* 2026/06/10 nx=5 nv=0.5 linux64
miqar = 0.09 ; meqar = 0.45 ;
*maqar = 0.89 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqar = 0.11 ; meqar = 0.37 ; maqar = 0.89 ;
'MESS'  'FORMAT' for 'TEST 2 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 2 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail2 'DENS' ;
'MESS'  'FORMAT' for 'TEST 2 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail2) momail2 ldens 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5 linux32
*miqer = 0.14 ; meqer = 0.15 ; maqer = 0.16 ;
* 2026/06/10 nx=5 nv=0.5 linux64
*miqer = 0.04 ; meqer = 0.15 ; maqer = 0.33 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqer = 0.04 ; meqer = 0.11 ; maqer = 0.32 ;
'MESS'  'FORMAT' for 'TEST 2 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 2 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 3  Remaillage de mail1 avec une taille voulue de 0.2 en touchant
*         les faces x=0, y=0, z=0 mais pas les trois autres
*
   tparam = 'TABL' ; tparam . 'impr' = 1 ;
   mail3 = 'REMA' mail1 fac1 ('/' 1. nv) tparam ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher les faces x_i=0' ;
      'TRAC' mail3 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 3 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
 
qmail3 = 'INDI' 'TOPO' 'COHE' 'DENS' mail3 ('/' 1. nv) ;
miq meq maq = MIMEMA qmail3 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail3 'COHE' ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5 linux32
*miqar = 0.18 ;
meqar = 0.26 ; maqar = 0.37 ;
* 2026/06/10 nx=5 nv=0.5 linux64
miqar = 0.10 ;
*meqar = 0.34 ; maqar = 0.89 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqar = 0.11 ; meqar = 0.36 ; maqar = 0.86 ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail3 'DENS' ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail3) momail3 ldens 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5 linux32
*miqer = 0.18 ; meqer = 0.19 ; maqer = 0.20 ;
* 2026/06/08 nx=5 nv=0.5 linux64
*miqer = 0.03 ; meqer = 0.16 ; maqer = 0.35 ;
* 2026/06/08 nx=5 nv=0.5 linux32
miqer = 0.06 ; meqer = 0.14 ; maqer = 0.39 ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.03) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 3 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  Remaillage de mail1 avec une taille voulue de 0.2 en touchant
*         tout le bord
*
tparam = 'TABL' ; tparam . 'impr' = 1 ;
   mail4 = 'REMA' mail1 ('/' 1. nv) tparam ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en modifiant le bord' ;
      'TRAC' mail4 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 4 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail4 = 'INDI' 'TOPO' 'COHE' 'DENS' mail4 ('/' 1. nv) ;
miq meq maq = MIMEMA qmail4 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 4 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail4 'COHE' ;
'MESS'  'FORMAT' for 'TEST 4 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail4 = 'MODE' mail4 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail4) momail4 lqual 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5
* miqar = 0.81 ; meqar = 0.81 ; maqar = 0.81 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqar = 0.63 ; meqar = 0.77 ; maqar = 0.88 ;
'MESS'  'FORMAT' for 'TEST 4 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 4 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail4 'DENS' ;
'MESS'  'FORMAT' for 'TEST 4 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail4) momail4 ldens 'TITR' tit ;
   'FINSI' ;
* 2026/06/08 nx=5 nv=0.5
* miqer = 0.55 ; meqer = 0.56 ; maqer = 0.57 ;
* 2026/06/11 nx=5 nv=0.5 linux32
miqer = 0.36 ; meqer = 0.44 ; maqer = 0.51 ;
'MESS'  'FORMAT' for 'TEST 4 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 4 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  Remaillage de mail4 avec une taille voulue de 0.2 en ne touchant
*         plus le bord. On s'attend à ne pas changer le maillage mais
*         c'est sans compter avec l'algorithme du noeud fictif qui nous
*         a deja fait des blagues
*
* Il faut aussi garder exactement le même critère de qualité
*   lpcritq = tparam . 'lpcritq' ;
*   lcq = 'EXTR' lpcritq ('DIME' lpcritq) ;
*   jcq = 'ENTI' 'PROC' ('EXTR' lcq 1) ;
*   pcq = 'EXTR' lcq 2 ; qcq =  'EXTR' lcq 3 ;
*   tparam5 = 'TABL' ;
*   tparam5 . 'impr' = 2 ;
*   tparam5 . 'critqual' = 'LECT' jcq ;
*   tparam5 . 'critqual_pmoy' = 'PROG' pcq ;
*   tparam5 . 'critqual_qbias' = 'PROG' qcq ;
 
tparam = 'TABL' ; tparam . 'impr' = 1 ; tparam . 'nbpasses_rema' = 1 ;
   mail5 = 'REMA' mail4 ('ENVE' mail4) ('/' 1. nv) tparam ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher le bord' ;
      'TRAC' mail5 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 5 : on vérifie que mail5 et mail4 sont identiques ainsi que les
* qualités
dn45= 'NBEL' ('DIFF' mail4 mail5) ;
'SI' ('NEG' dn45 0) ;
   'MESS' '!!! TEST 5 : mail4 .NE. mail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-3D3
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales