Télécharger la plaquette Cast3M


fr en

Télécharger lyre3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  lyre3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13    PROVENANCE : TEST
  5.  
  6. *******************************************
  7. *    Test lyre3.dgibi: jeux de données    *
  8. *    ---------------------------------    *
  9. *******************************************
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19.   OPTI ECHO 1   ;
  20.   OPTI TRAC PSC   ;
  21. SINO ;
  22.   OPTI ECHO 0   ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26.  
  27. *******************************************
  28. *                                         *
  29. *            LYRE-VICTUS 3                *
  30. *                                         *
  31. *   ESSAI ELEMENT TUYAU (DROIT ET COUDE)  *
  32. *                                         *
  33. *   description :                         *
  34. *   -----------                           *
  35. *   Test en statique lineaire, chargement *
  36. *   thermique.                            *
  37. *   La structure est constituee d'elements*
  38. *   TUYAU :                               *
  39. *     - 7 portions de tuyau droit,        *
  40. *     - 6 portions de tuyau coude.        *
  41. *                                         *
  42. *   Proprietes du materaiux :             *
  43. * - Module d'Young :         YOUN = 2.e11 *
  44. * - Coefficient de Poisson : NU   = 0.3   *
  45. * - Dilatabilite thermique : ALPH = 18.e-6*
  46. *                                         *
  47. *   Conditions aux limites :              *
  48. *     Encastrement aux extremites         *
  49. *    (P1 et P14)                          *
  50. *                                         *
  51. *   Chargement :                          *
  52. *     Chargement thermique : Elevation de *
  53. *     temperature de 400 degres Celcius.  *
  54. *     Le poids propre est neglige.        *
  55. *     Test corrig‚ le 10/09/92            *
  56. *******************************************
  57.  
  59. OPTI ELEM SEG2;
  60. *+++++++++++++++++++++++++++++++++++++++++*
  61. *               GEOMETRIE : MAILLAGE      *
  62. *+++++++++++++++++++++++++++++++++++++++++*
  63.  
  64. OEIL = 100 -100 100;
  65.  
  66. P1  = 0.    0.     0.;
  67. P2  = 0.79  0.     0.;
  68. P3  = 1.095 -.305  0.;
  69. P4  = 1.095 -1.155 0.;
  70. P5  = 1.400 -1.460 0.;
  71. P6  = 2.480 -1.460 0.;
  72. P7  = 2.785 -1.460 .305;
  73. P8  = 2.785 -1.460 1.155;
  74. P9  = 2.785 -1.155 1.460;
  75. P10 = 2.785  -.305 1.460;
  76. P11 = 2.785  0.    1.155;
  77. P12 = 2.785  0.    0.305;
  78. P13 = 3.090  0.    0.;
  79. P14 = 3.880  0.    0.;
  80.  
  81. T = TABL;
  82. T.1 = P1  DROI 10 P2;
  83. T.2 = P3  DROI 11 P4;
  84. T.3 = P5  DROI 14 P6;
  85. T.4 = P7  DROI 11 P8;
  86. T.5 = P9  DROI 11 P10;
  87. T.6 = P11 DROI 11 P12;
  88. T.7 = P13 DROI 12 P14;
  89.  
  90. C = TABL;
  91. C1 = 0.79  -0.305 0.;
  92. C2 = 1.4   -1.155 0.;
  93. C3 = 2.48  -1.460 0.305;
  94. C4 = 2.885 -1.155 1.155;
  95. C5 = 2.885 -0.305 1.155;
  96. C6 = 3.190  0.0   0.305;
  97.  
  98. C.1 = P2  CERC 12 C1 P3;
  99. C.2 = P4  CERC 12 C2 P5;
  100. C.3 = P6  CERC 12 C3 P7;
  101. C.4 = P8  CERC 12 C4 P9;
  102. C.5 = P10 CERC 12 C5 P11;
  103. C.6 = P12 CERC 12 C6 P13;
  104.  
  105. SUR1 = T.7;
  106. I = 0;
  107. REPETER BLOC1 6;
  108.   I = I + 1;
  109.   SUR1 = SUR1 ET T.I ET C.I;
  110. FIN BLOC1;
  111.  
  112. SI (NEG GRAPH 'N');
  113.    TITR 'LYRE3 : MAILLAGE';
  114.    TRAC OEIL 'QUAL' SUR1;
  115. FINSI;
  116.  
  117. *+++++++++++++++++++++++++++++++++++++++++*
  118. *     CALCUL DE LA RIGIDITE               *
  119. *+++++++++++++++++++++++++++++++++++++++++*
  120. VECT1 = TABL;
  121.  
  122. VECT1.1 = ( 0.  0. -1.); 
  123. VECT1.2 = ( 0.  0.  1.);
  124. VECT1.3 = ( 0. -1.  0.); 
  125. VECT1.4 = (-1.  0.  0.);
  126. VECT1.5 = (-1.  0.  0.); 
  127. VECT1.6 = ( 0. -1.  0.);
  128.  
  129. MODL1 = MODE T.7 MECANIQUE ELASTIQUE 
  130.                  ISOTROPE TUYA;
  131. MATR1 = MATE MODL1 YOUN 2.E11 NU 0.3 
  132.                    ALPH 18.E-6 'TALP' 0. 'TREF' 0.
  133.                    EPAI 8.18E-3 
  134.                    RAYON 109.59E-3;
  135. RIGI1 = RIGI MODL1 MATR1;
  136.  
  137. I = 0;
  138. REPETER BLOC2 6;
  139.   I = I + 1;
  140.  
  141.   MODL2 = MODE T.I MECANIQUE ELASTIQUE 
  142.                    ISOTROPE TUYA;
  143.   MATR2 = MATE MODL2 YOUN 2.E11 NU 0.3 
  144.                      ALPH 18.E-6  'TALP' 0. 'TREF' 0.
  145.                      EPAI 8.18E-3 
  146.                      RAYON 109.59E-3;
  147.   RIGI2 = RIGI MODL2 MATR2;
  148.  
  149.   MODL3 = MODE C.I MECANIQUE ELASTIQUE 
  150.                    ISOTROPE TUYA;
  151.   MATR3 = MATE MODL3 YOUN 2.E11 NU 0.3 
  152.                      ALPH 18.E-6 'TALP' 0. 'TREF' 0.
  153.                      EPAI 8.18E-3 
  154.                      RAYON 109.59E-3
  155.                  RACO 305.E-3 VECT VECT1.I;
  156.   RIGI3 = RIGI MODL3 MATR3;
  157.  
  158.   MODL1 = MODL1 ET MODL2 ET MODL3;
  159.   MATR1 = MATR1 ET MATR2 ET MATR3;
  160.   RIGI1 = RIGI1 ET RIGI2 ET RIGI3;
  161.  
  162. FIN BLOC2;
  163.  
  164. *+++++++++++++++++++++++++++++++++++++++++*
  165. *         RESOLUTION : CALCUL ELASTIQUE   *
  166. *+++++++++++++++++++++++++++++++++++++++++*
  167.  
  168. * Conditions aux limites
  169. CL1   = BLOQ DEPL ROTA P1;
  170. CL2   = BLOQ DEPL ROTA P14;
  171. RIGI1 = RIGI1 ET CL1 ET CL2;
  172.  
  173. * Chargement thermique
  174. CHPOTEMP = MANU CHPO SUR1 1 'T' 400.;
  175. SIGM1    = THET MODL1 MATR1 CHPOTEMP;
  176. CHAR1    = BSIG MODL1 SIGM1 MATR1;
  177.  
  178. * Resolution
  179. DEPL1    = RESO RIGI1 CHAR1;
  180.  
  181. * Trace
  182. SI (NEG GRAPH 'N');
  183.  
  184.   TITR 'LYRE3 : DEFORMEE';
  185.   DEF0  = DEFO SUR1 DEPL1 0. NOIR;
  186.   DEF1  = DEFO SUR1 DEPL1 1. BLEU;
  187.   TRAC OEIL (DEF0 ET DEF1);
  188. FINSI;
  189.  
  190. *+++++++++++++++++++++++++++++++++++++++++*
  191. *          extraction des resultats       *
  192. *+++++++++++++++++++++++++++++++++++++++++*
  193. V1P6 = -1.374E-2;
  194. V2P6 = EXTR DEPL1 UY P6;
  195. ERG1 = 100. * (ABS ((V1P6 - V2P6) / V1P6));
  196.  
  197. U1P7 = 1.070E-2;
  198. U2P7 = EXTR DEPL1 UX P7;
  199. ERG2 = 100. * (ABS ((U1P7 - U2P7) / U1P7));
  200.  
  201. W1P9 = 1.301E-2;
  202. W2P9 = EXTR DEPL1 UZ P9;
  203. ERG3 = 100. * (ABS ((W1P9 - W2P9) / W1P9));
  204.  
  205. *+++++++++++++++++++++++++++++++++++++++++*
  206. *          affichage des resultats        *
  207. *+++++++++++++++++++++++++++++++++++++++++*
  208. MESS 'RESULTATS : TEST LYRE VICTUS 3 ';
  209. MESS '------------------------------ ';
  211.  
  212. MESS '   Deplacement v (m) du point P6 ';
  213. MESS '   ----------------------------- ';
  214. MESS '      Valeur theorique : ' V1P6 'm';
  215. MESS '      Valeur calculee  : ' V2P6 'm';
  216. MESS '                Ecart  : ' ERG1 '%';
  218.  
  219. MESS '   Deplacement u (m) du point P7 ';
  220. MESS '   ----------------------------- ';
  221. MESS '      Valeur theorique : ' U1P7 'm';
  222. MESS '      Valeur calculee  : ' U2P7 'm';
  223. MESS '                Ecart  : ' ERG2 '%';
  225.  
  226. MESS '   Deplacement w (m) du point P9 ';
  227. MESS '   ----------------------------- ';
  228. MESS '      Valeur theorique : ' W1P9 'm';
  229. MESS '      Valeur calculee  : ' W2P9 'm';
  230. MESS '                Ecart  : ' ERG3 '%';
  232.  
  233. *+++++++++++++++++++++++++++++++++++++++++*
  234. *         Code de fonctionnement          *
  235. *+++++++++++++++++++++++++++++++++++++++++*
  236. ERGMAX = MAXI (PROG ERG1 ERG2 ERG3);
  237.  
  238. SI (ERGMAX <EG 3.);
  239.   ERRE 0;
  240. SINON;
  241.   ERRE 5;
  242. FINSI;
  244.  
  245. TEMPS;
  246.  
  247. FIN;
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales