Exemples de jeux de données Cast3M

* fichier :masse_modale.dgibi
************************************************************************
************************************************************************
*---------------------------------------------------------------------------*
*       Cas-test du la porocedure @MASSMOD                                  *
*                                                                           *
* Description :  ANALYSE VIBRATOIRE - 3 MASSES, 3 RESSORTS, ENCASTRE EN BAS *
* ------------   DDL autorises : UX et UY (UZ, RX, RY, RZ bloques)          *
*                                                                           *
* Objectif :     Determiner les frequences propres et les masses            *
* ---------      participantes (% de masse mobilisee par mode)              *
*                                                                           *
*---------------------------------------------------------------------------*
*
*               SCHEMA DU SYSTEME
*               -----------------
*       Z    Y
*       |   /                          ddl libres : UX, UY
*       |  /                           ddl bloques: UZ, RX, RY, RZ
*       | /
*       o-----> X
*
*
*                       +---------+
*                       |   M3    |    <-- masse 3 (UX, UY)
*                       | 1000 kg |        P4 (z = 0.3 m)
*                       +---------+
*                            |
*                            /
*                            \           Ressort 3 (D3)
*                            /           KX3 = 2.5e6 N/m
*                            \           KY3 = 2.0e6 N/m
*                            /
*                            |
*                       +---------+
*                       |   M2    |    <-- masse 2 (UX, UY)
*                       | 1500 kg |        P3 (z = 0.2 m)
*                       +---------+
*                            |
*                            /
*                            \           Ressort 2 (D2)
*                            /           KX2 = 3.0e6 N/m
*                            \           KY2 = 4.0e6 N/m
*                            /
*                            |
*                       +---------+
*                       |   M1    |    <-- masse 1 (UX, UY)
*                       | 2000 kg |        P2 (z = 0.1 m)
*                       +---------+
*                            |
*                            /
*                            \           Ressort 1 (D1)
*                            /           KX1 = 4.0e6 N/m
*                            \           KY1 = 5.0e6 N/m
*                            /
*                            |
*                      ===============
*                      / / / / / / / /     P1 (z = 0)
*                                          ENCASTREMENT
*                                          (DEPL + ROTA bloques)
*
*-------------------------------------------------------------------------
*
OPTI 'DIME' 3 'ELEM' 'SEG2' 'DENS' 0.1 'ECHO' 0;
*
* LES MASSES
M1      = 2000.;
M2      = 1500.;
M3      = 1000.;
*
* LES RIGIDITES SELON L'AXE X
KX1     = 4000.e3;
KX2     = 3000.e3;
KX3     = 2500.e3;
*
* LES RIGIDITES SELON L'AXE Y
KY1     = 5000.e3;
KY2     = 4000.e3;
KY3     = 2000.e3;
*
* SYSTEME BLOQUE EN Z, PAS NECESSAIRE LES KZ
**
P1      = 0. 0. 0.;
P2      = 0. 0. 0.1;
P3      = 0. 0. 0.2;
P4      = 0. 0. 0.3;
D1      = DROI 1 P1 P2;
D2      = DROI 1 P2 P3;
D3      = DROI 1 P3 P4;
STRUC   = D1 ET D2 ET D3;
CL1     = BLOQ 'DEPL' 'ROTA' P1;
* Seuls les deplacements X et Y sont autorises :
CL2     = BLOQ 'UZ' 'RX' 'RY' 'RZ' STRUC;
*
* MODELES ET MATERIAUX - CARACTERISTIQUES DES TROIS RESSORTS
MOD1     = MODE D1 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'JOI1' ;
MAT1     = MATE MOD1 'KN' 0. 'KS1' KX1 'KS2' KY1 'QN' 0. 'QS1' 0. 'QS2' 0.
                     'DIRECTION' (0. 0. 1.) (1. 0. 0.);
*
MOD2     = MODE D2 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'JOI1' ;
MAT2     = MATE MOD2 'KN' 0. 'KS1' KX2 'KS2' KY2 'QN' 0. 'QS1' 0. 'QS2' 0.
                     'DIRECTION' (0. 0. 1.) (1. 0. 0.);
*
MOD3     = MODE D3 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'JOI1' ;
MAT3     = MATE MOD3 'KN' 0. 'KS1' KX3 'KS2' KY3 'QN' 0. 'QS1' 0. 'QS2' 0.
                     'DIRECTION' (0. 0. 1.) (1. 0. 0.);
*
MATT     = MAT1 ET MAT2 ET MAT3;
MODT     = MOD1 ET MOD2 ET MOD3;
*
* LES MASSES
MASST1   = MASS 'UX' 'UY' M1 P2;
MASST2   = MASS 'UX' 'UY' M2 P3;
MASST3   = MASS 'UX' 'UY' M3 P4;
MASST    = MASST1 ET MASST2 ET MASST3;
*
* LES RIGIDITES (DE CHAQUE RESSORT)
RIG1     = RIGI MOD1 MAT1;
RIG2     = RIGI MOD2 MAT2;
RIG3     = RIGI MOD3 MAT3;
*
RIGT     = RIG1 ET RIG2 ET RIG3 ET CL1 ET CL2;
*
*-------------------------------------------------------------------------
* ANALYSE VIBRATOIRE - DETERMINATION DES MODES PROPRES
*-------------------------------------------------------------------------
MODE_PRO = VIBR 'INTERVALLE' 0. 34. RIGT MASST;
*
*-------------------------------------------------------------------------
* APPEL A LA PROCEDURE @MASSMOD POUR CALCULER LES MASSES MOBILISEES
* PAR MODE ET PAR DIRECTION
*-------------------------------------------------------------------------
TABMASSE = @MASSMOD MODE_PRO MASST;
*
*-------------------------------------------------------------------------
* VERIFICATION DES RESULTATS PAR COMPARAISON A LA SOLUTION ANALYTIQUE
*-------------------------------------------------------------------------
REF_MX   = PROG 87.64722  0.       0.      11.08348  1.26930  0.      100. ;
REF_MY   = PROG  0.      84.87547 12.34523  0.       0.       2.77930 100. ;
LIST_MX  = TABMASSE . ' MASSE-X_(%)' ;
LIST_MY  = TABMASSE . ' MASSE-Y_(%)' ;
ERR      = MAXI (MAXI 'ABS' (LIST_MX - REF_MX))
                (MAXI 'ABS' (LIST_MY - REF_MY)) ;
SI (ERR > 1.E-5) ;
  ERRE (CHAI 'ECART CAST3M - REFERENCE TROP IMPORTANT :' ERR) ;
SINON ;
  MESS 'CAS TEST PASSE AVEC SUCCES !' ;
FIN ;